Jump to content
Sign in to follow this  
daniel227

create new directory / make new folder. pls help.

Recommended Posts

daniel227

hello everybody!

i'm sure this is a noob question, please forgive me. i did try the search/faq beforehand.

i would like to create an executable (let's call it nf.exe) that creates a new folder in the currently open window, so basically an equivalent to alt+f+w+f. a bit more elegant if possible (without menus flickering).

my shell (bbClean) has a feature that lets me define hotkeys, so i would use that to run nf.exe.

nf.exe could go like this: wait for input+enter (no echo required), then create dir named input, or it could be the windows way (New Folder..(2)..(3)..) or some such. as soon as that is done the program exits.

i don't know if this is a good solution, but it should be fast enough and no need to have another process running all the time.

but i'm open to suggestions, anything that makes creating a new folder a 1 keystroke thing.

i'm a bit surprised that i didn't find more on the topic, mayb it's so simple there's no need to discuss it...

thanks in advance and excuse my stupidity/laziness!

d.

ps:

i tried compiling this:

but it didn't work.

Share this post


Link to post
Share on other sites
hannes08

Hi daniel,

for the input you could use an InputBox:

$s_folder = InputBox("foldername", "enter a name:","","",100,50,-1,-1,5)

This creates an input box that stays 5 seconds (last parameter).

Check if $s_folder is empty (if empty there was no input).

If you have a valid name, you could send the standard windows keys, and automate it like that. Or you could try and read the current folder from the open window and create a new folder with DirCreate().

:unsure:


Regards,Hannes[spoiler]If you can't convince them, confuse them![/spoiler]

Share this post


Link to post
Share on other sites
hannes08

An Example,

just out of curiosity:

_newfolder()

Func _newfolder()
    WinWaitActive("[CLASS:ExploreWClass]")
    $s_folders = WinGetText("[CLASS:ExploreWClass]")
    $a_temp = StringSplit($s_folders, @CRLF)
    If $a_temp[0] > 1 Then
        $s_folders = $a_temp[1]
    EndIf
    $s_f = InputBox("foldername", "enter a name:","","",100,50,-1,-1,5)
    
    If @error = 0 Then
        DirCreate($s_folders & "\" & $s_f)
    ElseIf @error = 2 Then
        $s_z = ""
        $i = 0
        While 1
            $rc = FileExists($s_folders & "\New Folder" & $s_z)
            If $rc = 0 Then
                DirCreate($s_folders & "\New Folder" & $s_z)
                ExitLoop
            Else
                $i += 1
                $s_z = " (" & $i & ")"
            EndIf
        WEnd
    EndIf
EndFunc

:unsure:

Edit:

Replace the function call _newfolder() on top of the script with:

While 1
    If WinActive("[CLASS:ExploreWClass]") Then
        HotKeySet("!g", "_newfolder")
    Else
        HotKeySet("!g")
    EndIf
    sleep(10)
WEnd
Exit

And you can set your own Hotkeys. Note: the program has to run all the time.

Edited by Hannes123

Regards,Hannes[spoiler]If you can't convince them, confuse them![/spoiler]

Share this post


Link to post
Share on other sites
daniel227

thanks for your answer!

i tried compiling what you gave me, also adding the last bit, but it didn't really do anything, was just hanging there in the tray...

but i found this: send("!fwf") - compiling that gives me a little proggy to which i can assign a hotkey and it makes a new folder the good old windows way.

a satisfying solution, if not perfect (just for a moment the file menu flickers. also, i think i remember situations where this doesn´t work because the key combo alt-f does something different).

still i wonder what you wanted to show me?

i'm really not a programmer at all, i downloaded autoit for this one specific task...

but thanks anyway, and if you care to continue mayb we can find a better solution.

d.

Share this post


Link to post
Share on other sites
jasonkhoo87

thanks for your answer!

i tried compiling what you gave me, also adding the last bit, but it didn't really do anything, was just hanging there in the tray...

but i found this: send("!fwf") - compiling that gives me a little proggy to which i can assign a hotkey and it makes a new folder the good old windows way.

a satisfying solution, if not perfect (just for a moment the file menu flickers. also, i think i remember situations where this doesn´t work because the key combo alt-f does something different).

still i wonder what you wanted to show me?

i'm really not a programmer at all, i downloaded autoit for this one specific task...

but thanks anyway, and if you care to continue mayb we can find a better solution.

d.

I have create this application long time ago. Just check it out. Source code not available. Sorry.

Download here to try:

https://www.dropbox.com/s/gf46k1ro1w62zt1/New%20Folder%20Maker%20v0.5.rar

Share this post


Link to post
Share on other sites
MystikSpiral

^ I don't see a "report post" button, but this is clearly spam at best, malware at worst.

Share this post


Link to post
Share on other sites
jasonkhoo87

^ I don't see a "report post" button, but this is clearly spam at best, malware at worst.

Do you refer to my post as spam/malware? I'm creating it with clean source code. no malware code. I share it. So, it up to you want to trust it or not.

Share this post


Link to post
Share on other sites
Melba23

MystikSpiral,

I don't see a "report post" button

And what do you think the "Report" link in the line of actions at the bottom right of the post is there for? Decoration? :)

this is clearly spam at best, malware at worst

And how do you know? Please read this before you make any future accusations. ;)

jasonkhoo87,

I cannot download your file - can you make sure the link is correct Nothing malicious with that file at all. :)

M23

Edited by Melba23
Now examined file

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
JLogan3o13

I was able to download and run the file on a VM. I see no evidence of malware or any problems with it. It does what it says; creates a new folder.


√-1 2^3 ∑ π, and it was delicious!

Share this post


Link to post
Share on other sites
MystikSpiral

lol Okay. Well then he's the first person I've ever seen anywhere who registers just to share a perfectly clean exe

Share this post


Link to post
Share on other sites
AZJIO

source - http://forum.script-coding.com/viewtopic.php?id=2259

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=F7.ico
#AutoIt3Wrapper_outfile=..BinF7.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Res_Comment=This program help you creating New folder in Explorer by pressing F7 hotkey.
#AutoIt3Wrapper_Res_Description=Press F7 in Explorer to create New folder.
#AutoIt3Wrapper_Res_Fileversion=1.0.4.16
#AutoIt3Wrapper_Res_LegalCopyright=© alexii & Script-Coding.Info Team, 2008.
#AutoIt3Wrapper_Res_Language=1049
://////=__=
://////=__=...
://////=__=://///= test only!
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#Include <GUIConstants.au3>
#Include <File.au3>
#Include <Process.au3>
#Include <GuiListView.au3>
#Include <Misc.au3>
#Include <WinAPI.au3>


Local $strIniFileName

Local $boolUseClipboard, $boolShowNotification, $boolChangeFolder, $boolAutorun
Local $mnuUseClipboard,  $mnuShowNotification,  $mnuChangeFolder,  $mnuAutorun, $mnuAbout, $mnuQuit

Local $intHWND
Local $strFolder, $strParentFolder

Local $objComErrorHandler
Local $objShell
Local $objFolder

Local $strFolderTemplate

Local $frmAbout
Local $lblHomePage
Local $boolHoverlblHomePage = False
Local $boolDoneAbout

Local $boolScriptlDone


AutoItSetOption("MustDeclareVars", 1)
AutoItSetOption("ExpandEnvStrings", 1)
AutoItSetOption("GUIOnEventMode", 1)
AutoItSetOption("TrayMenuMode",1)
AutoItSetOption("TrayOnEventMode",1)
AutoItSetOption("TrayIconHide",1)

If _Singleton("F7", 1) = 0 Then
    Msgbox(48, "Warning", "Another occurence F7 is already running", 5)
    
    Exit(1)
EndIf

fnReadOption()
fnCreateTrayMenu()
$strFolderTemplate = fnGetFolderTemplate()

If $boolShowNotification Then
    fnTrayInfoShow("F7", "Press F7 in Explorer to create New folder" & @CRLF & "Right click here for Option", 1, 3)
EndIf

$objComErrorHandler = ObjEvent("AutoIt.Error","fnComErrorHandler")
$objShell = ObjCreate("Shell.Application")

HotKeySet("{F7}", "fnF7")

$boolScriptlDone = False

Do
    Sleep(1000)
Until $boolScriptlDone

$objShell = 0

Exit(0)
;=============================================================================


;=============================================================================
; Read options
;=============================================================================
Func fnReadOption()
    $strIniFileName = fnGetIniFileName(@ScriptFullPath)
    
    $boolShowNotification = _Iif(IniRead($strIniFileName, "Main", "ShowNotification", "1") == "1", True, False)
    $boolUseClipboard     = _Iif(IniRead($strIniFileName, "Main", "UseClipboard",     "0") == "1", True, False)
    ;$boolChangeFolder     = _Iif(IniRead($strIniFileName, "Main", "ChangeFolder",     "0") == "1", True, False)
    $boolAutorun          = _Iif(IniRead($strIniFileName, "Main", "Autorun",          "0") == "1", True, False)
EndFunc
;=============================================================================


;=============================================================================
; Tray menu creating & …
;=============================================================================
Func fnCreateTrayMenu()
    TraySetState()
    TraySetIcon("Shell32.dll", 4)
    TraySetClick(8)

    ;--- Show Notification ---------------------------------------------------
    $mnuShowNotification = TrayCreateItem("Show Notification")
    TrayItemSetOnEvent($mnuShowNotification, "fnMnuShowNotification")
    If $boolShowNotification Then
        TrayItemSetState($mnuShowNotification, $TRAY_CHECKED)
    Else
        TrayItemSetState($mnuShowNotification, $TRAY_UNCHECKED)
    EndIf

    ;--- Use Clipboard -------------------------------------------------------
    $mnuUseClipboard = TrayCreateItem("Use Clipboard")
    TrayItemSetOnEvent($mnuUseClipboard, "fnMnuUseClipboard")
    If $boolUseClipboard Then
        TrayItemSetState($mnuUseClipboard, $TRAY_CHECKED)
    Else
        TrayItemSetState($mnuUseClipboard, $TRAY_UNCHECKED)
    EndIf

    #cs
    ;--- Change Folder -------------------------------------------------------
    $mnuChangeFolder = TrayCreateItem("Change Folder")
    TrayItemSetOnEvent($mnuChangeFolder, "fnMnuChangeFolder")
    If $boolChangeFolder Then
        TrayItemSetState($mnuChangeFolder, $TRAY_CHECKED)
    Else
        TrayItemSetState($mnuChangeFolder, $TRAY_UNCHECKED)
    EndIf
    ;*************************************************
    TrayItemSetState($mnuChangeFolder, $TRAY_DISABLE)
    ;*************************************************
    #ce

    ;--- Delimiter -----------------------------------------------------------
    TrayCreateItem("")

    ;--- Autorun -------------------------------------------------------------
    $mnuAutorun = TrayCreateItem("Start with Windows")
    TrayItemSetOnEvent($mnuAutorun, "fnMnuAutorun")
    If $boolAutorun Then
         TrayItemSetState($mnuAutorun, $TRAY_CHECKED)
         RegWrite("HKEY_CURRENT_USERSoftwareMicrosoftWindowsCurrentVersionRun", "F7", "REG_SZ", """" & @ScriptFullPath & """")
    Else
         TrayItemSetState($mnuAutorun, $TRAY_UNCHECKED)
         RegDelete("HKEY_CURRENT_USERSoftwareMicrosoftWindowsCurrentVersionRun", "F7")
    EndIf

    ;--- Delimiter -----------------------------------------------------------
    TrayCreateItem("")

    ;--- About ---------------------------------------------------------------
    $mnuAbout = TrayCreateItem("About F7…")
    TrayItemSetOnEvent($mnuAbout, "frmAbout")

    ;--- Delimiter -----------------------------------------------------------
    TrayCreateItem("")

    ;--- Quit ----------------------------------------------------------------
    $mnuQuit = TrayCreateItem("Quit")
    TrayItemSetOnEvent($mnuQuit, "fnQuit")
    TrayItemSetState($mnuQuit, $TRAY_DEFAULT)

    TraySetToolTip("Press F7 in Explorer to create New folder" & @CRLF & "Right click here for Option")
EndFunc

;-----------------------------------------------------------------------------
; … & Tray Menu processing
;-----------------------------------------------------------------------------
Func fnMnuShowNotification()
    $boolShowNotification = Not $boolShowNotification
    
    If $boolShowNotification Then
        TrayItemSetState(@TRAY_ID, $TRAY_CHECKED)
    Else
        TrayItemSetState(@TRAY_ID, $TRAY_UNCHECKED)
    EndIf
    
    IniWrite($strIniFileName, "Main", "ShowNotification", _Iif($boolShowNotification, "1", "0"))
EndFunc
;-----------------------------------------------------------------------------
Func fnMnuUseClipboard()
    $boolUseClipboard = Not $boolUseClipboard
    
    If $boolUseClipboard Then
        TrayItemSetState(@TRAY_ID, $TRAY_CHECKED)
    Else
        TrayItemSetState(@TRAY_ID, $TRAY_UNCHECKED)
    EndIf
    
    IniWrite($strIniFileName, "Main", "UseClipboard", _Iif($boolUseClipboard, "1", "0"))
EndFunc
;-----------------------------------------------------------------------------

#cs
Func fnMnuChangeFolder()
    $boolChangeFolder = Not $boolChangeFolder
    
    If $boolChangeFolder Then
        TrayItemSetState(@TRAY_ID, $TRAY_CHECKED)
    Else
        TrayItemSetState(@TRAY_ID, $TRAY_UNCHECKED)
    EndIf
    
    IniWrite($strIniFileName, "Main", "ChangeFolder", _Iif($boolChangeFolder, "1", "0"))
EndFunc
;-----------------------------------------------------------------------------
#ce

Func fnMnuAutorun()
    $boolAutorun = Not $boolAutorun
    
    If $boolAutorun Then
        TrayItemSetState(@TRAY_ID, $TRAY_CHECKED)
        RegWrite("HKEY_CURRENT_USERSoftwareMicrosoftWindowsCurrentVersionRun", "F7", "REG_SZ", """" & @ScriptFullPath & """")
    Else
        TrayItemSetState(@TRAY_ID, $TRAY_UNCHECKED)
        RegDelete("HKEY_CURRENT_USERSoftwareMicrosoftWindowsCurrentVersionRun", "F7")
    EndIf
    
    IniWrite($strIniFileName, "Main", "Autorun", _Iif($boolAutorun, "1", "0"))
EndFunc
;-----------------------------------------------------------------------------
Func fnQuit()
    $boolScriptlDone = True
EndFunc
;=============================================================================


;=============================================================================
; Hotkey F7 processing
;=============================================================================
Func fnF7()
    Local $objIE
    Local $strTempString
    Local $i
    
    HotKeySet(@HotKeyPressed)
    
    If WinActive("[CLASS:CabinetWClass]") Then
        $intHWND = WinGetHandle("[ACTIVE]")
        
        If _ProcessGetName(WinGetProcess($intHWND)) == "explorer.exe" Then
            For $objIE In $objShell.Windows
                If $objIE.HWND = $intHWND Then
                    $objFolder = $objShell.NameSpace($objIE.LocationUrl)
                    
                    If IsObj($objFolder) = 1 Then
                        $strParentFolder = $objFolder.Self.Path
                        
                        ExitLoop
                    Else
                        fnTrayInfoShow(ControlGetText($intHWND, "", "Edit1"), "Can't create folder in this location", 3, 3)
                        
                        HotKeySet(@HotKeyPressed, "fnF7")
                        Return
                    EndIf
                EndIf
            Next
            
            If StringLen($strParentFolder) <> 0 Then
                If $boolUseClipboard Then
                    $strTempString = StringReplace(ClipGet(), """", "")
                    $strFolder = StringMid($strTempString, StringInStr($strTempString, "" , 0 , -1) + 1)
                Else
                    $i = 1
                    
                    Do
                        If $i = 1 Then
                            $strFolder = $strFolderTemplate
                        Else
                            $strFolder = $strFolderTemplate & " (" & String($i) & ")"
                        EndIf
                        
                        $i += 1
                    Until FileExists(_PathFull($strParentFolder & "" & $strFolder)) = 0
                EndIf
                
                fnCreateFolder($intHWND)
            EndIf
        Else
            Send(@HotKeyPressed)
        EndIf
    Else
        Send(@HotKeyPressed)
    EndIf
    
    HotKeySet(@HotKeyPressed, "fnF7")
EndFunc
;=============================================================================

;=============================================================================
; Creating folder & processing action
;=============================================================================
Func fnCreateFolder($intHWND)
    Local $hwndSysListView32
    Local $intOldItemsCount
    Local $intIndex
    Local $i
    
    If Not FileExists(_PathFull($strParentFolder & "" & $strFolder)) Then
        $hwndSysListView32 = ControlGetHandle($intHWND, "", "SysListView321")
        $intOldItemsCount = _GUICtrlListView_GetItemCount($hwndSysListView32)
        
        $objFolder.NewFolder($strFolder)
        
        If Not @error Then
            If FileExists(_PathFull($strParentFolder & "" & $strFolder)) Then
                Do
                    Sleep(10)
                Until _GUICtrlListView_GetItemCount($hwndSysListView32) <> $intOldItemsCount
                
                ControlFocus($intHWND, "", $hwndSysListView32)
                _GUICtrlListView_BeginUpdate($hwndSysListView32)
                
                For $i = 0 To _GUICtrlListView_GetItemCount($hwndSysListView32) - 1
                    
                    If _GUICtrlListView_GetItemState($hwndSysListView32, $i, $LVIS_SELECTED) = $LVIS_SELECTED Then
                        _GUICtrlListView_SetItemState($hwndSysListView32, $i, 0, $LVIS_SELECTED)
                    EndIf
                Next
                
                _GUICtrlListView_EndUpdate($hwndSysListView32)
                
                $intIndex = _GUICtrlListView_FindText($hwndSysListView32, $strFolder, -1, False, True)
                _GUICtrlListView_EditLabel($hwndSysListView32, $intIndex)
                
                fnTrayInfoShow($strParentFolder, "Folder" & @CRLF & $strFolder & @CRLF & "created successfully", 1, 2)
            Else
                fnTrayInfoShow($strParentFolder, "Can't create folder" & @CRLF & $strFolder & @CRLF & "in this location", 3, 3)
            EndIf
        Else
            fnTrayInfoShow($strParentFolder, "Can't create folder" & @CRLF & $strFolder & @CRLF & "in this location." & @CRLF & @CRLF & _
                "Reason: " & $objComErrorHandler.WinDescription, 3, 3)
        EndIf
    Else
        fnTrayInfoShow($strParentFolder, "Can't create folder" & @CRLF & $strFolder & @CRLF & "in this location." & @CRLF & @CRLF & _
            "Reason: Folder already exists", 3, 3)
    EndIf
EndFunc
;=============================================================================


;=============================================================================
; Show & clear tips, errors
;=============================================================================
Func fnTrayInfoShow($strTitle, $strInfo, $intInfoType, $intTime)
    If $boolShowNotification Then
        AdlibDisable()
        TrayTip("", "", 0)
        
        TrayTip($strTitle, $strInfo, $intTime, $intInfoType)
        AdlibEnable("fnTrayInfoClear", $intTime * 1000)
    EndIf
    
    If $intInfoType = 3 Then
        AdlibEnable("fnTrayInfoClear", $intTime * 1000)
        TraySetIcon("shell32.dll", 200)
        SoundPlay(_Iif(StringLen(RegRead("HKEY_CURRENT_USERAppEventsSchemesApps.DefaultSystemHand.Current", "")) <> 0, _
            RegRead("HKEY_CURRENT_USERAppEventsSchemesApps.DefaultSystemHand.Current", ""), _
            RegRead("HKEY_CURRENT_USERAppEventsSchemesApps.DefaultSystemHand.Default", "")))
    EndIf
EndFunc
;-----------------------------------------------------------------------------
Func fnTrayInfoClear()
    AdlibDisable()
    TrayTip("", "", 0)
    TraySetIcon("shell32.dll", 4)
EndFunc
;=============================================================================

;=============================================================================
; form About creating & processing
;=============================================================================
Func frmAbout()
    $frmAbout = GUICreate("About F7", 307, 219, -1, -1, BitOR($WS_SYSMENU,$WS_CAPTION,$WS_POPUP,$WS_POPUPWINDOW,$WS_BORDER,$WS_CLIPSIBLINGS))

    GUISetIcon("C:\Windows\System32\shell32.dll", 4, $frmAbout)
    GUISetOnEvent($GUI_EVENT_CLOSE, "frmAboutClose", $frmAbout)
    GUISetOnEvent($GUI_EVENT_MOUSEMOVE, "frmAboutMouseMove", $frmAbout)

    Local $btnOK = GUICtrlCreateButton("&OK", 120, 184, 75, 25)
        GUICtrlSetOnEvent($btnOK, "btnOKClick")
    Local $grphDelimiter  = GUICtrlCreateGraphic(8, 168, 287, 3, BitOR($SS_RIGHT,$SS_ETCHEDHORZ,$SS_ETCHEDFRAME,$SS_NOTIFY))
    Local $icoProductName = GUICtrlCreateIcon("C:\Windows\System32\shell32.dll", -4, 8, 8, 32, 32, BitOR($SS_NOTIFY,$WS_GROUP))
    Local $lblProductName = GUICtrlCreateLabel("F7", 48, 8, 236, 28, $WS_GROUP)
        GUICtrlSetFont($lblProductName, 16, 800, 0, "MS Sans Serif")
        GUICtrlSetColor($lblProductName, 0x220088)
    Local $lblVersion     = GUICtrlCreateLabel("ver." & FileGetVersion(@ScriptFullPath), 48, 48, 239, 17, $WS_GROUP)
    Local $lblCopyright   = GUICtrlCreateLabel(StringReplace(FileGetVersion(@ScriptFullPath, "LegalCopyright"), "&", "&&"), 48, 72, 240, 17, $WS_GROUP)
    Local $lblComments    = GUICtrlCreateLabel(FileGetVersion(@ScriptFullPath, "Comments"), 48, 104, 240, 34, $WS_GROUP)
    Local $icoHomePage    = GUICtrlCreateIcon("C:\Windows\System32\shell32.dll", -151, 16, 144, 16, 16, BitOR($SS_NOTIFY,$WS_GROUP))
          $lblHomePage    = GUICtrlCreateLabel("Home page", 48, 144, 58, 17)
        GUICtrlSetOnEvent($lblHomePage, "lblHomePageClick")
        GUICtrlSetColor($lblHomePage, 0x000088)
        GUICtrlSetCursor($lblHomePage, 0)
        GUICtrlSetTip($lblHomePage, "http://forum.script-coding.info")

    GUISetState(@SW_SHOW)

    $boolDoneAbout = False

    Do
        Sleep(100)
    Until $boolDoneAbout

    GUISetState(@SW_HIDE)
    GUIDelete($frmAbout)
EndFunc
;-----------------------------------------------------------------------------
Func frmAboutClose()
    $boolDoneAbout = True
EndFunc
;-----------------------------------------------------------------------------
Func frmAboutMouseMove()
    Local $arrCursorInfo = GUIGetCursorInfo($frmAbout)
    
    If $arrCursorInfo[4] = $lblHomePage Then
        if Not $boolHoverlblHomePage Then
            $boolHoverlblHomePage = Not $boolHoverlblHomePage
            
            GUICtrlSetColor($lblHomePage, 0x0000FF)
            GUICtrlSetFont($lblHomePage, 8, 400, 4, "MS Sans Serif")
        EndIf
    Else
        If $boolHoverlblHomePage Then
            $boolHoverlblHomePage = Not $boolHoverlblHomePage
            
            GUICtrlSetColor($lblHomePage, 0x000066)
            GUICtrlSetFont($lblHomePage, 8, 400, 0, "MS Sans Serif")
        EndIf
    EndIf
EndFunc
;-----------------------------------------------------------------------------
Func btnOKClick()
    $boolDoneAbout = True
EndFunc
;-----------------------------------------------------------------------------
Func lblHomePageClick()
    ShellExecute("http://forum.script-coding.info")
EndFunc
;=============================================================================

;=============================================================================
; Get FolderTemplate
;=============================================================================
Func fnGetFolderTemplate()
    Local $hInstance
    Local $strTempString
    
    $hInstance = _WinAPI_LoadLibraryEx("shell32.dll")

    If $hInstance <> 0 Then
        $strTempString = _WinAPI_LoadString($hInstance, 30320)
        
        If @error Then
            $strTempString = "New folder"
        EndIf
        
        _WinAPI_FreeLibrary($hInstance)
    Else
        $strTempString = "New folder"
    EndIf
    
    Return $strTempString
EndFunc
;=============================================================================

;=============================================================================
; Get full file name of config
;=============================================================================
Func fnGetIniFileName($strPath)
    Local $szDrive, $szDir, $szFName, $szExt
    _PathSplit($strPath, $szDrive, $szDir, $szFName, $szExt)
    Return _PathMake($szDrive, $szDir, $szFName, "ini")
EndFunc
;=============================================================================

;=============================================================================
; COM objects error handler
;=============================================================================
Func fnComErrorHandler()
    SetError(1)
EndFunc
;=============================================================================

I use the "Send" in the program

Share this post


Link to post
Share on other sites
jasonkhoo87

jasonkhoo87,

I cannot download your file - can you make sure the link is correct Nothing malicious with that file at all. :huh:

M23

thanks for proving I'm clean.

I was able to download and run the file on a VM. I see no evidence of malware or any problems with it. It does what it says; creates a new folder.

you too.

lol Okay. Well then he's the first person I've ever seen anywhere who registers just to share a perfectly clean exe

Sorry for all. I register because I have been using autoit since 3years ago. But didn't register at all because I learn all from the help guideline. Just now I'm active online, then searching thread so, found this thread. I just reply it because I still keep the exe file for sharing. I like to code, I will never make my code dirty. :D

Edited by jasonkhoo87

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

×