[Solved] How to convert string ip to int

[E1M1]

From tcp server example I found code converts Int to string

$aRet = DllCall("Ws2_32.dll", "str", "inet_ntoa", "int", 2130706433)
  If Not @error Then $aRet = $aRet[0]

But how i can convert string IP to int again?

Solution: inet_addr

Edited October 31, 2011 by E1M1

[KaFu]

MSDN is your friend , search for inet_ntoa, read documentation and look for similar functions...

$aRet = DllCall("Ws2_32.dll", "str", "inet_ntoa", "int", 2130706433)
If Not @error Then $aRet = $aRet[0]
ConsoleWrite($aRet & @crlf)
$aRet = DllCall("Ws2_32.dll", "long", "inet_addr", "str", $aRet & chr(0))
If Not @error Then $aRet = $aRet[0]
ConsoleWrite($aRet & @crlf)

Edit: To be correct, return is long on not int.

Edited October 31, 2011 by KaFu

[E1M1]

thanks, I googled for it but didn't find. or actually didn't know what to look

[trancexx]

I would go with more natural solution any time over that calls considering the language we use:

$sIP = "255.255.255.255"
 
; Verify reversibleness
ConsoleWrite(_IPToString(_StringToIP($sIP)) & @CRLF)
 
Func _IPToString($iIP)
    Return Number(BinaryMid($iIP, 1, 1)) & "." & Number(BinaryMid($iIP, 2, 1)) & "." & Number(BinaryMid($iIP, 3, 1)) & "." & Number(BinaryMid($iIP, 4, 1))
EndFunc
 
Func _StringToIP($sIP)
    Local $aIP = StringSplit($sIP, ".")
    ReDim $aIP[5]
    Return Dec(Hex($aIP[4], 2) & Hex($aIP[3], 2) & Hex($aIP[2], 2) & Hex($aIP[1], 2))
EndFunc

...Ssspeeeedd

Edited October 31, 2011 by trancexx