Detect dropped files in a window?

[Khryus]

Hey, I was thinking if it was possible to detect when a file is dragged inside a window. If so, how would you do that?

(What I want to do is something much like "drag a file in this window to open it")

[Melba23]

megablox,

ProgAndy gave me this code a while ago:

#include <Array.au3>
#include <GUIConstantsEx.au3>

Global $gaDropFiles[1], $iDropItem = -1
Global $WM_DROPFILES = 0x233

GUICreate("DropIt", 241, 312, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, 0x00000018); WS_EX_ACCEPTFILES
$FILES_DROPPED = GUICtrlCreateDummy()
GUISetState()
GUIRegisterMsg($WM_DROPFILES, 'WM_DROPFILES_FUNC')


While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $FILES_DROPPED
            $aFiles = $gaDropFiles
            _ArrayDisplay($aFiles)
    EndSwitch
WEnd

Func WM_DROPFILES_FUNC($hWnd, $msgID, $wParam, $lParam)
    Local $nSize, $pFileName
    Local $nAmt = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', 0xFFFFFFFF, 'ptr', 0, 'int', 0)
    ReDim $gaDropFiles[$nAmt[0]]
    For $i = 0 To $nAmt[0] - 1
        $nSize = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', 0, 'int', 0)
        $nSize = $nSize[0] + 1
        $pFileName = DllStructCreate('wchar[' & $nSize & ']')
        DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', DllStructGetPtr($pFileName), 'int', $nSize)
        $gaDropFiles[$i] = DllStructGetData($pFileName, 1)
        $pFileName = 0
    Next
    GUICtrlSendToDummy($FILES_DROPPED, $nAmt[0])
EndFunc   ;==>WM_DROPFILES_FUNC

M23

[JohnOne]

Search $GUI_DROPACCEPTED and $WS_EX_ACCEPTFILES in the help file.

[Khryus]

That's really nice, thanks (also @ ProgAndy)