How can i print the contents of html select tag?

[bhodi78]

Hello everyone, I would like to know how can i print the contents of html select tag.

this is the code:

#include <IE.au3>
#include <Array.au3>
#requireadmin   

$start="Tampere (TMP)"

$oIE = _IECreate ("http://www.ryanair.com/php/sbforms/form.php?")
$SBform = _IEFormGetCollection ($oIE,0)

;Departing from
$o = _IEFormElementGetObjByName ($SBform,"sector1_o")
_IEFormElementOptionselect ($o, $start, 1, "byText")

;Going to
$d = _IEFormElementGetObjByName ($SBform,"sector1_d")
$e=0
For $s In $d
    MsgBox(0, $e,$s)
    $e=$e+1
Next
Exit

I would like to print out the following strings:

Bremen (BRE)

Dublin (DUB)

Frankfurt-Hahn (HHN)

London-Stansted (STN)

Milan (Bergamo) (BGY)

Riga (RIX)

I hope someone can help me.

Thank you.

[Authenticity]

#NoTrayIcon
#include <IE.au3>
#include <Array.au3>
#RequireAdmin

$start = "Tampere (TMP)"
$sFile = @ScriptDir & '\TMP(GoingTo).txt'

$oIE = _IECreate("http://www.ryanair.com/php/sbforms/form.php?")
$SBform = _IEFormGetCollection($oIE, 0)

;Departing from
$o = _IEFormElementGetObjByName($SBform, "sector1_o")
_IEFormElementOptionselect($o, $start, 1, "byText")

;Going to
$d = _IEFormElementGetObjByName($SBform, "sector1_d")
$sStr = ''

For $s In $d
    $sStr &= _IEPropertyGet($s, 'innerhtml') & @CRLF
Next

$sStr = StringTrimLeft($sStr, StringInStr($sStr, @CRLF)+1)
FileWrite($sFile, $sStr)
RunWait(@ComSpec & '/c print "' & $sFile & '"', '', @SW_HIDE)
FileDelete($sFile)

[DaleHohm]

Nothing wrong with the above, but also note that

select elements (like "sector1_o" and "sector1_d") have an options collection. Each option item in the options collection has a value and a text property. In addition the select element has a length property that tells you how many items are in the options collection (actually, the options collection also has this length property and gives you the same value).

$options = $o.options
For $option in $options
    ConsoleWrite($option.value & "|" & $option.text & @CRLF)
Next

Dale

[bhodi78]

Nothing wrong with the above, but also note that

select elements (like "sector1_o" and "sector1_d") have an options collection. Each option item in the options collection has a value and a text property. In addition the select element has a length property that tells you how many items are in the options collection (actually, the options collection also has this length property and gives you the same value).

$options = $o.options
For $option in $options
    ConsoleWrite($option.value & "|" & $option.text & @CRLF)
Next

Dale

Thank you very much, so it is perfect!