FileOpenDialogWithPreview

[trancexx]

It's FileOpenDialog with preview .

Called from msvfw32.dll. Looks like shit IMHO but gives the option to preview media files before selecting one.

All you need to do is browse to some folder with some music or video and you will get an option to preview it.

Like I said, I don't like it but hey it's just me. For example I don't like Robbie Williams, Lady Gaga or F1 races too.

Script with one example:

expandcollapse popup

Global $sSelected = _FileOpenDialogWithPreview("Open with preview", "", "Music files (*.mp3;*.wav;*.wma)| Video files (*.avi)| All files (*.*)", "")

ConsoleWrite("!@error = " & @error & @CRLF)
ConsoleWrite("Selected: " & $sSelected & @CRLF)





Func _FileOpenDialogWithPreview($sTitle = "Open", $sInitDir = "", $sFilter = "All Files (*.*)", $sDefaultName = "", $hWnd = 0)

    ; OPENFILENAME structure:
    Local $tOPENFILENAME = DllStructCreate("dword StructSize;" & _
            "hwnd Owner;" & _
            "ptr Instance;" & _
            "ptr Filter;" & _
            "ptr  CustomFilter;" & _
            "dword MaxCustFilter;" & _
            "dword FilterIndex;" & _
            "ptr File;" & _
            "dword MaxFile;" & _
            "ptr FileTitle;" & _
            "dword MaxFileTitle;" & _
            "ptr InitialDir;" & _
            "ptr Title;" & _
            "dword Flags;" & _
            "ushort FileOffset;" & _
            "ushort FileExtension;" & _
            "ptr DefExt;" & _
            "ptr CustData;" & _
            "ptr Hook;" & _
            "ptr TemplateName;" & _
            "ptr Reserved;" & _
            "dword SizeReserved;" & _
            "dword FlagsEx")

    ; Set size and owner:
    DllStructSetData($tOPENFILENAME, "StructSize", DllStructGetSize($tOPENFILENAME))
    DllStructSetData($tOPENFILENAME, "Owner", $hWnd)

    ; Filter job:
    Local $tagFilter
    Local $aArray = StringRegExp($sFilter & "|", "\s*(.*?)\s*\((.*?)\)\|", 3)

    For $i = 0 To UBound($aArray) - 1
        $tagFilter &= "wchar[" & StringLen($aArray[$i]) + 1 & "];"
    Next

    $tagFilter &= "wchar"

    Local $tFilter = DllStructCreate($tagFilter)
    For $i = 0 To UBound($aArray) - 1
        DllStructSetData($tFilter, $i + 1, $aArray[$i])
    Next

    DllStructSetData($tOPENFILENAME, "Filter", DllStructGetPtr($tFilter, 1))

    ; Path job:
    Local $tPath = DllStructCreate("wchar[32767]")
    DllStructSetData($tPath, 1, $sDefaultName)

    DllStructSetData($tOPENFILENAME, "File", DllStructGetPtr($tPath))
    DllStructSetData($tOPENFILENAME, "MaxFile", 32767)

    ; Title job:
    Local $tTitle = DllStructCreate("wchar[" & StringLen($sTitle) + 1 & "]")
    DllStructSetData($tTitle, 1, $sTitle)

    DllStructSetData($tOPENFILENAME, "Title", DllStructGetPtr($tTitle))

    ; Initial dir job:
    Local $tInitDir = DllStructCreate("wchar[" & StringLen($sInitDir) + 1 & "]")
    DllStructSetData($tInitDir, 1, $sInitDir)

    DllStructSetData($tOPENFILENAME, "InitialDir", DllStructGetPtr($tInitDir))

    ; Call the function
    DllCall("msvfw32.dll", "int", "GetOpenFileNamePreviewW", "ptr", DllStructGetPtr($tOPENFILENAME))

    ; Get wanted string
    Local $sOut = DllStructGetData(DllStructCreate("wchar[32767]", DllStructGetData($tOPENFILENAME, "File")), 1)

    Return SetError($sOut = False, 0, $sOut)

EndFunc   ;==>_FileOpenDialogWithPreview

[MrCreatoR]

Thanks, once i've searched for such dialog. Very usefull!

[RobertBedrosian]

It's FileOpenDialog with preview .

Called from msvfw32.dll. Looks like shit IMHO but gives the option to preview media files before selecting one.

All you need to do is browse to some folder with some music or video and you will get an option to preview it.

Like I said, I don't like it but hey it's just me. For example I don't like Robbie Williams, Lady Gaga or F1 races too.

Thanks, nice work!

Script with one example:

expandcollapse popup

Global $sSelected = _FileOpenDialogWithPreview("Open with preview", "", "Music files (*.mp3;*.wav;*.wma)| Video files (*.avi)| All files (*.*)", "")

ConsoleWrite("!@error = " & @error & @CRLF)
ConsoleWrite("Selected: " & $sSelected & @CRLF)





Func _FileOpenDialogWithPreview($sTitle = "Open", $sInitDir = "", $sFilter = "All Files (*.*)", $sDefaultName = "", $hWnd = 0)

    ; OPENFILENAME structure:
    Local $tOPENFILENAME = DllStructCreate("dword StructSize;" & _
            "hwnd Owner;" & _
            "ptr Instance;" & _
            "ptr Filter;" & _
            "ptr  CustomFilter;" & _
            "dword MaxCustFilter;" & _
            "dword FilterIndex;" & _
            "ptr File;" & _
            "dword MaxFile;" & _
            "ptr FileTitle;" & _
            "dword MaxFileTitle;" & _
            "ptr InitialDir;" & _
            "ptr Title;" & _
            "dword Flags;" & _
            "ushort FileOffset;" & _
            "ushort FileExtension;" & _
            "ptr DefExt;" & _
            "ptr CustData;" & _
            "ptr Hook;" & _
            "ptr TemplateName;" & _
            "ptr Reserved;" & _
            "dword SizeReserved;" & _
            "dword FlagsEx")

    ; Set size and owner:
    DllStructSetData($tOPENFILENAME, "StructSize", DllStructGetSize($tOPENFILENAME))
    DllStructSetData($tOPENFILENAME, "Owner", $hWnd)

    ; Filter job:
    Local $tagFilter
    Local $aArray = StringRegExp($sFilter & "|", "\s*(.*?)\s*\((.*?)\)\|", 3)

    For $i = 0 To UBound($aArray) - 1
        $tagFilter &= "wchar[" & StringLen($aArray[$i]) + 1 & "];"
    Next

    $tagFilter &= "wchar"

    Local $tFilter = DllStructCreate($tagFilter)
    For $i = 0 To UBound($aArray) - 1
        DllStructSetData($tFilter, $i + 1, $aArray[$i])
    Next

    DllStructSetData($tOPENFILENAME, "Filter", DllStructGetPtr($tFilter, 1))

    ; Path job:
    Local $tPath = DllStructCreate("wchar[32767]")
    DllStructSetData($tPath, 1, $sDefaultName)

    DllStructSetData($tOPENFILENAME, "File", DllStructGetPtr($tPath))
    DllStructSetData($tOPENFILENAME, "MaxFile", 32767)

    ; Title job:
    Local $tTitle = DllStructCreate("wchar[" & StringLen($sTitle) + 1 & "]")
    DllStructSetData($tTitle, 1, $sTitle)

    DllStructSetData($tOPENFILENAME, "Title", DllStructGetPtr($tTitle))

    ; Initial dir job:
    Local $tInitDir = DllStructCreate("wchar[" & StringLen($sInitDir) + 1 & "]")
    DllStructSetData($tInitDir, 1, $sInitDir)

    DllStructSetData($tOPENFILENAME, "InitialDir", DllStructGetPtr($tInitDir))

    ; Call the function
    DllCall("msvfw32.dll", "int", "GetOpenFileNamePreviewW", "ptr", DllStructGetPtr($tOPENFILENAME))

    ; Get wanted string
    Local $sOut = DllStructGetData(DllStructCreate("wchar[32767]", DllStructGetData($tOPENFILENAME, "File")), 1)

    Return SetError($sOut = False, 0, $sOut)

EndFunc   ;==>_FileOpenDialogWithPreview

[AdmiralAlkex]

Amazing, I can't remember ever seeing that dialog before. Looks like shit thou and doesn't work any good with modern video formats.

Also I like Robbie Williams and Lady Gaga.... Well a few of their songs anyway. And a F1 race every once in a while.

[danielkza]

Amazing, I can't remember ever seeing that dialog before. Looks like shit thou and doesn't work any good with modern video formats.

Also I like Robbie Williams and Lady Gaga.... Well a few of their songs anyway. And a F1 race every once in a while.

I don't like Lady Gaga at all, but I have to say the South Park version is a lot better

http://kotaku.com/5392643/lady-gagas-poker-face-comes-to-rock-band-+-in-south-park

[Dolemite50]

It definitely looks 80's but might come in handy.

Was I supposed to get an actual preview of the file? (I only got a preview of the list of files)

Thanks!

[trancexx]

It definitely looks 80's but might come in handy.

Was I supposed to get an actual preview of the file? (I only got a preview of the list of files)

Thanks!

Click once (not twice) on one of those files to select it and you'll get player controls below 'Cancel'.

[Dolemite50]

Ahh, thanks for the explanation. I was trying "All Files" to preview images.

Do you happen to know how to get the Image Preview dialog?

BTW, this would be great with a facelift. I've yet to find a "File..." dialog written it AutoIt, although there have been some great examples of customizing the Win dialogs. I'm hoping somebody proves me wrong.