Managing two forms

[motionman95]

I have two forms - one is the main form, and another is the settings dialog. I want to be able to easily open the settings form and keep the main form inaccessible while the settings form is open.

Thanks in advance!

[Melba23]

motionman95,

And what have you tried yourself so far?

M23

[motionman95]

motionman95,

And what have you tried yourself so far?

M23

You don't wanna know - I had to get a new computer because of it.

[Melba23]

motionman95,

I had to get a new computer because of it

I find that rather hard to believe.....

But to give you a clue:

expandcollapse popup

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Settings", 10, 10, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            Settings()
    EndSwitch

WEnd


Func Settings()

    GUISetState(@SW_DISABLE, $HGUI)

    $hSettings_GUI = GUICreate("Settings", 200, 200)

    $hExit = GUICtrlCreateButton("Exit", 10, 10, 80, 30)

    GUISetState()

    While 1

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $hExit
                GUISetState(@SW_ENABLE, $hGUI)
                GUIDelete($hSettings_GUI)
                Return
        EndSwitch

    WEnd

EndFunc

That should do what you want and not destroy anything.....

M23

P.S. When you reply please use the "Add Reply" button at the top and bottom of the page rather then the "Reply" button in the post itself. That way you do not get the contents of the previous post quoted in your reply and the whole thread becomes easier to read.

[motionman95]

Ha ha ha. And actually I did have to get a new computer - apparently I used a script I found on the net that did something exactly opposite of what I wanted...

I have a button and everything already, just figuring out how to set up the forms like in other applications - you run the app, click on the settings button, and whenever you try to click on the main form the settings forum blinks twice, and you can't access the main form until you close the settings dialog...

[Melba23]

motionman95,

The settings form now flashes twice if you click on the main form:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Settings", 10, 10, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            Settings()
    EndSwitch

WEnd

Func Settings()

    GUISetState(@SW_DISABLE, $hGUI)

    $hSettings_GUI = GUICreate("Settings", 100, 100)

    $hExit = GUICtrlCreateButton("Exit", 10, 10, 80, 30)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $hExit
                GUISetState(@SW_ENABLE, $hGUI)
                GUIDelete($hSettings_GUI)
                Return
            Case $GUI_EVENT_PRIMARYDOWN
                $aMousePos = MouseGetPos()
                Local $TPoint = DllStructCreate($tagPoint)
                DllStructSetData($TPoint, "x", MouseGetPos(0))
                DllStructSetData($TPoint, "y", MouseGetPos(1))
                If _WinAPI_WindowFromPoint($TPoint) = $hGUI Then
                    For $i = 1 To 4
                        _WinAPI_FlashWindow($hSettings_GUI)
                        Sleep(100)
                    Next
                EndIf
        EndSwitch
    WEnd

EndFunc

M23

[motionman95]

Wowzers. OK, I'll take a look at that. Thanks!!!

EDIT:

Is there a way to remove the Settings form from the task bar?

Edited May 24, 2010 by motionman95

[Melba23]

motionman95,

You want fries with that?

$hSettings_GUI = GUICreate("Settings", 100, 100, Default, Default, -1, -1, $hGUI)

M23

[motionman95]

motionman95,

You want fries with that?

M23

Yes please! xD

[Melba23]

motionman95,

Then go buy them yourself!

M23