GUICtrlSetOnEvent problem

[Damein]

I've used this function in many of my scripts, but for some reason I can't seem to figure out why it won't go in this one.

Global $NewItemLabel, $NewCost, $TotalWeeklyCost, $VarianceFromLastWeek, $SaveBudgetButton, $IniFile, $IniFileInfo, $LastWeeksBudgetTab, $CurrentWeeksBudgetTab
 
Opt("GUIOnEventMode", 1)
 
_CreateGui()
 
Func _CreateGui()
     GuiCreate("Budgeting System", 800, 700, Default, Default)
     GuiCtrlCreateTab(10,5,780,680)
     $LastWeeksBudgetTab = GuiCtrlCreateTabItem("Previous Week")
     GUICtrlSetOnEvent($LastWeeksBudgetTab, "_PreviousWeeksBudgetDisplay")
     $CurrentWeeksBudgetTab = GuiCtrlCreateTabItem("Current Week")
     GUICtrlSetOnEvent($CurrentWeeksBudgetTab, "_CurrentWeeksBudgetDisplay")
     GuiSetState()
EndFunc
 
Func _PreviousWeeksBudgetDisplay()
     Msgbox(0, "Test", "Previous")
EndFunc
 
Func _CurrentWeeksBudgetDisplay()
     Msgbox(0, "test", "Current")
EndFunc
 
While 1
    Sleep(10)
WEnd

Edited September 4, 2011 by Damein

[martin]

expandcollapse popup

#include <GuiConstantsEx.au3>

Global $NewItemLabel, $NewCost, $TotalWeeklyCost, $VarianceFromLastWeek, $SaveBudgetButton, $IniFile, $IniFileInfo, $LastWeeksBudgetTab, $CurrentWeeksBudgetTab
Global $Tab1
Opt("GUIOnEventMode", 1)

_CreateGui()

Func _CreateGui()
    Local $G1 = GUICreate("Budgeting System", 800, 700, Default, Default)
    $Tab1 = GUICtrlCreateTab(10, 5, 780, 680)
    $LastWeeksBudgetTab = GUICtrlCreateTabItem("Previous Week")
    GUICtrlSetOnEvent($LastWeeksBudgetTab, "_PreviousWeeksBudgetDisplay")
    $CurrentWeeksBudgetTab = GUICtrlCreateTabItem("Current Week")
    ;GUICtrlSetOnEvent($CurrentWeeksBudgetTab, "_CurrentWeeksBudgetDisplay")
    GUICtrlSetOnEvent($Tab1, "_CurrentWeeksBudgetDisplay")
    GUICtrlCreateTabItem("")
    GUISetState()
    GUISetOnEvent($GUI_EVENT_CLOSE, "AllDone", $G1)
EndFunc   ;==>_CreateGui

Func _PreviousWeeksBudgetDisplay()
    MsgBox(0, "Test", "Previous")
EndFunc   ;==>_PreviousWeeksBudgetDisplay

Func _CurrentWeeksBudgetDisplay()
    Switch GUICtrlRead($Tab1)
        Case 0
            MsgBox(0, "test", "Previous")
        Case 1
            MsgBox(0, "test", "Current")
    EndSwitch
EndFunc   ;==>_CurrentWeeksBudgetDisplay

While 1
    Sleep(10)
WEnd

Func AllDone()
    Exit
EndFunc   ;==>AllDone

[sleepydvdr]

I struggled with this problem for about 30 minutes before I gave up on trying to help. Now I understand. Thanks for the solution, martin.