Jump to content
Sign in to follow this  
SpookMeister

Setting Tray Submenu Items

Recommended Posts

SpookMeister

Hi,

I'm hoping someone can point me in the right direction. I need to be able to Set a dynamicly created TrayItem as the currently selected item based on information I will have stored on the last use of a program. Consider this example:

#include <Constants.au3>
#NoTrayIcon

; set script wide options
Opt("WinTitleMatchMode", 1) ;1=start, 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase
Opt("TrayMenuMode", 1) ; Default tray menu items (Script Paused/Exit) will not be shown.
Opt("TrayOnEventMode", 1)

; pretend I am populating this array from some external semi-dynamic data
Global $a_Things[6]
For $x = 1 To UBound($a_Things, 1) - 1
$a_Things[$x] = "Item " & $x
Next

$submenu = TrayCreateMenu("Submenu")
For $y = 1 To UBound($a_Things, 1) - 1
TrayCreateItem($a_Things[$y], $submenu, -1, 1)
TrayItemSetOnEvent(-1, "_SubmenuChoice")
Next

TrayCreateItem("")

$aboutitem = TrayCreateItem("About")
TrayItemSetOnEvent(-1, "_About")
TrayCreateItem("")
$exititem = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "_Exit")
TraySetState()

While 1
Sleep(1000)
WEnd

Func _Exit()
Exit
EndFunc ;==>_Exit

Func _About()
MsgBox(4096, "About", "Blah Blah Blah")
EndFunc ;==>_About

Func _SubmenuChoice()
MsgBox(4096, "Info", "Menu Choice:" & @TRAY_ID)
EndFunc ;==>_SubmenuChoice

I can work with the @TRAY_ID value to do the actions I need within the program, but I want to save their choice, and re-use it later.

Now, I know how to do that (writing to and reading from the registry for example), but what I do not know how to do, is to programatically mark the submenu item as the current selected choice upon loading, based on the info that I have stored.


[u]Helpful tips:[/u]If you want better answers to your questions, take the time to reproduce your issue in a small "stand alone" example script whenever possible. Also, make sure you tell us 1) what you tried, 2) what you expected to happen, and 3) what happened instead.[u]Useful links:[/u]BrettF's update to LxP's "How to AutoIt" pdfValuater's Autoit 1-2-3 Download page for the latest versions of Autoit and SciTE[quote]<glyph> For example - if you came in here asking "how do I use a jackhammer" we might ask "why do you need to use a jackhammer"<glyph> If the answer to the latter question is "to knock my grandmother's head off to let out the evil spirits that gave her cancer", then maybe the problem is actually unrelated to jackhammers[/quote]

Share this post


Link to post
Share on other sites
Melba23

SpookMeister,

Use TrayItemSetState like this: ;)

#include <GUIConstantsEx.au3>
#include <Constants.au3>
#NoTrayIcon

; set script wide options
Opt("WinTitleMatchMode", 1) ;1=start, 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase
Opt("TrayMenuMode", 1) ; Default tray menu items (Script Paused/Exit) will not be shown.
Opt("TrayOnEventMode", 1)

; pretend I am populating this array from some external semi-dynamic data
Global $a_Things[6]
For $x = 1 To UBound($a_Things, 1) - 1
    $a_Things[$x] = "Item " & $x
Next

Global $aSubItem[UBound($a_Things)]

$submenu = TrayCreateMenu("Submenu")
For $y = 1 To UBound($a_Things, 1) - 1
    $aSubItem[$y]= TrayCreateItem($a_Things[$y], $submenu)
    TrayItemSetOnEvent(-1, "_SubmenuChoice")
Next

TrayCreateItem("")

$aboutitem = TrayCreateItem("About")
TrayItemSetOnEvent(-1, "_About")
TrayCreateItem("")
$exititem = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "_Exit")
TraySetState()

; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
$iIndex = Random(1, UBound($a_Things), 1)
TrayItemSetState($aSubItem[$iIndex], $GUI_CHECKED)
; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

While 1
    Sleep(1000)
WEnd

Func _Exit()
    Exit
EndFunc   ;==>_Exit

Func _About()
    MsgBox(4096, "About", "Blah Blah Blah")
EndFunc   ;==>_About

Func _SubmenuChoice()
    MsgBox(4096, "Info", "Menu Choice:" & @TRAY_ID)
EndFunc   ;==>_SubmenuChoice

Look for the <<<<<<<<<<<<<< section. :)

M23

  • Like 1

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
SpookMeister

Perfect, thanks.


[u]Helpful tips:[/u]If you want better answers to your questions, take the time to reproduce your issue in a small "stand alone" example script whenever possible. Also, make sure you tell us 1) what you tried, 2) what you expected to happen, and 3) what happened instead.[u]Useful links:[/u]BrettF's update to LxP's "How to AutoIt" pdfValuater's Autoit 1-2-3 Download page for the latest versions of Autoit and SciTE[quote]<glyph> For example - if you came in here asking "how do I use a jackhammer" we might ask "why do you need to use a jackhammer"<glyph> If the answer to the latter question is "to knock my grandmother's head off to let out the evil spirits that gave her cancer", then maybe the problem is actually unrelated to jackhammers[/quote]

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

×