Custom Index on a control

[JakeJohnson74]

Hello all, 

I am running a fully data driven form with 2 list views. Is it possible to force my primary key from the database into the index of the listviews?

This would save me from having to create an array of the items and storing the PK for later referencing. I thought about adding another column to my listviews, but that is unnecessary data on the list and I don't really need the users seeing the ID's. 

My search methods could be weak, but I have searched for this and not come up with much other than, returning the index, not setting the index.

Thanks!

[Melba23]

JakeJohnson74,

Just add the data to the ListView but use _GUICtrlListView_HideColumn to (guess what) hide the column. You may have to make the header unresponsive to prevent the users dragging the separators - like this:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <HeaderConstants.au3>

; The 0-based column to be disabled
Global $iFix_Col

_Main()

Func _Main()
    Local Const $hGUI = GUICreate("ListView Fix Column Width", 400, 300)

    Local Const $hListView = GUICtrlCreateListView("Column 0|Column 1|Column 2|Column 3", 2, 2, 394, 268)

    _GUICtrlListView_HideColumn($hListView, 1) ; Hide column 1

    GUISetState(@SW_SHOWNORMAL)

    ; Prevent resizing of column 1
    $iFix_Col = 1

    GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam

    ; Get details of message
    Local Const $tNMHEADER = DllStructCreate($tagNMHEADER, $lParam)

    ; Look for header resize code
    Local Const $iCode = DllStructGetData($tNMHEADER, "Code")

    Switch $iCode
        Case $HDN_BEGINTRACKW
            ; Now get column being resized
            Local $iCol = DllStructGetData($tNMHEADER, "Item")

            If $iCol = $iFix_Col Then
                ; Prevent resizing
                Return True
            Else
                ; Allow resizing
                Return False
            EndIf
    EndSwitch
EndFunc   ;==>_WM_NOTIFY

 I hope that helps.

M23