BatteryQuery - I just don't get it.

[Maffe811 0]

Here is the UDF, cause im not sure if this is the original:

; #FUNCTION# ========================================================================================================================
; Function Name:    _BatteryQuery
; Description:      Return information on the Battery.
; Syntax            _BatteryQuery (  )
; Parameter(s):     None.
; Return Value(s):  Success: Returns 4 elements array:
;                            $array[0] - ACPower (0 - Offline, 1 - Online, 255 - Unknown)
;                            $array[1] - BatteryFlag (1 - High, 2 - Low, 4 - Critical, 8 - Charging, 128 - No Battery, 255 - Unknown)
;                                        Use BitAnd() to test, ie BitAnd($array[1], 128)
;                            $array[2] - BatteryLife, % (0 - 100, 255 - Unknown)
;                            $array[3] - Seconds left of charge, estimate (4294967295 - Unknown)
;
;                   Failure: Returns 0 and sets the @error flag to non-zero.
; Author(s):        -
; Note(s):          -
;====================================================================================================================================

func _BatteryQuery()

    local $tStruct = DllStructCreate('ubyte;ubyte;ubyte;ubyte;ulong;ulong')
    local $aRet, $aRes[4]

    $aRet = DllCall('kernel32.dll', 'int', 'GetSystemPowerStatus', 'ptr', DllStructGetPtr($tStruct))
    if (@error) or ($aRet[0] = 0) then
        $aRet = 1
    endif
    $aRes[0] = DllStructGetData($tStruct, 1) ; AC
    $aRes[1] = DllStructGetData($tStruct, 2) ; Battery Charge
    $aRes[2] = DllStructGetData($tStruct, 3) ; Battery Charge, %
    $aRes[3] = DllStructGetData($tStruct, 5) ; Battery Left, Sec
    $tStruct = 0
    if $aRet = 1 then
        return SetError(1, 0, 0)
    endif
    return SetError(0, 0, $aRes)
endfunc; _BatteryQuery

Now... I don't understand how to use it!

Ive tried diffentr things.

If some one could point me in the right direction, i would be most gratefull.

All I need to know is when the charger is connected and when its not.

[BrewManNH 1,305]

Add this to the top of the script:

#include <array.au3>
Global $array = _BatteryQuery()
_ArrayDisplay($array)

Now run it on a laptop and look at the contents of $array in the _ArrayDisplay output. Look at the explanation in the header of the UDF for what the values mean.

[taietel 34]

Or this:

$aQuery = _BatteryQuery()
Switch $aQuery[0]
 Case 1;AC Power online
  ConsoleWrite("On AC Power")
 Case 0;AC Power offline
  ConsoleWrite("On battery")
 Case Else;AC Power unknown
  ConsoleWrite("On your own")
EndSwitch

[wakillon 403]

Now... I don't understand how to use it!

That's because you don't know SetError function :

$aRes[0] = DllStructGetData($tStruct, 1) ; AC

$aRes[1] = DllStructGetData($tStruct, 2) ; Battery Charge

$aRes[2] = DllStructGetData($tStruct, 3) ; Battery Charge, %

$aRes[3] = DllStructGetData($tStruct, 5) ; Battery Left, Sec

return SetError(0, 0, $aRes) ;==> SetError ( code [, extended [, return value]] )

So it return $aRes value, who is an array, as it is writed in your post : "; Return Value(s): Success: Returns 4 elements array"

Look in my signature for a monitoring battery script.

[Maffe811 0]

Now, i understand why everything i did failed.

Or this:

$aQuery = _BatteryQuery()
Switch $aQuery[0]
 Case 1;AC Power online
  ConsoleWrite("On AC Power")
 Case 0;AC Power offline
  ConsoleWrite("On battery")
 Case Else;AC Power unknown
  ConsoleWrite("On your own")
EndSwitch

As you ca see, Taietel is using $aQuery[0], I would be using $aQuery[1].

Thats why everything i did failed.

Also the lack of sleep didnt help!

Thank you for the help, i can now complete my program!