GUI Fade In / Fade out

[insignia96]

This is a simple little UDF I made that fades your GUI in with pure AutoIt.

To show your GUI simply call the _FadeGUIIn() function, the only parameter is a handle to the GUI, and it will fade in. here is the UDF:

expandcollapse popup

#include-once

; #INDEX# =======================================================================================================================
; Title .........: GUI Fading Script
; Description ...: This module contains functions used to fade a GUI in and out with pure AutoIt code.
; AutoIt Version.: 3.3.0.0 (Current Release)
; Author ........: Insignia96 (iWoW Programming)
; ===============================================================================================================================


; ===============================================================================================================================

; #NO_DOC_FUNCTION# =============================================================================================================
; Not working/documented/implimented at this time
; ===============================================================================================================================
; NONE
; ===============================================================================================================================

; ===============================================================================================================================
; #CURRENT# =====================================================================================================================
;_FadeGUIIn
;_FadeGUIOut
; ===============================================================================================================================


; #DECLARES# ;===============================================================================
;
Global $GUIFADE_MAXTRANS = 255 ; the current max transparency level
;
; ;==========================================================================================

; #FUNCTION# ;===============================================================================
;
; Name...........: _FadeGUIIn
; Description ...: Gradually shows a GUI.
; Syntax.........: _FadeGUIIn( $hWnd )
; Parameters ....: $hWnd - Handle to GUI you wish to fade in.
;                  $iMax - The transparency level to stop at. (0-255, 0 = hidden, 255 = fully shown)
; Return values .: None
; Author ........: Insignia96 (iWoW Programming)
; Modified.......: Saturday, December 12, 2009
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......; Yes
;
; ;==========================================================================================

Func _FadeGUIIn($hWnd,$iMax=255)

    $GUIFADE_MAXTRANS = $iMax

    WinSetTrans($hWnd, "", 0)

    GUISetState(@SW_SHOW)

    Local $delay = 0

    For $i = 1 To $iMax Step 1
        WinSetTrans($hWnd, "", $i)
        Sleep($delay)
    Next

EndFunc   ;==>_FadeGUIIn

; #FUNCTION# ;===============================================================================
;
; Name...........: _FadeGUIOut
; Description ...: Gradually fades a GUI out.
; Syntax.........: _FadeGUIOut( $hWnd )
; Parameters ....: $hWnd - Handle to GUI you wish to fade out.
; Return values .: None
; Author ........: Insignia96 (iWoW Programming)
; Modified.......: Saturday, December 12, 2009
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......; Yes
;
; ;==========================================================================================

Func _FadeGUIOut($hWnd)
    Local $delay = 0

    For $i = $GUIFADE_MAXTRANS To 0 Step -1
        WinSetTrans($hWnd, "", $i)
        Sleep($delay)
    Next

    GUISetState(@SW_HIDE)
EndFunc   ;==>_FadeGUIOut

And I also provided an example script:

; ~~~~~~~~~~~ INCLUDES ~~~~~~~~~~

#include "GUIFade.au3"

; ~~~~~~~~~~~ END INCLUDES ~~~~~~~~~~~

; ~~~~~~~~~~~ INTERNAL CONFIGURATION ~~~~~~~~~~

Global $width = 350 ; Width of GUI to be created.

Global $height = 350 ; Height of GUI to be created.

Global $title = "Test GUI" ; Title of GUI to be created.

Global $max_trans = 255 ; How transparent do you want the window, 0 = hidden, 255 = fully shown

; ~~~~~~~~~~~ END CONF ~~~~~~~~~~~

Global $pos[2]
$pos[0] = @DesktopWidth / 2 - $width / 2 ; X (left) position of window
$pos[1] = @DesktopHeight / 2 - $height / 2 ; Y (top) Position of window

Global $hGUI = GUICreate($title & " - w/ Fade in/out", $width, $height, $pos[0], $pos[1])
_FadeGUIIn($hGUI,$max_trans)

While 1
    Local $nMsg = GUIGetMsg()

    Switch $nMsg
        Case -3
            _FadeGUIOut($hGUI)
            Exit
    EndSwitch
WEnd

I also made a zip file for download here: GUIFade.zip

Enjoy! (and please comment!)

EDIT: Fixed title

EDIT2: added $iMax parameter (GEOSoft's idea)

WARNING: The $iMax Parameter may cause problems when using the _GUIFadeOut() function on multiple GUI's

Edited December 12, 2009 by insignia96

[GEOSoft]

That works.

I just find it easier to use the DLL method.

DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hWnd, "int", $tFade, "long", $Fade)

Where $tFade is the fade in/out time And $Fade is 0x80000 for fade in and 0x90000 for fade out

[insignia96]

I just wanted it in "Pure AutoIt", also im pretty sure this way works faster.

[GEOSoft]

No problem with that but can I suggest a minor change in them? Just to allow for those windows where someone wants semi-transparency, add a parameter to replace the 255 and another to control $delay ($iDelay below) so people can choose the transition rate.

Func _FadeGUIIn($hWnd, $iMax = 255, $iDelay = 0)

    WinSetTrans($hWnd, "", 0)

    GUISetState(@SW_SHOW)

    For $i = 1 To $iMax Step 1
        WinSetTrans($hWnd, "", $i)
        Sleep($iDelay)
    Next

EndFunc   ;==>_FadeGUIIn

[insignia96]

No problem with that but can I suggest a minor change in them? Just to allow for those windows where someone wants semi-transparency, add a parameter to replace the 255 and another to control $delay ($iDelay below) so people can choose the transition rate.

Func _FadeGUIIn($hWnd, $iMax = 255, $iDelay = 0)

    WinSetTrans($hWnd, "", 0)

    GUISetState(@SW_SHOW)

    For $i = 1 To $iMax Step 1
        WinSetTrans($hWnd, "", $i)
        Sleep($iDelay)
    Next

EndFunc   ;==>_FadeGUIIn

Actually, it had a delay parameter at first, however the sleep function could only do 10ms between increments, that meant that it was really slow, so i deleted it. I will add the semi-transparency option.

[AdmiralAlkex]

I just wanted it in "Pure AutoIt", also im pretty sure this way works faster.

What?

That works.

I just find it easier to use the DLL method.

DllCall("user32.dll", "int", "AnimateWindow", "hwnd", $hWnd, "int", $tFade, "long", $Fade)

Where $tFade is the fade in/out time And $Fade is 0x80000 for fade in and 0x90000 for fade out

[GEOSoft]

What?

I also forgot to mention that $tFade is in milliseconds

[cramaboule]

I did that long time ago !!!

see my sign "Ending Script Nicely"

Cramaboule !!!

[GEOSoft]

I did that long time ago !!!

see my sign "Ending Script Nicely"

Cramaboule !!!

So have several others. People have been writing that since WinSetTrans() was first added to AutoIt, none the less, he made it work which was good practice.

[nugame]

No problem with that but can I suggest a minor change in them? Just to allow for those windows where someone wants semi-transparency, add a parameter to replace the 255 and another to control $delay ($iDelay below) so people can choose the transition rate.

Func _FadeGUIIn($hWnd, $iMax = 255, $iDelay = 0)

    WinSetTrans($hWnd, "", 0)

    GUISetState(@SW_SHOW)

    For $i = 1 To $iMax Step 1
        WinSetTrans($hWnd, "", $i)
        Sleep($iDelay)
    Next

EndFunc   ;==>_FadeGUIIn

I put in the delay. good thing to do. I agree with the dll concept. DLL is more stable to less frequent changes. I did a major autoit automation for client. when it came to update for more features, had to update autoit on each site which should be done anyhow. Just like to change one for all sites. My two cents worth. thanks. I will use this one you did.

[Michel Claveau]

Hi!

Difference between Autoit_trans method and DLL method:

- DLL method delete shadow of the window before fadein (and re-set after fadeout).

- Autoit_trans keep shadow during run.

(under Win 7-32 + Aero + shadow)

Edited December 28, 2009 by Michel Claveau

[KaFu]

Also you should change GUISetState(xxx) to GUISetState(xxx, $hWnd), otherwise the function always refers to the last gui handle used.