GUICtrlSetOnEvent with MouseDown

[Manfred]

I made a simple GUI:

GUICtrlSetOnEvent($Button_Stop, "Button_Stop")

It works, the Func Button_Stop is executed, but after relase the mousebutton, not in time when clicking left.

Is there any way, to execute it at once with MouseDown?

Regards

Manfred

[Melba23]

Manfred,

Buttons only activate on mouse button up. Try using a label if you need to get a response on mouse button down:

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "OnExit")

GUICtrlCreateLabel("Test", 10, 10, 80, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetOnEvent(-1, "Test")
GUICtrlSetBkColor(-1, 0xFF0000)

GUISetState()

While 1
    Sleep(10)
WEnd

Func Test()
    ConsoleWrite("Hit" & @CRLF)
EndFunc

Func OnExit()
    Exit
EndFunc

Or you could use something like this which ignores the actual button and looks for a click on the rectangle of the button coordinates (credit to Malkey for the basic idea):

expandcollapse popup

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "OnExit")

GUICtrlCreateButton("Test", 10, 10, 80, 30)
; Note no event attached

GUISetState()

; When left mouse button pressed - check if within button rectangle
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "InRect")

While 1
    Sleep(10)
WEnd

Func OnExit()
    Exit
EndFunc

Func InRect()

    ; Set client mouse coord option and save current setting
    $iOldOpt = Opt("MouseCoordMode", 2)
    ; Set up rectangle at button coords
    Local $tRect = DllStructCreate("int Left;int Top;int Right;int Bottom")
    DllStructSetData($tRect, "Left", 10)
    DllStructSetData($tRect, "Top", 10)
    DllStructSetData($tRect, "Right", 90)
    DllStructSetData($tRect, "Bottom", 40)
    ; Get mouse position
    Local $aPos = MouseGetPos()
    ; See if mouse over rectangle
    Local $aResult = DllCall("User32.dll", "int", "PtInRect", "ptr", DllStructGetPtr($tRect), "int", $aPos[0], "int", $aPos[1])
    If @error Then Return
    ; Act if over button
    If $aResult[0] <> 0 Then ConsoleWrite("Hit" & @CRLF)
    ; Reset original mouse coord option
    Opt("MouseCoordMode", $iOldOpt)

EndFunc

I hope one of these is useful. >_<

M23

[Manfred]

Buttons only activate on mouse button up. Try using a label if you need to get a response on mouse button down:

GUICtrlCreateLabel("Test", 10, 10, 80, 30, BitOR($SS_CENTER, $SS_CENTERIMAGE), $WS_EX_DLGMODALFRAME)

Or you could use something like this which ignores the actual button and looks for a click on the rectangle of the button coordinates (credit to Malkey for the basic idea):

I hope one of these is useful. >_<

Many thanks, also for your very fast response!

Using labels instead of button is my way, by adding '$WS_EX_DLGMODALFRAME' it looks like a button. I did and it works as needed! Also I can play with colors for it - in the future.

The use of the rectangle I think is not possible because of more than one button.

Best regards and many thanks

Manfred

[Melba23]

Manfred,

And thank you for the $WS_EX_DLGMODALFRAME tip. I do enjoy this forum. >_<

M23

[Manfred]

And thank you for the $WS_EX_DLGMODALFRAME tip. I do enjoy this forum.

Don't forget:

#include <WindowsConstants.au3> for this >_<

[Info]

$question = "" ;your question here

If StringInStr($question,"GUI") <> 0 Then MsgBox(0,'IT IS GUI RELATED!',"POST IT IN THE GUI SUPPORT FORUM! :)")

Edited August 25, 2009 by Info