Rounding decimal down

[SimpleC]

Hello everybody! 

I'm having trouble with rounding.  The program I'm using rounds decimals down. Autoit's round function rounds them up.

Example:

round(174.126, 2) = 174.13

I need that round to be 174.12.   

 

Here's the actually script:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=C:Program FilesAutoinstallForm1.kxf
$Form1 = GUICreate("AutoCalc", 227, 200, 15, 15, $WS_EX_TOPMOST)
$Button1 = GUICtrlCreateButton("Calculate", 8, 144, 99, 25)
$Button2 = GUICtrlCreateButton("Close", 120, 144, 91, 25)
$Label4 = GUICtrlCreateLabel("", 72, 136, 4, 4)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
$Group1 = GUICtrlCreateGroup("Input", 8, 8, 209, 129)
$Label1 = GUICtrlCreateLabel("Rate", 16, 32, 27, 17)
$Label2 = GUICtrlCreateLabel("Number of Nights", 16, 64, 86, 17)
$Input1 = GUICtrlCreateInput("0.00", 112, 24, 89, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_RIGHT))
$Label3 = GUICtrlCreateLabel("Total", 16, 96, 45, 28)
GUICtrlSetFont(-1, 11, 400, 0, "MS Sans Serif")
$Input2 = GUICtrlCreateInput("1", 112, 56, 89, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_RIGHT))
;$Label5 = GUICtrlCreateLabel("0.00", 136, 96, 39, 28)
GUICtrlSetFont(-1, 11, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
 $nMsg = GUIGetMsg()
 Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
   case $Button1
   ;$val = round((((((GUICtrlRead($input1) * .1545) + GUICtrlRead($input1)) + 1.5 + .13) * GUICtrlRead($input2))), 2)
   $val = (((((GUICtrlRead($input1) * .1545) + GUICtrlRead($input1)) + 1.5 + .13) * GUICtrlRead($input2)))
   $Label5 = GUICtrlCreateLabel($val, 136, 96, 39, 28)
   case $Button2
   Exit
 EndSwitch
WEnd

[Melba23]

SimpleC,

Interesting. My first thought was to use StringFormat - but that function seems to use Round too:

$sRet = StringFormat("%.2f", String(174.126))
MsgBox(0, "Result", $sRet)

So it seems you will need to use a wrapper function like this:

$nRet = _RoundDown(174.126, 2)
MsgBox(0, "Result", $nRet)

; Long version
Func _RoundDown($nVar, $iCount)
    ; Move the decimal point
    $nMult = $nVar * (10 ^ $iCount)
    ; Remove remaining decimals
    $iRound = Int($nMult)
    ; Move decimal point back again
    $nRoundDown = Round($iRound / (10 ^ $iCount), $iCount)
    Return $nRoundDown
EndFunc

; Short version
Func _RoundDown($nVar, $iCount)
    Return Round((Int($nVar * (10 ^ $iCount))) / (10 ^ $iCount), $iCount)
EndFunc

That seems to work,

 

M23

[Starg]

Try this:

Round(174.126 - 0.005 , 2)

Edit:

Melba23 was faster!

Edited August 14, 2013 by Starg

[BrewManNH]

Round by definition will round the number up or down to the nearest number with the specified decimal places. If 5 or above, it will round up, if 0 to 4 will round down. The only thing I can think of would be to take the number, multiply it by 10*(the number of decimal places you want) and then use Intinstead of round, and divide by what you multiplied by. Something like this change to your code.

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#region ### START Koda GUI section ### Form=C:\Program Files\Auto\install\Form1.kxf
$Form1 = GUICreate("AutoCalc", 227, 200, 15, 15, $WS_EX_TOPMOST)
$Button1 = GUICtrlCreateButton("Calculate", 8, 144, 99, 25)
$Button2 = GUICtrlCreateButton("Close", 120, 144, 91, 25)
$Label4 = GUICtrlCreateLabel("", 72, 136, 4, 4)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
$Group1 = GUICtrlCreateGroup("Input", 8, 8, 209, 129)
$Label1 = GUICtrlCreateLabel("Rate", 16, 32, 27, 17)
$Label2 = GUICtrlCreateLabel("Number of Nights", 16, 64, 86, 17)
$Input1 = GUICtrlCreateInput("0.00", 112, 24, 89, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_RIGHT))
$Label3 = GUICtrlCreateLabel("Total", 16, 96, 45, 28)
GUICtrlSetFont(-1, 11, 400, 0, "MS Sans Serif")
$Input2 = GUICtrlCreateInput("1", 112, 56, 89, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_RIGHT))
$Label5 = GUICtrlCreateLabel("0.00", 136, 96, 39, 28)
GUICtrlSetFont(-1, 11, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#endregion ### END Koda GUI section ###
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            $Tax = .1545
            $Rate = GUICtrlRead($Input1)
            $LengthStay = GUICtrlRead($Input2)
            $val = Int(((((($Rate * $Tax) + $Rate) + 1.5 + .136) * $LengthStay)) * 10 ^ 2) / 10 ^ 2
;~          $val = (((((GUICtrlRead($input1) * .1545) + GUICtrlRead($input1)) + 1.5 + .13) * GUICtrlRead($input2)))
            GUICtrlSetData($Label5, $val)
        Case $Button2
            Exit
    EndSwitch
WEnd

[SimpleC]

I think Melba's is correct.  Thank you for the quick responses! 

[macargu]

Hello everybody! 

I'm having trouble with rounding.  The program I'm using rounds decimals down. Autoit's round function rounds them up.

Example:

round(174.126, 2) = 174.13

I need that round to be 174.12.   

 

Unless I am not understanding something here, but it would seem to me that the program is just trimming off everything after the second digit to the right of the decimal point.

To achieve that, I would do the following:

$Var = 174.126

; Splitting the number into its components, using the decimal point as separator:

$SplitVar = StringSplit($Var, ".")  ;  $SplitVar[1]= 174 ; $SplitVar[2]= 126

; Trimming the decimal component to two digits:

$SplitVar[2] = StringLeft($SplitVar[2], 2)  ;  $SplitVar[2] = 12

; Joining both components back together

$FinalVar = $SplitVar[1] & "." & $SplitVar[2])  ;  $FinalVar = 174.12

I hope I am not saying something really stupid!

[kylomas]

Or more simply

ConsoleWrite(stringtrimright(123.1123,1) & @LF)

[jchd]

macargu

Indeed one can work on the string representation as well, and even make that a one-liner by trimming or as a regexp replacement.

But I bet that it would be more costly this way since that involves 2 costly conversions (double <==> string) plus string operation(s).

kylomas

BTW, trimming needs a bit more caution unless you already know in advance how many positions the decimal part has. Furthermore, it would fail as is on integral values.

Pffft, too many edits.

Edited August 14, 2013 by jchd

[Melba23]

macargu,

Welcome to the AutoIt forum.

Your suggestion is perfectly valid - there are often several ways of reaching the same destination. Incidentally, the new Beta allows you to do this in just one line:

$nVar = 174.126

$nRounded = StringSplit($nVar, ".")[1] & "." & StringLeft(StringSplit($nVar, ".")[2], 2)

ConsoleWrite($nRounded & @CRLF)

Pretty nifty - if a little complex at first glance.

M23

[kylomas]

@jchd - Yes, you're probably right but AutoIT handles the conversion Ok

local $a = 1.55

ConsoleWrite(stringtrimright($a,1) * 2 & @LF)

[jchd]

Of course it does!

I meant from a performance point of view. If you invoke that once in a blue moon, fine. If it's in a tight loop, it might slow things down.

[kylomas]

@jchd - Understood

BTW, trimming needs a bit more caution unless you already know in advance how many positions the decimal part has. Furthermore, it would fail as is on integral values.

 

I agree, it's a kludgy solution

Edited August 14, 2013 by kylomas

[jchd]

For strings either Melba's 1-liner or a regexp are fine. But if the user wants strings and a fixed 2-digit decimal part, he has to cope with integers.

[macargu]

macargu,

Welcome to the AutoIt forum.

Your suggestion is perfectly valid - there are often several ways of reaching the same destination. Incidentally, the new Beta allows you to do this in just one line:

$nVar = 174.126

$nRounded = StringSplit($nVar, ".")[1] & "." & StringLeft(StringSplit($nVar, ".")[2], 2)

ConsoleWrite($nRounded & @CRLF)

Pretty nifty - if a little complex at first glance.

M23

 

Thank you, Melba23.

I am really glad to see that an experienced coder as yourself used the exact same logic I, a beginner, did, only you did it in a sintactically compact, more efficient and elegant way. What took me 3 rows, you did in one. Very clear, very nice.

Macargu

[BrewManNH]

My solution was a single line as well, and the result is the same.

[kylomas]

@BrewmanNH - Nice!  Can you explain why this works (math illiterate)

local $a = 1.737
; 1 dec place
ConsoleWrite((int($a*10^1)/10^1) * 2 & @LF)
; 2 dec place
ConsoleWrite((int($a*10^2)/10^2) * 2 & @LF)

kylomas

edit: shopping for new fingers that can actually type

Edited August 14, 2013 by kylomas

[BrewManNH]

Your first example is multiplying the number by 10, removing anything past the decimal point 1.737 * 10 = 17.37, take the integer portion of that, 17, divide by 10 to get 1.7.

The second is the same except you're multiplying  and dividing by 100 in this case, so you get 1.73.

Edited August 14, 2013 by BrewManNH

[kylomas]

@BrewmanNH - Shifting the decimal and dividing the int, of course (obvious when you see the solution). Thanks for the explanation!

[macargu]

My solution was a single line as well, and the result is the same.

 

Yes. Very nice solution, BrewManNH.

Macargu