Just a simple question.

[ubbelol]

Hello all!

Unfortunaly my first post at this forum had to be a support question

Anyways, i want to know how to send the value of a textbox (input) in AutoIT.

For example, i made a simple GUI with a textbox and a button and i want so when i press the button, it sends the value of textbox!

I've tried

send($input1)

But it doesn't seem to work.

Thanks!

[bogQ]

  ubbelol said:

Hello all!

Unfortunaly my first post at this forum had to be a support question

Anyways, i want to know how to send the value of a textbox (input) in AutoIT.

For example, i made a simple GUI with a textbox and a button and i want so when i press the button, it sends the value of textbox!

I've tried

send($input1)

But it doesn't seem to work.

Thanks!

from help file

GUICtrlSetData and GUICtrlRead can help

edit:

short example

#include <GUIConstantsEx.au3>
Global $data = "hi all"
GUICreate("My GUI Button")
$input = GUICtrlCreateInput("",0, -1)
$Button_1 = GUICtrlCreateButton("Hi all", 10, 30, 100)
GUISetState() 
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_1
            GUICtrlSetData($input,$data )
;~          Send(GUICtrlRead($input))

    EndSelect
WEnd

Edited May 24, 2009 by bogQ

[Melba23]

ubbelol,

This script opens Notepad and sends the text in the input box to it:

#include <GUIConstantsEx.au3>

Run("notepad")
WinWait("Untitled - Notepad")

$hGUI = GUICreate("Test", 500, 500)
$hInput = GUICtrlCreateInput("", 10, 10, 480, 200)
$hButton = GUICtrlCreateButton("Send", 10, 220, 80, 30)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            WinClose("Untitled - Notepad")
            Exit
        Case $hButton
            $sInput = GUICtrlRead($hInput)
            WinActivate("Untitled - Notepad")
            WinWaitActive("Untitled - Notepad")
            Send($sInput)
            GUICtrlSetData($hInput, "")
            WinActivate("Test")
            WinWaitActive("Test")
            ControlFocus ("Test", "", $hInput)
    EndSwitch
WEnd

It should help you on your way. :-)

M23

[nf67]

(This is just a clear short answer, check Melba and bog for details)

$InputText = GUICtrlRead ($Input)
Send ($InputText)