Trapping $NM_RETURN in a ListView via WM_NOTIFY

[LarsJ]

Just a small comment to this thread. With Yashied's solution in post #16 you can get NM_RETURN notifications in both a ListView and a TreeView.

Edited April 9, 2012 by LarsJ

[robertcollier4]

Any way to detect an Enter keyboard press in a Listview with Opt("GUIOnEventMode", 1)?

[Melba23]

robertcollier4,

Like this perhaps:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

$cListView = GUICtrlCreateListView("Item List", 10, 10, 300, 300)
$hLV = GUICtrlGetHandle($cListView)

For $i = 1 To 10
    GUICtrlCreateListViewItem("Item " & $i, $cListView)
Next

$cInPut = GUICtrlCreateInput("", 10, 400, 200, 20)

$cEnter_Dummy = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, "_Enter")

GUISetState()

Local $aAccelKeys[1][2] = [["{ENTER}", $cEnter_Dummy]]
GUISetAccelerators($aAccelKeys)

While 1
    Sleep(10)
WEnd

Func _Exit()
    Exit
EndFunc

Func _Enter()
    If _WinAPI_GetFocus() = $hLV Then
        MsgBox(0, "Hi", "Enter pressed in ListView")
    EndIf
EndFunc

M23

[robertcollier4]

Thanks Melba23. I got it working based on your example but setting the event on my ListView instead of a dummy control:

$hListView1 = GUICtrlCreateListView("", 0, 130, 800, 460, $LVS_SINGLESEL, $LVS_EX_FULLROWSELECT)
GUICtrlSetOnEvent(-1, '_hListView1')
Dim $aAccelKeys[2][2] = [['{SPACE}', $hListView1], ['{ENTER}', $hListView1]]
GUISetAccelerators($aAccelKeys)

Func _hListView1()
    $rowNum = _GUICtrlListView_GetSelectedIndices($hListView1, False)
    If(($rowNum <> "") AND ($rowNum <> -1)) Then
        MsgBox(0,0,"Pushed Space or Enter in Row Number: " & $rowNum)
    EndIf
EndFunc

Edited March 29, 2013 by robertcollier4