Loop help

[trnew]

Hi.I need some help with a GUI.I have one button which I attached a function to, but I want to stop a loop at some point (by pressing a key) and run it again later by pressing the button again, so I made use of ExitLoop.. After a while I noticed that when I click the button again it won't loop anymore, but do only one cycle and I don't understand why.I want to know what I should write to make it work( like press button>loops>press key>stops>press button again>loops and so on)

My script:

expandcollapse popup

#include
#include
#include

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Autodevelop", 301, 301)
$Button1 = GUICtrlCreateButton("b1", 50, 16, 201, 41)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


Global $Paused
Func TogglePause() ; the pause function
$Paused = NOT $Paused
While $Paused
ToolTip('Please press "F8" to resume!',700,400,"",1,2)
sleep(1000)
WEnd
ToolTip("")
EndFunc

Func Terminate() ; the exit function
Exit
EndFunc

Func Stop()
EndFunc


HotKeySet("{F8}", "TogglePause") ; pause
HotKeySet("{ESC}", "Terminate") ; close
HotKeySet("{s}", "Stop")



While 1

$do=GUIGetMsg()
switch $do
case $GUI_EVENT_CLOSE
Exit

Case $Button1

While 1

mousemove(615,555)
mouseclick("")
sleep(800)
mousemove(620,556)
mouseclick("")
sleep(800)
mousemove(580,556)


If @HotKeyPressed = "{s}" Then
ExitLoop
EndIf

WEnd


EndSwitch
WEnd

I appreciate any help regarding this script.

Edited April 16, 2013 by trnew

[FireFox]

Hi,

Welcome to the autoit forum

I would do it this way :

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $blPaused = False, $blStopped = False

HotKeySet("{F8}", "TogglePause") ; pause
HotKeySet("{ESC}", "Terminate") ; close
HotKeySet("{s}", "Stop")

#region ### START Koda GUI section ### Form=
$hGUI = GUICreate("Autodevelop", 301, 301)
$iButton1 = GUICtrlCreateButton("b1", 50, 16, 201, 41)
GUISetState(@SW_SHOW, $hGUI)
#endregion ### END Koda GUI section ###

While 1
    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $iButton1
            $blStopped = False

            While Not $blStopped
                MouseMove(615, 555)
                MouseClick("")
                Sleep(800)
                MouseMove(620, 556)
                MouseClick("")
                Sleep(800)
                MouseMove(580, 556)
            WEnd
    EndSwitch
    Sleep(10)
WEnd

GUIDelete($hGUI)

Func TogglePause() ; the pause function
    $blPaused = Not $blPaused

    If $blPaused Then
        ToolTip('Please press "F8" to resume!', 700, 400, "", 1, 2)
        While $blPaused
            Sleep(10)
        WEnd
    Else
        ToolTip("")
    EndIf
EndFunc   ;==>TogglePause

Func Terminate() ; the exit function
    Exit
EndFunc   ;==>Terminate

Func Stop()
    $blStopped = True
EndFunc   ;==>Stop

Take a look at the script structure to keep it clear.

Br, FireFox.

[trnew]

Thank you.This is definitely what I am looking for.I wouldn't have thought about using booleans.

Also, I have some questions :

What's the role of GUIDelete ( what kind of "delete" is this, cause it doesn't seem to delete/close the GUI windows or buttons )?

What's the role of sleep(10) after EndSwitch?(it seems to run fine without it)

[FireFox]

What's the role of GUIDelete ( what kind of "delete" is this, cause it doesn't seem to delete/close the GUI windows or buttons )?

It's a good coding pratice to delete the GUIs before exiting the script to release the ressources yourself.

What's the role of sleep(10) after EndSwitch?(it seems to run fine without it)

Less CPU usage.

Br, FireFox.

[trnew]

Thanks for explaining.It uses less CPU because it pauses for a while there, right?

And I got something else, not related to loops.I want to background to this GUI to make nice, so I found this would work -GUICtrlCreatePic('...abc.jpg', 0, 0, 0, 0)-

It's good, but it makes my buttons disappear, though when I click the area where the button should be, the button appears.Any idea why that happens and how to make the area where buttons are visible?

[BrewManNH]

Read the remarks in the help file for GUICtrlCreatePic, it tells you what to do.

[trnew]

Yeah, alreay looked into that before, but I didn't read that part.. I also checked out other topic to see how it's done (if somebody will ever be interested : )

Anyway if this will be of help here is what I added ( order is important: GUI window 1st>GUI pic 2nd>disable GUI pic |so other controls won't overlap| 3rd>Controls 4th>GUI show 5th ) :

$hGUI = GUICreate("Autodevelop", 301, 301)

GUICtrlCreatePic('...abc.jpg', 0, 0, 0, 0)

GuiCtrlSetState(-1, $GUI_DISABLE)

$iButton1 = GUICtrlCreateButton("b1", 50, 16, 201, 41)

GUISetState(@SW_SHOW, $hGUI)