Help with String change to Lower Or Upper Cases

[RZLucian0127]

i was wondering if there a certain Commands that can convert a lower case word into Caps Word.

Example:

$var = my word
theCommand($var); converting my word into My Word.

MsgBox (0, "Title", $var)

Then the output will be "My Word".

can anyone tell me what is that commands for set to lowercase and uppercase or upperlowercase? thanks in advance!

[andybiochem]

StringUpper() and StringLower() will convert the whole string to upper and lower cases.

This quick func I've just knocked up will just convert just the 1st letters of each word.

$a = "hello there everyone"

MsgBox(0,"",_StringUpper_FirstLetterOnly($a))


Func _StringUpper_FirstLetterOnly($sString)
    
    Local $aArray = StringSplit($sString,"")
    
    $sString = StringLower($sString)
    
    $sString = ""
    For $i = 1 To UBound($aArray) - 1
        If $aArray[$i - 1] = " " Or $i = 1 Then $aArray[$i] = StringUpper($aArray[$i])
        $sString &= $aArray[$i]
    Next
    
    Return $sString 
    
EndFunc

I'll bet there is a nice RegExp that does this in one line, but that's big boy stuff.

[Authenticity]

Using _StringProper:

#include <String.au3>
ConsoleWrite(_StringProper("hello there everyone") & @LF)oÝ÷ Øêî²)àJÚâ^Lijëh×6Dim $sStr = "hello there everyone"
Dim $aWords = StringRegExp($sStr, '(\w+|\W+)', 3)

If IsArray($aWords) Then
    $sStr = ''
    For $i = 0 To UBound($aWords)-1
        If StringRegExp($aWords[$i], '^\w') Then
            $sStr &= Chr(BitAND(Asc(StringLeft($aWords[$i], 1)), 0xDF)) & StringTrimLeft($aWords[$i], 1)
        Else
            $sStr &= $aWords[$i]
        EndIf
    Next
    ConsoleWrite($sStr & @LF)
EndIf

No one line StringRegExpReplace for this one without a callback procedure (maybe). ;]

[SmOke_N]

StringUpper() and StringLower() will convert the whole string to upper and lower cases.

This quick func I've just knocked up will just convert just the 1st letters of each word.

$a = "hello there everyone"

MsgBox(0,"",_StringUpper_FirstLetterOnly($a))


Func _StringUpper_FirstLetterOnly($sString)
    
    Local $aArray = StringSplit($sString,"")
    
    $sString = StringLower($sString)
    
    $sString = ""
    For $i = 1 To UBound($aArray) - 1
        If $aArray[$i - 1] = " " Or $i = 1 Then $aArray[$i] = StringUpper($aArray[$i])
        $sString &= $aArray[$i]
    Next
    
    Return $sString 
    
EndFunc

I'll bet there is a nice RegExp that does this in one line, but that's big boy stuff.

I don't think regexreplace can make changes to upper/lower in the 3rd param.

Here's another method:

$s = "I am a string"
ConsoleWrite( _String_UpperCase_IndividualWords($s) & @CRLF)

Func _String_UpperCase_IndividualWords($s_str)
    Local $a_sre = StringRegExp($s_str, "(.*?)([a-zA-Z-_]+)", 3)
    If @error Then Return SetError(1, 0, $s_str)
    Local $s_hold = ""
    For $i = 0 To UBound($a_sre) - 1 Step 2
        $s_hold &= $a_sre[$i] & _
            StringUpper(StringLeft($a_sre[$i + 1], 1)) & _
            StringTrimLeft($a_sre[$i + 1], 1)
    Next
    Return $s_hold
EndFunc

Edit:

Authenticity beat me with the regex, but you have to versions to look at at least ...

Edited May 16, 2009 by SmOke_N

[MrCreatoR]

For this reason the feature request about StringRegExpReplaceCallback was posted, and there is a UDF by amel27: _StringRegExpReplaceCallBack implementation.

I guess it will be much easier to do those kind of tasks now