Sign in to follow this  
Followers 0
Info

Slow reaction with GUIOnEventMode?

3 posts in this topic

Opt("GUIOnEventMode",1)

Global $iClicks

$gui = GUICreate("test")
$hlist = GUICtrlCreateListView("A|B",2,2, 300, 400)
GUISetOnEvent(-3, "_Close", $gui)
For $i = 1 To 20 Step 2
    GUICtrlCreateListViewItem($i & "|" & $i + 1,$hlist)
    GUICtrlSetOnEvent(-1, "_Click")
Next
GUISetState()

While 1
    Sleep(100)
WEnd

Func _Click()
    $iClicks += 1
    ToolTip($iClicks)
EndFunc

Func _Close()
    Exit
EndFunc

I'm trying to capture double clicks on a listview but GUICtrlSetOnEvent reacts too late?

Share this post


Link to post
Share on other sites



Info,

GUICtrlSetOnEvent is not the way to go here - you need to use a message handler: ;)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode",1)

Global $iClicks

$gui = GUICreate("test")
GUISetOnEvent(-3, "_Close", $gui)

$hlist = GUICtrlCreateListView("A|B",2,2, 300, 400)
$hList_Handle = GUICtrlGetHandle(-1)
For $i = 1 To 20 Step 2
    GUICtrlCreateListViewItem($i & "|" & $i + 1,$hlist)
Next

GUISetState()

; Register message handler
GUIRegisterMsg($WM_NOTIFY, "WM_ListView_DoubleClick")

While 1
    Sleep(100)
WEnd

Func _Close()
    Exit
EndFunc

; React to double clicks on ListView
Func WM_ListView_DoubleClick($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam
    Local $tNMHDR = DllStructCreate("int;int;int", $lParam)
    If @error Then Return
    If DllStructGetData($tNMHDR, 1) = $hList_Handle Then
        If DllStructGetData($tNMHDR, 3) = $NM_DBLCLK Then
            $iClicks += 1
            ToolTip($iClicks)
        EndIf
    EndIf
    $tNMHDR = 0
    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_ListView_DoubleClick

Please ask if anything is unclear. :blink:

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

thanks melba :blink:

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0