10 replies to this topic

[Dhilip89]

Hello, this is my first release of UDF for AutoIt.
This UDF is designed for work with Unicode string, so only use it with AutoIt3.exe (Unicode Version).

I have used it on my project for unicode URL Encoding and Decoding.
This is an example project that used this UDF:
http://dhilip89.hopto.org/autoit%20test/li.../unicode%20test

AutoIt        expandcollapse  popup

#include-once

;===============================================================================
; _UnicodeURLEncode()
; Description: : Encodes an unicode string to be URL-friendly
; Parameter(s): : $UnicodeURL - The Unicode String to Encode
; Return Value(s): : The URL encoded string
; Author(s): : Dhilip89
; Note(s): : -
;
;===============================================================================

Func _UnicodeURLEncode($UnicodeURL)
    $UnicodeBinary = StringToBinary ($UnicodeURL, 4)
    $UnicodeBinary2 = StringReplace($UnicodeBinary, '0x', '', 1)
    $UnicodeBinaryLength = StringLen($UnicodeBinary2)
    Local $EncodedString
    For $i = 1 To $UnicodeBinaryLength Step 2
        $UnicodeBinaryChar = StringMid($UnicodeBinary2, $i, 2)
        If StringInStr("$-_.+!*'(),;/?:@=&abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890", BinaryToString ('0x' & $UnicodeBinaryChar, 4)) Then
            $EncodedString &= BinaryToString ('0x' & $UnicodeBinaryChar)
        Else
            $EncodedString &= '%' & $UnicodeBinaryChar
        EndIf
    Next
    Return $EncodedString
EndFunc   ;==>_UnicodeURLEncode



;===============================================================================
; _UnicodeURLDecode()
; Description: : Tranlates a URL-friendly string to a normal string
; Parameter(s): : $toDecode - The URL-friendly string to decode
; Return Value(s): : The URL decoded string
; Author(s): : nfwu, Dhilip89
; Note(s): : Modified from _URLDecode() that's only support non-unicode.
;
;===============================================================================
Func _UnicodeURLDecode($toDecode)
    Local $strChar = "", $iOne, $iTwo
    Local $aryHex = StringSplit($toDecode, "")
    For $i = 1 To $aryHex[0]
        If $aryHex[$i] = "%" Then
            $i = $i + 1
            $iOne = $aryHex[$i]
            $i = $i + 1
            $iTwo = $aryHex[$i]
            $strChar = $strChar & Chr(Dec($iOne & $iTwo))
        Else
            $strChar = $strChar & $aryHex[$i]
        EndIf
    Next
    $Process = StringToBinary (StringReplace($strChar, "+", " "))
    $DecodedString = BinaryToString ($Process, 4)
    Return $DecodedString
EndFunc   ;==>_UnicodeURLDecode
#endregion

[Pakku]

This is just where i was looking for, thanks

Edited by Pakku, 16 November 2010 - 12:15 AM.

[Dhilip89]

This is just where i was looking for, thanks

Arjan

You're welcome
Hope it can help you much.

[Raik]

_UnicodeURLDecode returns the same string back unchanged (not decoded)

[Dhilip89]

_UnicodeURLDecode returns the same string back unchanged (not decoded)

Hmm...can you post an example ?

[Raik]

_UnicodeURLDecode-test.aux

Func _UnicodeURLDecode($toDecode)
...
EndFunc

consoleWrite(_UnicodeURLDecode('YWRtaW46bXlwYXNz'))
; "YWRtaW46bXlwYXNz" = "admin:mypass"

returns "YWRtaW46bXlwYXNz"

Edited by Raik, 02 June 2007 - 11:10 AM.

[Dhilip89]

_UnicodeURLDecode-test.aux

Func _UnicodeURLDecode($toDecode)
...
EndFunc

consoleWrite(_UnicodeURLDecode('YWRtaW46bXlwYXNz'))
; "YWRtaW46bXlwYXNz" = "admin:mypass"

returns "YWRtaW46bXlwYXNz"

Hmm...Seems you misunderstood what this function use for.

This function is designed for URL Encoding and Decoding, this is an example of how it is used for,

The unicode string : Ελληνικά
You can't use these type character to request something from webservers, so you need to encode it:

$UnicodeStr = "Ελληνικά"
When we use _UnicodeURLEncode($UnicodeStr), it will return :
%CE%95%CE%BB%CE%BB%CE%B7%CE%BD%CE%B9%CE%BA%CE%AC

When we want to change the URL encoded strings to the text we understand, just use this:

$URLStr = "%CE%95%CE%BB%CE%BB%CE%B7%CE%BD%CE%B9%CE%BA%CE%AC"
_UnicodeURLDecode($URLStr)

It will turn the encoded URL back to normal: Ελληνικά

Hope this information can help you.

[Raik]

sorry, was my mistake.
"YWRtaW46bXlwYXNz" is the base64 encoded HTTP_AUTHORIZATION string.

[Dhilip89]

sorry, was my mistake.
"YWRtaW46bXlwYXNz" is the base64 encoded HTTP_AUTHORIZATION string.

OK, never mind

[4ggr35510n]

I love you! You are best!

Thank you for that!

[ProgAndy]

I love you! You are best!

Thank you for that!

I have written functions for URL-encoding in UTF8, too:
http://www.autoitscript.com/forum/index.php?showtopic=95850&view=findpost&p=689060