Convert binary to file

[Floppy]

I use this to convert a file in binary mode.

$File_Handle = FileOpen($File_Path, 0+16)

$File_Content = FileRead($File_Handle)

FileClose($File_Handle)

FileWrite("prova.txt", $File_Content)

How can I convert the new file (in this case, prova.txt) back to the original file?

Thanks for help

[Melba23]

FSoft,

Just open the new file for binary writing:

$File_Path = "fred4.au3"

$File_Handle = FileOpen($File_Path, 0 + 16)
$File_Content = FileRead($File_Handle)
FileClose($File_Handle)

ConsoleWrite($File_Content & @CRLF)

FileWrite("prova.txt", $File_Content)

$File_Handle = FileOpen("Original.txt", 2 + 16)
FileWrite($File_Handle, $File_Content)
FileClose($File_Handle)

But have you looked at what is in prova.txt?

M23

[Floppy]

@Melba: Thank you for your reply, but you don't understand what I'm trying to do.

I have the following script:

$File_Path = "test.zip"
$File_Handle = FileOpen($File_Path, 0+16)
$File_Content = FileRead($File_Handle)
FileClose($File_Handle)
FileWrite("prova.txt", $File_Content)
Exit

The file "prova.txt" contains the binary version of the file "test.zip".

Now I want another script to open the file "prova.txt" and convert it back to "test.zip". It's possible to do this?

Thank you for help!

Edited May 6, 2012 by FSoft

[PhoenixXL]

Hey!! FSoft

Nice Meeting U

Maybe This is the UDF that will Do Your Work

Link:

Thumbs Up if it Helped

Regards

Phoenix XL

[Floppy]

Hi Phoenix. Thank you for the answer, however that script uses encbin and decbin to do the work. I don't want to rely on 3rd part components.

It's possible to do everything in pure AutoIt?

Edited May 6, 2012 by FSoft

[ProgAndy]

I don't really understand. You have a binary file, and write it as Hex-encoded string in a new file. Now you are looking for a way to convert this string back into a binary file?

; read binary file
$hFile = FileOpen($sBinaryFile, 16)
$bBinary = FileRead($hFile)
FileClose($hFile)

; write hex file
$hFile = FileOpen($sStringFile, 2)
FileWrite($hFile, String($sBinary))
FileClose($hFile)

; --------------------------------------

; read hex file
$hFile = FileOpen($sStringFile)
$sString = FileRead($hFile)
FileClose($hFile)

; write new binary file
$hFile = FileOpen($sNewBinaryFile, 18)
FileWrite($hFile, Binary($sString))
FileClose($hFile)

[Floppy]

@ProgAndy: That doesn't work. I tried with a PDF and the new file created is corrupted.

[ProgAndy]

  On 5/7/2012 at 8:55 AM, 'Filarono said:

@ProgAndy: That doesn't work. I tried with a PDF and the new file created is corrupted.

There was a small typo. This works for me:

$sBinaryFile = "test.png"
$sStringFile = "testbin.txt"
$sNewBinaryFile = "test_out.png"

; read binary file
$hFile = FileOpen($sBinaryFile, 16)
$bBinary = FileRead($hFile)
FileClose($hFile)

; write hex file
$hFile = FileOpen($sStringFile, 2)
FileWrite($hFile, String($bBinary))
FileClose($hFile)

; --------------------------------------

; read hex file
$hFile = FileOpen($sStringFile)
$sString = FileRead($hFile)
FileClose($hFile)

; write new binary file
$hFile = FileOpen($sNewBinaryFile, 18)
FileWrite($hFile, Binary($sString))
FileClose($hFile)

[Floppy]

Thank you ProgAndy. Now it works!