Get resources from shell32.dll

[jeantje]

let's say i want an image from shell32.dll but i don't want to export it so i want to directly load it from the dll and then display it in a guy any ways to do that?

Edited April 4, 2009 by jeantje

[TerarinK]

Look into _GUIImageList Managment under the help think that will aid you then

[jeantje]

Look into _GUIImageList Managment under the help think that will aid you then

eh actually i want to load a bitmap from a dll file

[maqleod]

eh actually i want to load a bitmap from a dll file

well, for icons from shell32.dll, this would load it directly to a control in your gui:

GUICtrlSetImage($controlid, "shell32.dll", 22)

not sure how you would load it as a bitmap though.

[Authenticity]

expandcollapse popup

#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
_GDIPlus_Startup()

Dim $hGUI = GUICreate('Test')
Dim $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
Dim $hBitmap = _WinAPI_LoadBitmap(_WinAPI_GetModuleHandle('shell32.dll'), 147)
Dim $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)
GUISetState()
_GDIPlus_GraphicsDrawImage($hGraphics, $hImage, 0, 0)

GUIRegisterMsg($WM_PAINT, 'OnPaint')

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_RESTORE
            _GDIPlus_GraphicsDrawImage($hGraphics, $hImage, 0, 0)
            
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
    
    Sleep(20)
WEnd

_WinAPI_DeleteObject($hImage)
_WinAPI_DeleteObject($hBitmap)
_GDIPlus_GraphicsDispose($hGraphics)
GUIDelete()

_GDIPlus_Shutdown()

Func OnPaint($hwnd, $iMsg, $iwParam, $ilParam)
    _GDIPlus_GraphicsDrawImage($hGraphics, $hImage, 0, 0)
    
    Return $GUI_RUNDEFMSG
EndFunc

[trancexx]

For example above mine I would go with this:

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

GUICreate("Test", 413)
$hPic = GUICtrlCreatePic("", 0, 0, 413, 72)

Local $hInstance = _WinAPI_GetModuleHandle("shell32.dll")

Local $hBitmap= _WinAPI_LoadImage($hInstance, 147, $IMAGE_BITMAP, 0, 0, 0)

Local $STM_SETIMAGE = 370
Local $iMsg = GUICtrlSendMsg($hPic, $STM_SETIMAGE, 0, $hBitmap)

GUISetState()

While 1
    If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
WEnd

[jeantje]

and are there any ways to load a bitmap from a dll file and not shell32.dll but HSInst.dll and then bitmap 102

Download: HSInst.zip

[ProgAndy]

Yes, this is possible:

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

GUICreate("Test", 413)
$hPic = GUICtrlCreatePic("", 0, 0, 300, 180)

Local $hInstance = _WinAPI_LoadLibraryEx(@WindowsDir&"\explorer.exe",$LOAD_LIBRARY_AS_DATAFILE )

Local $hBitmap= _WinAPI_LoadImage($hInstance, 170, $IMAGE_BITMAP, 0, 0, 0)

Local $STM_SETIMAGE = 370
Local $iMsg = GUICtrlSendMsg($hPic, $STM_SETIMAGE, 0, $hBitmap)
If $iMsg Then 
    _WinAPI_DeleteObject($iMsg)
EndIf

GUISetState()

While 1
    If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
WEnd

[jeantje]

Yes, this is possible:

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

GUICreate("Test", 413)
$hPic = GUICtrlCreatePic("", 0, 0, 300, 180)

Local $hInstance = _WinAPI_LoadLibraryEx(@WindowsDir&"\explorer.exe",$LOAD_LIBRARY_AS_DATAFILE )

Local $hBitmap= _WinAPI_LoadImage($hInstance, 170, $IMAGE_BITMAP, 0, 0, 0)

Local $STM_SETIMAGE = 370
Local $iMsg = GUICtrlSendMsg($hPic, $STM_SETIMAGE, 0, $hBitmap)
If $iMsg Then 
    _WinAPI_DeleteObject($iMsg)
EndIf

GUISetState()

While 1
    If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
WEnd

thank you very much