Date format handling

[niubbone]

Hi.

Looking into the forum for date format and date type didn't showed up any result. I'm sure there's something about in forum though.

Anyways, I implemented a little internal calendar in a program based on _DateAdd Function.

_DateAdd wants the date input in the YYYY/MM/DD format.

I need to show up the date in the whole program in DD/MM/YYYY european format.

Checking in the help file I managed to catch up some of the date handling related functions.

But if there is a way to easily convert dates from a format to another remains a mistery to me.

Global $BeginDate="2010/01/01"

Func DayAfter($Date)

Local $NewDate = $Date

$NewDate = _DateAdd('d', 1, $NewDate)

Global $BeginDate=$NewDate

$DateFormatted=StringRight($NewDate,2) & '/' & StringMid($NewDate,6,2) & '/' & StringLeft($NewDate,4)

Return $DateFormatted

EndFunc

This basically adds a day up everytime it's called and convert the date in the Euro Format I need.

There is a fast way of doing it, like some autoit Opt settings or some function to convert it or would be better to create a new one?

[somdcomputerguy]

StringSplit $NewDate, with '/' as the delimiter, ending up with $DateFormatted[1], ..[2], ..[3]. I'm sure there are other ways too, but this comes to my primitive mind..

[jchd]

There are other ways as well: _DateTimeFormat, regexps or pedestrian massaging of substrings like exposed.

What is the problem? Do you estimate these are not fast enough? How many times per second are you going to perform that fransformation into display date style?

[Melba23]

niubbone,

Try _DateTimeFormat - if your PC has the European date settings, you should get the same result - I certainly do:

#include <Date.au3>

Global $BeginDate = "2010/01/01"

ConsoleWrite(DayAfter_1($BeginDate) & @CRLF)

ConsoleWrite(DayAfter_2($BeginDate) & @CRLF)

Func DayAfter_1($Date)
    Local $NewDate = _DateAdd('d', 1, $Date)
    Return StringRight($NewDate, 2) & '/' & StringMid($NewDate, 6, 2) & '/' & StringLeft($NewDate, 4)
EndFunc   ;==>DayAfter_1

Func DayAfter_2($Date)
    Return _DateTimeFormat(_DateAdd('d', 1, $Date), 2)
EndFunc   ;==>DayAfter_2

I also tidied up your function a bit.

M23

[KaFu]

Something like this?

$sDate = "2010/06/24"
MsgBox(0,"",$sDate & @crlf & _SwitchDateFormast($sDate, "dd/MM/yyyy") & @crlf & _SwitchDateFormast(_SwitchDateFormast($sDate, "DD/MM/YYYY")))

Func _SwitchDateFormast($sSwitchDateFormat_Date, $sDateStyle = "yyyy/MM/dd")
    Local Const $DTM_SETFORMAT_ = 0x1032
    ;Local Const $sDateStyle = "yyyy/MM/dd"
    Local $hSwitchDateFormatGUI = GUICreate("")
    Local $cSwitchDateFormat_Date = GUICtrlCreateDate($sSwitchDateFormat_Date, 1, 1, 1, 1)
    GUICtrlSendMsg($cSwitchDateFormat_Date, $DTM_SETFORMAT_, 0, $sDateStyle)
    $sReturn = GUICtrlRead($cSwitchDateFormat_Date)
    GUICtrlDelete($cSwitchDateFormat_Date)
    GUIDelete($hSwitchDateFormatGUI)
    Return $sReturn
EndFunc

[niubbone]

somdcomputerguy

Thanks but that's what i did.

jhcd

thanks, would have liked more code though.

Melba23

Seems best solution. Thanks

KaFu

Thanks but way tooooo advanced for me. Works but I don't get anything there.

Edited June 24, 2010 by niubbone