Stuck in Loop

[GoofyGremlin]

Working on OCR for a bot I am making. Reading individual characters works fine and is handled by GetChar(). The problem I am encountering is spaces. Spaces in the font I am reading are a variable number of pixels. I can get the OCR function to recognize spaces, but then it does not realize when it is at the end of the word and endlessly adds spaces. Here is the problem section of my script:

Func GetCardName()
Do
    GetChar()
        If $char = "" Then
            For $xdum = 0 to 10
                For $ydum = 0 To 15
                    $pixCol = PixelGetColor($xstart + $xdum, $ystart - $ydum)
                    If $pixCol = 0xEBE2AF Then
                        If $space = False Then
                            $char = " "
                            $xstart = $xstart + $xdum
                            $space = True
                            ExitLoop(2)
                        Else
                            $wcomplete = True
                            Msgbox(0, "Complete", "Cardname Complete")
                            ExitLoop(2)
                        EndIf
                    EndIf
                Next
            Next
        Else
            $space = False
        EndIf
    $wordString = $wordString & $char
    MsgBox(0, "Reading", $wordString)
Until $wcomplete = True
EndFunc

The method I used here was that when GetChar() encounter blank space after a character, it would search the next 10 pixels (bigger than spaces which are 5-9 pixels) to the right for another character. This works find as far as recognizing spaces and restarting on the next character, but never realizes its at the end of the word ($wcomplete never becomes true).

I have considered a couple problems I might be having, and would appreciate any comments or ideas.

1. I have been staring at the computer screen for way too long and can't see the obvious mistake.

2. I have some flawed logic in the loop.

3. I am overstepping the end of the column while looking to see if there are extra spaces.

[Melba23]

GoofyGremlin,

This is my attempt to cretae a logical function for you, but of course it is untested. I have tried to simplify it as much as possible and commented almost every line to explain my thinking. Try it and see! >_<

expandcollapse popup

Func GetCardName()
    While 1
        ; Try and read character
        GetChar()   ; Assume that $xstart and $ystart are reset for next read if successful

        ; Was a character read?
        If $char = "" Then  ; No - we have a gap

            ; Is it a space (5-9 pixels wide) or the end of word (10 pixels wide)
            For $xdum = 0 to 10
                For $ydum = 0 To 15
                    ; Search the gap
                    $pixCol = PixelGetColor($xstart + $xdum, $ystart - $ydum)
                    ; If we find "text colour" exit the search
                    If $pixCol = 0xEBE2AF Then ExitLoop 2     ; Break out of 2 For...Next loops
                    ; <<<<<<<<<<<<< Use correct syntax for ExitLoop !!!!!!  >>>>>>>>>>>>>>>>>>>
                Next
            Next
            ; Check to see if we exited early because text colour was found
            If $xdum = 11 Then
                ; No early exit so gap is end of word
                Msgbox(0, "Complete", "Cardname Complete")
                ExitLoop    ; Break out of While...WEnd loop
            Else
                ; Early exit so gap must only be a space
                $char = " "
                ; Reset $xstart for next read
                $xstart = $xstart + $xdum   ; Might be $xdum +/- 1 - you will have to test!
            EndIf
        EndIf

        ; Add char to string
        $wordString = $wordString & $char
        MsgBox(0, "Reading", $wordString)

    WEnd
EndFunc

Two points - both made in the comments but reiterated here:

1. You were using the wrong syntax for ExitLoop - that may have caused your problem in part.

2. You will have to play with resetting $xstart after finding a space - I think I have it set correctly, but it might well be a pixel out either way.

Let me know how you get on.

M23

[GoofyGremlin]

Thanks a lot that worked. I still don't understand why my original code didn't work thought. Exit 2 and Exit(2) both had the same effect (the help file seems to imply that it has to be in parantheses). But anyway thanks a lot for your help, OCR is now working great.

[bo8ster]

Exit and ExitLoop are different. You cannot use ExitLoop like you can Exit.

ExitLoop(2) is the incorrect syntax. See http://www.autoitscript.com/autoit3/docs/keywords/ExitLoop.htm.

[Melba23]

GoofyGremlin,

Your initial code did not work because of several logic errors within it. That is why I went for a complete rewrite rather than amending your code. Sorry, but I am not going to analyse them in detail.

As to the syntax question:

Exit: "Remarks - The parameter, if included, can be enclosed in parentheses. Thus, the following are equivalent: Exit, Exit 0, and Exit(0). However, Exit() is invalid."

ExitLoop: No parentheses allowed.

The two are very different in action: Exit quits the script setting a DOS errorlevel (oh, how that takes me back..... >_< ) while ExitLoop breaks out of a While/Do/For loop.

M23