Ctrl+Tab not works on tab control

[rexx]

I found that ctrl+tab and ctrl+shift+tab not works on tabs created by autoit.

It should switch to next/previous tab but it just works like a normal tab, jump to the next control.

Is that a bug or there are some options for it?

[Authenticity]

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <TabConstants.au3>

Global $hGUI, $Tab, $TabRight, $TabLeft
Global $aAccelerator[2][2]
Global $aTabs[21] = [20]

$hGUI = GUICreate('Test', 400, 500)
$Tab = GUICtrlCreateTab(0, 0, 400, 500)
$TabRight = GUICtrlCreateDummy()
$TabLeft = GUICtrlCreateDummy()

For $i = 1 To $aTabs[0]
    $aTabs[$i] = GUICtrlCreateTabItem('Tab ' & $i)
Next
GUICtrlCreateTabItem("")

$aAccelerator[0][0] = '^{TAB}'
$aAccelerator[0][1] = $TabRight
$aAccelerator[1][0] = '^+{TAB}'
$aAccelerator[1][1] = $TabLeft
GUISetAccelerators($aAccelerator, $hGUI)

GUISetState()
Sleep(1000)

While 1
    Switch GUIGetMsg()
        Case $TabRight
            Local $iIndex = GUICtrlRead($Tab)+1
            If $iIndex >= $aTabs[0] Then $iIndex = 0
            GUICtrlSendMsg($Tab, $TCM_SETCURSEL, $iIndex, 0)
            
        Case $TabLeft
            Local $iIndex = GUICtrlRead($Tab)-1
            If $iIndex < 0 Then $iIndex = $aTabs[0]-1
            GUICtrlSendMsg($Tab, $TCM_SETCURSEL, $iIndex, 0)
        
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

GUIDelete()
Exit

[rexx]

wow thanks, that's beautiful and it works fine.

So it's not a native function of tab control?

I thought it was :S

[rexx]

Case $TabRight
            Local $iIndex = GUICtrlRead($Tab)+1
            If $iIndex >= $aTabs[0] Then $iIndex = 0
            GUICtrlSendMsg($Tab, $TCM_SETCURSEL, $iIndex, 0)

It should be $TCM_SETCURFOCUS here to make the content in tab change.

SetCurSel only change the selected tab, but not the contents, that's weird.

Edited August 10, 2009 by rexx

[GEOSoft]

You could also have looked at

ControlCommand ( "title", "text", $Tab, "TabRight", "");; Or "TabLeft" depending on the direction you want to go.