Hello all!
As I have just read access to my companies Active Directory I need some users willing to test the rewritten _AD_ModifyAttribute function.
My goal is to have the function handle single and multi value attributes the same way and support CLEAR, UPDATE, APPEND and DELETE for the attributes.
First step is to test how the function handles single value attributes:
Please modify the following script to specify the object (I suggest a dummy user in your test AD environment - the function might still be buggy).
Then please run the script and post the restults!
If everything works as expected we will test multi value attributes. AD attributes: http://www.rlmueller.net/UserAttributes.htm
#include <AD.au3>
_AD_Open()
$sObject = "user-to-modify" ; <== NEEDS TO BE CHANGED BY YOU!
$sAttribute = "Description"
; CLEAR - single value attribute
_AD_ModifyAttribute($sObject, $sAttribute, "Original value", 2) ; Set the original value
If @error Then Exit MsgBox(0, "Single value - Error!", "CLEAR: Set original value returned @error = " & @error & ", @extended = " & @extended)
_AD_ModifyAttributeEX($sObject, $sAttribute, "", 1)
If @error Then Exit MsgBox(0, "Single value - Error!", "CLEAR returned @error = " & @error & ", @extended = " & @extended)
$sReturnValue = _AD_GetObjectAttribute($sObject, $sAttribute)
If @error Then Exit MsgBox(0, "Single value - Error!", "CLEAR: Query new value returned @error = " & @error & ", @extended = " & @extended)
MsgBox(0, "Success!", "Value after CLEAR: " & $sReturnValue & @CRLF & "Expected value: ''")
; UPDATE - single value attribute
_AD_ModifyAttribute($sObject, $sAttribute, "Original value", 2) ; Set the original value
If @error Then Exit MsgBox(0, "Single value - Error!", "UPDATE: Set original value returned @error = " & @error & ", @extended = " & @extended)
_AD_ModifyAttributeEX($sObject, $sAttribute, "UPDATE", 2)
If @error Then Exit MsgBox(0, "Single value - Error!", "UPDATE returned @error = " & @error & ", @extended = " & @extended)
$sReturnValue = _AD_GetObjectAttribute($sObject, $sAttribute)
If @error Then Exit MsgBox(0, "Single value - Error!", "UPDATE: Query new value returned @error = " & @error & ", @extended = " & @extended)
MsgBox(0, "Success!", "Value after UPDATE: " & $sReturnValue & @CRLF & "Expected value: 'UPDATE'")
; APPEND - single value attribute - APPEND should work the same way as UPDATE
_AD_ModifyAttribute($sObject, $sAttribute, "Original value", 2) ; Set the original value
_AD_ModifyAttributeEX($sObject, $sAttribute, "APPEND", 3)
$sReturnValue = _AD_GetObjectAttribute($sObject, $sAttribute)
If @error Then Exit MsgBox(0, "Single value - Error!", "APPEND returned @error = " & @error & ", @extended = " & @extended)
MsgBox(0, "Success!", "Value after APPEND: " & $sReturnValue & @CRLF & "Expected value: 'APPEND'")
; DELETE - single value attribute - DELETE should work the same way as CLEAR
_AD_ModifyAttribute($sObject, $sAttribute, "Original value", 2) ; Set the original value
_AD_ModifyAttributeEX($sObject, $sAttribute, "DELETE", 4)
$sReturnValue = _AD_GetObjectAttribute($sObject, $sAttribute)
If @error Then Exit MsgBox(0, "Single value - Error!", "DELETE returned @error = " & @error & ", @extended = " & @extended)
MsgBox(0, "Success!", "Value after DELETE: " & $sReturnValue & @CRLF & "Expected value: ''")
_AD_Close()
Exit
; #FUNCTION# ====================================================================================================================
; Name...........: _AD_ModifyAttribute
; Description ...: Modifies an attribute of the given object to the value specified.
; Syntax.........: _AD_ModifyAttribute($sObject, $sAttribute[, $vValue = ""[, $iOption = 1]])
; Parameters ....: $sObject - Object (user, group ...) to add/delete/modify an attribute (sAMAccountName or FQDN)
; $sAttribute - Attribute to add/delete/modify
; $vValue - Optional: Value(s) to modify the attribute with. Use a blank string ("") to remove all values (default).
; +$vValue can be a single value (as a string) or a multi-value (as a zero-based one-dimensional array)
; $iOption - Optional: Indicates the mode of modification: Clear, Update, Append, Delete.
; |1 - CLEAR: remove all value(s) from the attribute (default when $vValue = "" or Default)
; |2 - UPDATE: replace the current value(s) with the specified value(s)
; |3 - APPEND: append the specified value(s) to the existing values(s)
; |4 - DELETE: delete the specified value(s) from the object
; Return values .: Success - 1
; Failure - 0, sets @error to:
; |1 - $sObject does not exist
; |2 - Parameter $iOption is invalid. needs to be in the range1 to 4.
; |x - Error returned by SetInfo method (Missing permission etc.)
; Author ........: Jonathan Clelland
; Modified.......: water
; Remarks .......:
; Related .......: _AD_GetObjectAttribute, _AD_GetObjectProperties, _AD_AddEmailAddress
; Link ..........: http://msdn.microsoft.com/en-us/library/aa746353(VS.85).aspx (ADS_PROPERTY_OPERATION_ENUM Enumeration)
; Example .......: Yes
; ===============================================================================================================================
Func _AD_ModifyAttributeEX($sObject, $sAttribute, $vValue = "", $iOption = 1)
Local $aValue[1]
If $vValue = Default Then $vValue = ""
If IsArray($vValue) Then
$aValue = $vValue
Else
; Move the string value to the array
$aValue[0] = $vValue
EndIf
If $iOption = Default Then $iOption = 1
If $iOption < 1 Or $iOption > 4 Then Return SetError(2, 0, 0)
If Not _AD_ObjectExists($sObject) Then Return SetError(1, 0, 0)
Local $sProperty = "sAMAccountName"
If StringMid($sObject, 3, 1) = "=" Then $sProperty = "distinguishedName" ; FQDN provided
$__oAD_Command.CommandText = "<LDAP://" & $sAD_HostServer & "/" & $sAD_DNSDomain & ">;(" & $sProperty & "=" & $sObject & ");ADsPath;subtree"
Local $oRecordSet = $__oAD_Command.Execute ; Retrieve the ADsPath for the object
Local $sLDAPEntry = $oRecordSet.fields(0).Value
Local $oObject = __AD_ObjGet($sLDAPEntry) ; Retrieve the COM Object for the object
$oObject.GetInfo
Switch $iOption
Case 1
$oObject.PutEx(1, $sAttribute, 0) ; CLEAR: remove all the property value(s) from the object
Case 2
$oObject.PutEx(2, $sAttribute, $aValue) ; UPDATE: replace the current value(s) with the specified value(s)
Case 3
$oObject.PutEx(3, $sAttribute, $aValue) ; APPEND: append the specified value(s) to the existing values(s)
Case 4
$oObject.PutEx(4, $sAttribute, $aValue) ; DELETE: delete the specified value(s) from the object
EndSwitch
$oObject.SetInfo
If @error Then Return SetError(@error, 0, 0)
Return 1
EndFunc ;==>_AD_ModifyAttributeEX
41
1
