Multiple AutoIt Processes Updating 1 ListView GUI...???

[cypher175]

Is it possible to have multiple autoit processes update text data in different rows/columns in one main listview GUI window..?

what functions would I need to use to accomplish this type of task..?

[cypher175]

Anybody knows??

[KaFu]

Seems like you just have to get the right handle...

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=test.exe
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

If StringInStr($CmdLineRaw, "child") Then
    $hListView = ControlGetHandle("GUI_LV_Parent", "", "SysListView321")
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)
    Exit
EndIf

GUICreate("GUI_LV_Parent", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)

; Add columns
_GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
_GUICtrlListView_InsertColumn($hListView, 1, "Column 2", 100)
_GUICtrlListView_InsertColumn($hListView, 2, "Column 3", 100)
GUISetState()

If @Compiled Then
    Run(@ScriptFullPath & " child")
Else
    Run(@AutoItExe & " """ & @ScriptFullPath & """ child")
EndIf

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()

Edited February 26, 2012 by KaFu