25 replies to this topic

[ConsultingJoe]

This could look the same as if you were to embed a video in a website.
It embeds WMP into a gui, This is beta.
the example should help a lot
Let me know what you think
Thanks

UPDATED ON 09/06/07 WITH MORE FUNCTIONS

Plain Text        expandcollapse  popup

#include <GUIConstants.au3>
#include <wmp.au3>

Opt("GUIOnEventMode", 1)

$Form1 = GUICreate("AForm1", 518, 439, 192, 125)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
$wmp = _wmpcreate(1, 8, 8, 425, 425);creates object
_wmpvalue( $wmp, "nocontrols" );hides controls
_wmploadmedia( $wmp, @HomeDrive & "\WINDOWS\clock.avi" );loads media
;_wmpsetvalue( $wmp, "controls" );shows controls
$slider = GUICtrlCreateSlider( 4, 330, 330, 25 )
GUICtrlSetOnEvent( -1, "change" )
GUISetState(@SW_SHOW)

While _wmpvalue($wmp,"getduration") = 0
    Sleep(1)
WEnd
GUICtrlSetLimit($slider,_wmpvalue($wmp,"getduration"),0)
GUISetState(@SW_SHOW)

While 1
Sleep(100)
GUICtrlSetData( $slider, _wmpvalue($wmp,"getposition"))
WEnd

Func quit()
    Exit
EndFunc

Func change()
    _wmpvalue($wmp,"setposition",GUICtrlRead($slider))
EndFunc

Plain Text        expandcollapse  popup

#cs
_wmpcreate($show, $left, $top, $width = 100, $height = 100)
$show:   1 = shows controls
        2 = hides controls

Return: The object for the control
#ce
Func _wmpcreate($show, $left, $top, $width = 100, $height = 100)
$oWMP = ObjCreate("WMPlayer.OCX")
If $oWMP = 0 Then Return 0
$oWMP.settings.autoStart = "False"
If $show = 1 Then
    GUICtrlCreateObj($oWMP, $left, $top, $width, $height)
EndIf
Return $oWMP
EndFunc
#cs
_wmploadmedia( $object, $URL, $autostart = 1 )
$object:    Object returned from the _wmpcreate()
$URL:       Path or URL of the media
$autostart: 1 = yes
            0 = no

Return: None
#ce
Func _wmploadmedia( $object, $URL, $autostart = 1 )
    $object.URL = $URL
    While Not $object.controls.isAvailable("play")
        Sleep(1)
    WEnd
    If $autostart = 1 Then $object.controls.play()
EndFunc
#cs
_wmpsetvalue( $object, $setting, $para=1 )
$object:    Object returned from the _wmpcreate()
$setting:   "play"
            "stop"
            "pause"
            "invisible" (Hides all)
            "control"   (Shows controls)
            "nocontrol" (Hides controls)
            "fullscreen"
            "step"      (frames to step before freezing)
            "fastforward"
            "fastreverse"
            "volume"    (0 To 100)
            "rate"      (-10 To 10)
            "playcount"

Return: None
#ce
Func _wmpvalue( $object, $setting, $para=1 )
        Select
            Case $setting = "play"
            If $object.controls.isAvailable("play") Then $object.controls.play()
        Case $setting = "stop"
            If $object.controls.isAvailable("stop") Then $object.controls.stop()
        Case $setting = "pause"
            If $object.controls.isAvailable("pause") Then $object.controls.pause()
        Case $setting = "invisible"
            $object.uiMode = "invisible"
        Case $setting = "controls"
            $object.uiMode = "mini"
        Case $setting = "nocontrols"
            $object.uiMode = "none"
        Case $setting = "fullscreen"
            $object.fullscreen = "true"
        Case $setting = "step"
            If $object.controls.isAvailable("step") Then $object.controls.step($para)
        Case $setting = "fastForward"
            If $object.controls.isAvailable("fastForward") Then $object.controls.fastForward()
        Case $setting = "fastReverse"
            If $object.controls.isAvailable("fastReverse") Then $object.controls.fastReverse()
        Case $setting = "volume"
            $object.settings.volume = $para
        Case $setting = "rate"
            $object.settings.rate = $para
        Case $setting = "playcount"
            $object.settings.playCount = $para
        Case $setting = "setposition"
            $object.controls.currentPosition = $para
        Case $setting = "getposition"
            Return $object.controls.currentPosition
        Case $setting = "getpositionstring";Returns HH:MM:SS
            Return $object.controls.currentPositionString
        Case $setting = "getduration"
            Return $object.currentMedia.duration
    EndSelect
EndFunc

Edited by CyberZeroCool, 06 September 2007 - 08:59 PM.

[slightly_abnormal]

this is nice

[ConsultingJoe]

this is nice

Thanks, its way better than my embeder that used IE to write and embed a web page

[ptrex]

very nice

I like COM objects a lot and this one is a nice addition.

[J_Y_C]

Ummm, am I daft or is there no link to a WMP UDF anywhere in this thread.....

[RazerM]

I want to see this also, could you post the script again please?

[WTS]

I want to see this also, could you post the script again please?

it mysteriously disapeared?

I think this is it..
WMP.au3

Plain Text        expandcollapse  popup

#cs
_wmpcreate($show, $left, $top, $width = 100, $height = 100)
$show:  1 = shows controls
        2 = hides controls

Return: The object for the control
#ce
Func _wmpcreate($show, $left, $top, $width = 100, $height = 100)
$oWMP = ObjCreate("WMPlayer.OCX")
If $oWMP = 0 Then Return 0
$oWMP.settings.autoStart = "False"
If $show = 1 Then
    GUICtrlCreateObj($oWMP, $left, $top, $width, $height)
EndIf
Return $oWMP
EndFunc
#cs
_wmploadmedia( $object, $URL, $autostart = 1 )
$object:    Object returned from the _wmpcreate()
$URL:       Path or URL of the media
$autostart: 1 = yes
            0 = no

Return: None
#ce
Func _wmploadmedia( $object, $URL, $autostart = 1 )
    $object.URL = $URL
    If $autostart = 1 And $object.controls.isAvailable("play") Then $object.controls.play()
EndFunc
#cs
_wmpsetvalue( $object, $setting, $para=1 )
$object:    Object returned from the _wmpcreate()
$setting:   "play"
            "stop"
            "pause"
            "invisible" (Hides all)
            "control"   (Shows controls)
            "nocontrol" (Hides controls)
            "fullscreen"
            "step"      (frames to step before freezing)
            "fastforward"
            "fastreverse"
            "volume"    (0 To 100)
            "rate"      (-10 To 10)
            "playcount"

Return: None
#ce
Func _wmpsetvalue( $object, $setting, $para=1 )
        Select
            Case $setting = "play"
            If $object.controls.isAvailable("play") Then $object.controls.play()
        Case $setting = "stop"
            If $object.controls.isAvailable("stop") Then $object.controls.stop()
        Case $setting = "pause"
            If $object.controls.isAvailable("pause") Then $object.controls.pause()
        Case $setting = "invisible"
            $object.uiMode = "invisible"
        Case $setting = "controls"
            $object.uiMode = "mini"
        Case $setting = "nocontrols"
            $object.uiMode = "none"
        Case $setting = "fullscreen"
            $object.fullscreen = "true"
        Case $setting = "step"
            If $object.controls.isAvailable("step") Then $object.controls.step($para)
        Case $setting = "fastForward"
            If $object.controls.isAvailable("fastForward") Then $object.controls.fastForward()
        Case $setting = "fastReverse"
            If $object.controls.isAvailable("fastReverse") Then $object.controls.fastReverse()
        Case $setting = "volume"
            $object.settings.volume = $para
        Case $setting = "rate"
            $object.settings.rate = $para
        Case $setting = "playcount"
            $object.settings.playCount = $para
    EndSelect
EndFunc

WMP_Example.au3

#include <GUIConstants.au3>
#include <wmp.au3>
; == GUI generated with Koda ==
$Form1 = GUICreate("AForm1", 518, 439, 192, 125)
$wmp = _wmpcreate(1, 8, 8, 425, 425);creates object
_wmpsetvalue( $wmp, "nocontrols" );hides controls
GUISetState(@SW_SHOW)
_wmploadmedia( $wmp, @HomeDrive & "\WINDOWS\clock.avi" );loads media
;Sleep(1000)
;_wmpsetvalue( $wmp, "controls" );shows controls
While 1
    $msg = GuiGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
    Case Else
;;;;;;;
    EndSelect
WEnd
Exit

Edited by WTS, 09 August 2006 - 07:26 PM.

[RazerM]

Thanks

[J_Y_C]

Aweso! Thanks for sharing.

[ConsultingJoe]

Thanks, I dono what happend

[Wus]

Nice, I will use it to hotkey WMP from games and such.

[BananaFredSoft]

When I try play an AVI video with this, it plays the audio but doesn't show the video, just a black square. Here is my code:

$display = _wmpcreate(1, 181, 10, 280, 210)
_wmploadmedia($display, $readfrom, 0)
_wmpsetvalue($display, "control")

By the way, the functions are really good! Thanks!

Edited by BananaFredSoft, 23 July 2007 - 06:45 PM.

[Trasy]

When I try play an AVI video with this, it plays the audio but doesn't show the video, just a black square. Here is my code:

$display = _wmpcreate(1, 181, 10, 280, 210)
_wmploadmedia($display, $readfrom, 0)
_wmpsetvalue($display, "control")

By the way, the functions are really good! Thanks!

Be sure $readfrom is a valid path and __wmpsetvalue($display, "control") is false, it's _wmpsetvalue($display, "controls").

[Tam0r]

http://msdn2.microsoft.com/en-us/library/bb249349.aspx

Can't one use these objects?

[Nahuel]

Why do I get this error?

[ConsultingJoe]

http://msdn2.microsoft.com/en-us/library/bb249349.aspx

Can't one use these objects?

yeah, go for it

[ConsultingJoe]

TO ALL: UPDATE YOUR MEDIA PLAYER

Goto help and click check for update.

[Nahuel]

Why? It only works with Wmp 11?

[ConsultingJoe]

Why? It only works with Wmp 11?

no, it should work with 9 and 10 too. but some functions maybe limited.

[mnchartier]

This looks very good. I did notice that you can not use the slider though to select where you want to listen from or go back to. Is there anyway to get that to work otherwise this is sweet.