adding unique id to text file

[grimmlock]

So I am using this code:

Local $file = FileOpen("test.txt", 1)

; Check if file opened for writing OK
If $file = -1 Then
MsgBox(0, "Error", "Unable to open file.")
Exit
EndIf

FileWrite($file, "Line1")
FileWrite($file, "Still Line1" & @CRLF)
FileWrite($file, "Line2")

FileClose($file)

However I would like to add a unique number to the beginning, so that the result would be something like:

test.txt

id 1: line

id 2: line 2

id 3: line 3

etc

Any ideas?

Thanks in advance

Grimm

[Melba23]

grimmlock,

How about this - just call the function at the beginning of each line:

Local $file = FileOpen("test.txt", 1)

; Check if file opened for writing OK
If $file = -1 Then
    MsgBox(0, "Error", "Unable to open file.")
    Exit
EndIf

FileWrite($file, _LineID() & "Line1")
FileWrite($file, "Still Line1" & @CRLF)
FileWrite($file, _LineID() & "Line2")

FileClose($file)

Func _LineID()
    Static $iCount = 0
    $iCount += 1
    Return "id" & StringFormat("%04i", $iCount) & ": "
EndFunc

Any use?

M23

Edited March 26, 2013 by Melba23
Fixed tags

[grimmlock]

Thank you Melba23,

Great! Ok so I close the app and reopen it, then run it. It puts the unique id however it starts at 1 again. Is there a way to have the function look at the previous id and then add 1 to it?

Meaning I open the app and create a line 1 with id001. Then I close the app and reopen it and add something else, right now it adds id001 again but can it be setup to see that it already has a id001 so it makes it id002, and so on?

Thanks

Grimm

[Melba23]

grimmlock,

Fun little task that:

expandcollapse popup

#include <File.au3>

Local $file = FileOpen("test.txt", 1)
Local $aLines, $iCount = 0

; Check if file opened for writing OK
If $file = -1 Then
    MsgBox(0, "Error", "Unable to open file.")
    Exit
EndIf

; Read the file
_FileReadToArray("Test.txt", $aLines)
If Not @error Then
    ; if the file exists look for the ID starting on the last line
    For $i = $aLines[0] To 1 Step -1
        If StringLeft($aLines[$i], 2) == "id" Then
            ; get the ID number
            $iCount = Int(StringRegExpReplace($aLines[$i], "id(\d*):.*", "$1"))
            ExitLoop
        EndIf
    Next
    ; Check we found an ID
    If $i = 0 Then
        MsgBox(0, "Error", "No line id found")
        Exit
    EndIf
EndIf

FileWrite($file, _LineID() & "LineA")
FileWrite($file, "Still LineA" & @CRLF)
FileWrite($file, _LineID() & "LineB" & @CRLF)

FileClose($file)

Func _LineID()
    $iCount += 1
    Return "id" & StringFormat("%04i", $iCount) & ": "
EndFunc

All clear?

M23

[grimmlock]

Melba you are the best!!!!

Thanks!

Grimm