Sign in to follow this  
Followers 0
zwierzak

ListView getting msg

7 posts in this topic

Hello, here is the Help's example:

Select
            Case $msg = $listview
                MsgBox(0, "listview", "clicked=" & GUICtrlGetState($listview), 2)
        EndSelect

It workns only when I click on the top column. I'd like it to work when i click on each item inside the ListView, not just the title of a column. How to do it?

Share this post


Link to post
Share on other sites



zwierzak,

You have to look for double-clicks on the ListView items as the ListView eats the single-clicks to show the selection.

You do it like this: ;)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; Set flag
$fDblClk = False

$hGUI = GUICreate("Test", 500, 500)

$hLV = GUICtrlCreateListView("Col 1", 10, 10, 200, 200)
$hLV_Handle = GUICtrlGetHandle(-1)

For $i = 1 To 20
    GUICtrlCreateListViewItem("Item " & $i, $hLV)
Next

GUISetState()

; Register "ListView DoubleClick" function
GUIRegisterMsg($WM_NOTIFY, "WM_ListView_DoubleClick")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    : if the ListView was clicked
    If $fDblClk = True Then
        ; Read the item
        $sText = GUICtrlRead($hLV)
        MsgBox(0, "", "You double-clicked the ListView on Item " & $sText)
        ; Reset the flag
        $fDblClk = False
    EndIf

WEnd

; React to double clicks on ListView
Func WM_ListView_DoubleClick($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $wParam
    Local $tNMHDR = DllStructCreate("int;int;int", $lParam)
    If @error Then Return
    ; Is it out ListView that has been clicked?
    If DllStructGetData($tNMHDR, 1) = $hLV_Handle Then
        ; Was it a double click?
        If DllStructGetData($tNMHDR, 3) = $NM_DBLCLK Then
            ; Set the flag
            $fDblClk = True
        EndIf
    EndIf
    $tNMHDR = 0
    Return $GUI_RUNDEFMSG

EndFunc   ;==>WM_ListView_DoubleClick

If you are not too familiar with GUIRegisterMsg, ther is a tutorial in the Wiki which you might find useful. :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Your example doesn't even works for me. I double-click on an item and nothing happens. ^^

Share this post


Link to post
Share on other sites

#5 ·  Posted (edited)

Exchange

Local $tNMHDR = DllStructCreate("int;int;int", $lParam)

with

Local $tNMHDR = DllStructCreate("INT_PTR;INT_PTR;INT", $lParam)

then it should work on x86 and x64...

Edited by KaFu

Share this post


Link to post
Share on other sites

Thank you, now it works correctly

Share this post


Link to post
Share on other sites

KaFu,

We need a tutorial or something about these x86/x64 differences. I am getting very lost. ;)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0