RecFileListToArray - Deprecated

[Melba23]

Spiff59,

I quite agree - our wonderful Help file does get too big sometimes!

But thanks for making me check it out - as the SRE worked for me I wondered why and went looking!

M23

[AZJIO]

Very fast regular expression, if the files are not processed separately, but the whole list

$Mask = StringStripWS(StringRegExpReplace($Mask, "\s*;\s*", "|"), 3)
$Mask = StringRegExpReplace(StringReplace(StringRegExpReplace($Mask, '[][$^.{}()+]', '\\$0'), '?', '.'), '\*+', '.*?')
If $Include Then
$aFileList = StringRegExp($FileList, '(?mi)^(.+\|(?:' & $Mask & '))(?:\r|\z)', 3)
 Else
$FileList = StringRegExpReplace($FileList & @CRLF, '(?mi)^.+\|(' & $Mask & ')\r\n', '')
EndIf

[TopXm]

Hello,

I had not seen it

Sorry, I had not seen it

They are the same for me - can you explain what results you get?

Just a mistake, i use the same var => $Filename for create subfolders and search filter...

which will return the folders containing that file. Is that what you want?

Yes, good

thanks

[Melba23]

TopXM,

Glad I could help - and a belated welcome to the Autoit forum.

M23

[Massi]

Thank you Azjio, yours solution works well with [ in the file name. RFLTA now seems to works well. Thank you also to Melba23 this udf could be very useful in more than one situation.

[Melba23]

Massi,

And a belated welcome to you too.

There will be a new release this weekend when I have caught up with a few things.

M23

[Melba23]

Hi,

New Version - 18 Oct 2011

Changed - The UDF was not finding file/folder names which contained certain characters as these characters were being interpreted as SRE instructions. All such SRE instruction characters - []$^.{}()+- - are now escaped (only some were before) and the UDF will match names which include them.

Thanks to Massi (for reporting the problem) and AZJIO (for providing a solution before I even realised there was a problem!)

New UDF in first post.

M23

[Xandy]

Thank you so much. This update (18 Oct 2011) seems to fix discrepancies I had returning folders only. Sorry no useful criticism, only praise.

Edited October 18, 2011 by songersoft

[sleepydvdr]

I wrote a little GUI application to make it easier to write the code:

expandcollapse popup

; #INDEX# =======================================================================================================================
; Title .........: RecFileListToArray Helper
; AutoIt Version : v3.3.1.1 or higher
; Language ......: English
; Description ...: GUI interface to work with RecFileListToArray
; Note ..........:
; Author(s) .....: RecFileListToArray Helper: sleepydvdr; RecFileListToArray: Melba23
; ===============================================================================================================================

#include <Array.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <RecFileListToArray.au3>

Global $InputPathValue, $error = 0, $folderExcludeValue = ""

$mainGUI = GUICreate("RecFileListToArray Script Helper", 475, 360)

$inputPath = GUICtrlCreateInput("", 16, 32, 217, 21)
$labelInputPath = GUICtrlCreateLabel("Input Path:", 16, 12, 60, 17)
$buttonInputBrowse = GUICtrlCreateButton("Browse", 248, 30, 75, 25)

$labelFileTypeInclude = GUICtrlCreateLabel("File Types To Include (*.* means all file types):", 16, 68, 225, 17)
GUICtrlSetTip(-1, "Separate entries by semicolon. Example: *.doc;*.txt;*.xlsx;*.jpg;*.bmp")
$fileTypeInclude = GUICtrlCreateInput("*.*", 16, 88, 217, 21)
GUICtrlSetTip(-1, "Separate entries by semicolon. Example: *.doc;*.txt;*.xlsx;*.jpg;*.bmp")
$hint = GUICtrlCreateLabel("Hint", 240, 92, 27, 17)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUICtrlSetColor(-1, 0x008000)
GUICtrlSetCursor (-1, 0)

$labelExcludeList = GUICtrlCreateLabel("File Types To Exclude (optional)", 16, 120, 200, 17)
GUICtrlSetTip(-1, "Separate entries by semicolon. Example: *.doc;*.txt;*.xlsx;*.jpg;*.bmp")
$excludedList = GUICtrlCreateInput("", 16, 144, 217, 21)
GUICtrlSetTip(-1, "Separate entries by semicolon. Example: *.doc;*.txt;*.xlsx;*.jpg;*.bmp")

$labelWhatToReturn = GUICtrlCreateLabel("What To Return:", 16, 180, 84, 17)
$comboWhatToReturn = GUICtrlCreateCombo("", 16, 200, 217, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
GUICtrlSetData($comboWhatToReturn, "Return both files and folders|Return files only|Return folders only", "Return both files and folders")

$labelSorting = GUICtrlCreateLabel("Sorting:", 248, 180, 55, 17)
$comboSorting = GUICtrlCreateCombo("", 248, 200, 200, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
GUICtrlSetData($comboSorting, "Not Sorted|Sorted|Sorted with faster algorithm", "Not Sorted")

$labelRecursion = GUICtrlCreateLabel("Recursion:", 16, 236, 50, 17)
$comboRecursion = GUICtrlCreateCombo("", 16, 256, 217, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL)) ; Leave the combo empty here <<<<<<<<<<
GUICtrlSetTip(-1, "If you choose the option of specified depth, you will be prompted when you press the Give Me Code button")
GUICtrlSetData($comboRecursion, "Do not search in subfolders|Search in all subfolders|Search in subfolders to specified depth", "Do not search in subfolders")

$labelReturnType = GUICtrlCreateLabel("Return Type:", 248, 236, 66, 17)
$comboReturnType = GUICtrlCreateCombo("", 248, 256, 200, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL))
GUICtrlSetData($comboReturnType, "Relative to initial path|File/folder name only|Full path included", "Relative to initial path")

$labelFolderExclude = GUICtrlCreateLabel("Folder To Exclude (optional):", 16, 288, 139, 17)
$inputFolderExclude = GUICtrlCreateInput("", 16, 312, 353, 21)
$buttonFolderExclude = GUICtrlCreateButton("Browse", 376, 310, 75, 25)

$Label1 = GUICtrlCreateLabel("RecFileListToArray.au3", 336, 8, 114, 17)
$Label2 = GUICtrlCreateLabel("Written by Melba23", 353, 24, 96, 17)

$giveMeCode = GUICtrlCreateButton("Give Me Code!", 340, 80, 107, 89)

GUISetState(@SW_SHOW)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $buttonInputBrowse
            $InputPathValue = FileSelectFolder("Choose a folder.", "")
            GUICtrlSetData($inputPath, $InputPathValue)
        Case $buttonFolderExclude
            $folderExcludeValue = FileSelectFolder("Choose a folder.", $InputPathValue)
            GUICtrlSetData($inputFolderExclude, $folderExcludeValue)
        Case $giveMeCode
            _ProduceCode()
        Case $hint
            MsgBox(0, "", "You must separate values using a semicolon (;). If you use anything else, your list may not return any data." & @CRLF & @CRLF & "Example: " & @CRLF & "*.doc;*.txt;*.xlsx;*.jpg;*.bmp")
    EndSwitch
WEnd

Func _ProduceCode()
    $InputPathValue = GUICtrlRead($inputPath)
    $fileTypeIncludeValue = GUICtrlRead($fileTypeInclude)
    $excludedListValue = GUICtrlRead($excludedList)
    $whatToReturnValue = GUICtrlRead($comboWhatToReturn)
    $recursionValue = GUICtrlRead($comboRecursion)
    $sortingValue = GUICtrlRead($comboSorting)
    $returnTypeValue = GUICtrlRead($comboReturnType)

    If $whatToReturnValue = "Return both files and folders" Then
        $whatToReturnValue = "0"
    EndIf
    If $whatToReturnValue = "Return files only" Then
        $whatToReturnValue = "1"
    EndIf
    If $whatToReturnValue = "Return folders only" Then
        $whatToReturnValue = "2"
        $fileTypeIncludeValue = "*"
    EndIf
    If $recursionValue = "Do not search in subfolders" Then
        $recursionValue = "0"
    EndIf
    If $recursionValue = "Search in all subfolders" Then
        $recursionValue = "1"
    EndIf
    If $recursionValue = "Search in subfolders to specified depth" Then
        $recursionValue = InputBox("Specify depth", "You chose to search to a specific depth of subfolders to search. What is the depth that you want to search?")
        $recursionValue = "-" & $recursionValue
    EndIf
    If $sortingValue = "Not sorted" Then
        $sortingValue = "0"
    EndIf
    If $sortingValue = "Sorted" Then
        $sortingValue = "1"
    EndIf
    If $sortingValue = "Sorted with faster algorithm" Then
        $sortingValue = "2"
    EndIf
    If $returnTypeValue = "File/folder name only" Then
        $returnTypeValue = "0"
    EndIf
    If $returnTypeValue = "Relative to initial path" Then
        $returnTypeValue = "1"
    EndIf
    If $returnTypeValue = "Full path included" Then
        $returnTypeValue = "2"
    EndIf
    If $folderExcludeValue <> "" Then
        If $whatToReturnValue <> "0" Or $recursionValue <> "1" Then
            MsgBox(0, "Error", "You have chosen to exclude a folder. For this option, you must choose " & '"' & "Return both files and folders" & '"' & " and " & '"' & "Relative to initial path" & '"')
            $error = 1
        Else
            $error = 0
        EndIf
    EndIf

    If $InputPathValue <> "" Or $error = 1 Then
        $outputString = "_RecFileListToArray(" & '"' & $InputPathValue & '"' & ", " & '"' & $fileTypeIncludeValue & '"' & ", " & $whatToReturnValue & ", " & $recursionValue & ", " & $sortingValue & ", " & $returnTypeValue & ", " & '"' & $excludedListValue & '"' & ", " & '"' & $folderExcludeValue & '"' & ")"
        ClipPut($outputString)

        $Form2 = GUICreate("Output", 569, 149)
        $outputWindow = GUICtrlCreateEdit("", 8, 48, 545, 89)
        GUICtrlSetData($outputWindow, $outputString)
        $labelOutputWindow = GUICtrlCreateLabel("Script has been copied to the clipboard!", 16, 8, 377, 28)
        GUICtrlSetFont(-1, 14, 800, 0, "MS Sans Serif")
        GUICtrlSetColor(-1, 0xFF0000)
        $buttonTestScript = GUICtrlCreateButton("Test The Script", 408, 8, 147, 25)
        GUISetState(@SW_SHOW)

        While 1
            $nMsg = GUIGetMsg()
            Switch $nMsg
                Case $GUI_EVENT_CLOSE
                    GUIDelete($Form2)
                    ExitLoop
                Case $buttonTestScript
                    $testScript = _RecFileListToArray($InputPathValue, $fileTypeIncludeValue, Number($whatToReturnValue), Number($recursionValue), Number($sortingValue), Number($returnTypeValue), $excludedListValue, $folderExcludeValue)
                    _ArrayDisplay($testScript)
                    If @error Then
                        MsgBox(0, "", "No data was returned")
                    EndIf
            EndSwitch
        WEnd
    Else
        MsgBox(0, "Error", "You must select an Input Path folder")
    EndIf
EndFunc   ;==>_ProduceCode

Edited October 23, 2011 by sleepydvdr

[Melba23]

sleepydvdr,

Very nice.

Might I make a couple of small observations?

- 1. You are gettting a double entry of the default value in each of the combos - it is better to create them this way:

$comboRecursion = GUICtrlCreateCombo("", 16, 256, 217, 25, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL)) ; Leave the combo empty here <<<<<<<<<<
GUICtrlSetTip(-1, "If you choose the option of specified depth, you will be prompted when you press the Give Me Code button")
GUICtrlSetData($comboRecursion, "Do not search in subfolders|Search in all subfolders|Search in subfolders to specified depth", "Do not search in subfolders") ; Use the "default" parameter here <<<<<<<<<<
;

- 2. Perhaps explain how to separate multiple file types (there has already been one query about it).

M23

[sleepydvdr]

1. Melba23, I did not know that trick with Comboboxes. Thanks for the tip. I have already revised the code in my previous post.

2. When you hover over the box, it gives you a hint about using semicolons. I added the word Hint next to the box and provided a message box explaining it.

Thanks, Melba23!

[Melba23]

sleepydvdr,

When you hover over the box, it gives you a hint about using semicolons

I suppose that makes us 15-all!

M23

Edit: I have added a link to your helper script in the first post.

Edited October 23, 2011 by Melba23

[rolok]

Exactly what I was looking for. Thank you so much!

[JoshuaBarnette]

Thank you, very much! This helped me to finish a project for a client.

Joshua Barnette

[Malkavian99]

I love this script it does exactly what I want it to do, except for one thing. I have found one small problem that I'm sure it is a setting on my part or something I'm not doing. When excluding folders I can exclude the top folder but I'm unable to exclude specific subfolders.

Example:

C:\Users folder - can be excluded and all subfolders under it are excluded as well

C:\Users\Public - I cannot exclude a specific subfolder but still scan the other folders under the Users folder.

I believe it has something to do with the backslash(\). Any help would be appreciated.

Thanks

Michael

[Melba23]

Malkavian99,

Welcome to the AutoIt forum.

There are 2 ways to do what you want with the UDF - but both will require a little effort on your part:

- 1. Get a list of subfolders ignoring the specific one you do not want and then run the UDF again within each of these folders looking for the files - a bit involved.

- 2. Get a list fo files and folders and use the $sExclude_List_Folder parameter (it is ignored in all other cases) - what I would suggest.

Here is a script which shows these options on the "Examples" folder of your AutoIt installation - we will ignore the "Advanced" subfolder in both cases:

#include <Array.au3>
#include <RecFileListToArray.au3>

Local $sProgFiles = @ProgramFilesDir
If @AutoItX64 Then $sProgFiles &= " (x86)"

; Ignore folder when returning folders
$aArray = _RecFileListToArray($sProgFiles & "AutoIt3Examples", "*", 2, 1, 1, 1, "Advanced")
_ArrayDisplay($aArray)

; Ignore folder when returning files and folders
$aArray = _RecFileListToArray($sProgFiles & "AutoIt3Examples", "*", 0, 1, 1, 1, "", "Advanced")
_ArrayDisplay($aArray)

Let us see what is going on in each case:

- 1. Here we are looking for folders only - so the "Exclude" parameter will not return any folders which match. You get a list of all the subfolders in the path bar AutoIt3ExamplesAdvanced - you can then loop through them and use the UDF to get the files.

- 2. Here we can use the $sExclude_List_Folder parameter and get a list of all the subfolders and their files - other than AutoIt3ExamplesAdvanced. Notice that the folders all have a trailing backslash because I added one to the root path - that makes it very easy to distinguish files from folders as you loop through the array (StringRight will do the trick).

I hope one or other of these methods will enable you to do what you require. Please ask if anything is unclear.

M23

[Malkavian99]

Ok. I think I understand and will take a longer look at it while at work tomorrow. I will report back to see what results I get.

Example one and then recycle through might be the way to go. I could scan everything in the top folder and then scan through each entry in the array and pull out the subfolders I want to exclude. This would leave me with the folders that I want to keep. The folders I want to exclude are the same on all my workstations so I could hard code them into the program. Everthing else could be dynamic.

Lets see what I can come up with.

Thank you.

Michael.

[Malkavian99]

I have learned something today. It seems that the _RecFileListToArray doesn't look at the full path when exluding. So 'UsersPublic' it doesn't like, but just 'Public' it likes and excludes 'Public' and all the subfolders, everywhere. This could be a good thing or a bad thing depending on what you want to search for. For me, a good thing.

I don't need to put the full path in the Exclude Folder list (i.e. Users/Public). I just need to put Public and Users/Public will be skipped but the rest of the Users folder will not be skipped.

Since my Excluded Folders is read from a .txt file and then put into a variable, I just need to be specific on what folders I want to exclude in the .txt file. Little more work on my part, but worth it.

Thanks for the help

Michael

Edited December 23, 2011 by Malkavian99

[Melba23]

Malkavian99,

You are correct that _RecFileListToArray does not look at the full path when excluding. As it states:

"Use multiple masks to include/exclude particular names and extensions"

Not paths.

The UDF uses a Regular Expression to identify the folder/filename, so you can exclude "Folder_1", "Folder_2", etc with a simple "Folder_*. If you try to use a path the \ will cause problems as the RegEx engine uses that as a control character - as that character is illegal in folder/filenames it shoudl never appear in the "exclude" parameters.

Glad you got what you wanted out of the UDF. Nice to have a satisfied customer!

M23

[Malkavian99]

Melba23,

How can I check if I am running the latest version of the _RecFileListToArray.