Jump to content
Sign in to follow this  
remin

Accelerator keys, where to place them?

Recommended Posts

I'm a bit confused about accelerator keys and checkboxes.

1) See my code below: Is this the correct way how I put them in the script?

    (First: reading the ini file to see if the checkbox is enabled then setting the checkbox state before "GUISetState(@SW_SHOW"

     Second: After having created the GUI, if the status of the checkbox changes disable or enable the accelerator keys (Case $CB3)

     Third: when the GUI is closed, write checkbox status in ini)

2) I've read in a reply of Melba in another topic that in order to disable the accelerator keys (in my case {enter})

    It is needed to Send a CR to the control

    "ControlSend($hGUI, "", $hFocus, @CR)"
    I don't know why this is, I haven't understand it very well and I don't know where to put it in my case.
    (but it seems to work fine in my code without it)
3) In my code below I have inserted only 2 buttons (search and images)
    In reality I have a lot more buttons.
    The code between ";Focus and Accelerator key" and ";END Focus and Accelerator key" is almost the same in all Cases.
    The only thing different is the value of $focus. The value of $focus is the Case name. 
    Is there a way to put this code in an external function to avoid multiplying the code many times?
    (I noted in the help file that there is not a GUI ID in GUICtrlSetState and GUISetAccelerators)
 
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <String.au3>
#include <GuiButton.au3>
#include <Constants.au3>
#include <EditConstants.au3>


HotKeySet("^4", "SearchMenu")


While 1
    Sleep(10000)
WEnd


Func SearchMenu()

;========GUI=============
$MyFile = "d:\temp\RW-autoit.ini"
Global $url


 $Form5=          GUICreate("Search Menu", 345, 140, @DesktopWidth*0.65, @DesktopHeight*0.21)
 $RWSearch =      GuiCtrlCreateEdit("",                               16,  10, 270, 50)
 $textGoogle  =   GUICtrlCreateLabel("Google:",                       20,  90, 100, 20)
 $bsearch =       GUICtrlCreateButton("Search",                      110,  90,  60, 20)
 $bimages =       GUICtrlCreateButton("Images",                      175,  90,  60, 20)
 $CB3  =          GUICtrlCreateCheckbox("Enter=Send (^Enter=Enter)", 110, 120, 145, 20)


 If FileExists($MyFile) Then
     $State = IniRead($MyFile,"CheckBox","CB3",0)
     If $State == 1 Then
        GUICtrlSetState(($CB3), BitOr($GUI_ENABLE, $GUI_CHECKED))
     Else
        GUICtrlSetState(($CB3), BitOr($GUI_ENABLE, $GUI_UNCHECKED))
     EndIf
     $Focus = IniRead($MyFile,"Focus","Button",0)
 Else
     GUICtrlSetState(($CB3, BitOr($GUI_ENABLE, $GUI_CHECKED))
     $Focus = "bsearch"
 EndIf
GUISetState(@SW_SHOW)
;========END GUI==========


Local $aAccelKeys[1][2] = [["{ENTER}", eval($focus)]]


If _GUICtrlButton_GetCheck($CB3) Then
   GUISetAccelerators($aAccelKeys)
   Global $EnterSubmit = true
Else
   GUISetAccelerators(0)
   Global $EnterSubmit = false
EndIf


; Set the Default Key
GUICtrlSetState(eval($focus), $GUI_DEFBUTTON)


While 1
$nMsg = GUIGetMsg()
Switch $nMsg


   Case $GUI_EVENT_CLOSE
        ; write status checkboxes in ini
        If FileExists($MyFile) Then
            If _GUICtrlButton_GetCheck($CB3) Then
              IniWrite($MyFile, "CheckBox", "CB3", 1)
            Else
              IniWrite($MyFile, "CheckBox", "CB3", 0)
            EndIf
        EndIf


        ; write focus in ini
        IniWrite($MyFile, "Focus", "Button", $Focus)


        GuiDelete($Form5)
        ExitLoop


      Case $CB3
           If _GUICtrlButton_GetCheck($CB3) Then
               GUISetAccelerators($aAccelKeys)
               Global $EnterSubmit = true
           Else
               GUISetAccelerators(0)
               Global $EnterSubmit = false
           EndIf


      Case $bsearch
           $RWSearch1 = GUICtrlRead($RWSearch)
           $RWSearch2 = StringRegExpReplace($RWSearch1, "(\s+)", "+")


           ;Focus and Accelerator key
           $focus = "bsearch"
           GUICtrlSetState(eval($focus), $GUI_DEFBUTTON)
           If $EnterSubmit then
             GUISetAccelerators($aAccelKeys)
           Else
             GUISetAccelerators(0)
           Endif
           ;End Focus and Accelerator key


           $url = "https://www.google.com/search?q=" & $RWSearch2
           SearchMenuExec()


      Case $bimages
           $RWSearch1 = GUICtrlRead($RWSearch)
           $RWSearch2 = StringRegExpReplace($RWSearch1, "(\s+)", "+")


           ;Focus and Accelerator key
           $focus = "bsearch"
           GUICtrlSetState(eval($focus), $GUI_DEFBUTTON)
           If $EnterSubmit then
             GUISetAccelerators($aAccelKeys)
           Else
             GUISetAccelerators(0)
           Endif
           ;End Focus and Accelerator key


           $url = "http://images.google.com/images?hl=en&q=" & $RWSearch2
           SearchMenuExec()
EndSwitch
 WEnd
EndFunc ;==>SearchMenu


Func SearchMenuExec()
 ClipPut($url)
 ShellExecute($url)
EndFunc ;==>SearchMenuExec
Edited by remin

Share this post


Link to post
Share on other sites

remin,

 

I've read in a reply of Melba in another topic that in order to disable the accelerator keys (in my case {enter}) - It is needed to Send a CR to the control

Can you point me to where you found that because it is wrong and I cannot remember having said such a thing. :wacko:

How you are setting/cancelling the Accelerator keys is fine - just pass a non-array value to the function. :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

remin,

 

Can you point me to where you found that because it is wrong and I cannot remember having said such a thing. :wacko:

How you are setting/cancelling the Accelerator keys is fine - just pass a non-array value to the function. :)

M23

 

Sure :)

'?do=embed' frameborder='0' data-embedContent>>

(the last post)

Can you please tell me what you mean with pass a non-array value to the function?  :unsure:

Share this post


Link to post
Share on other sites

remin,

That code is used because the OP wanted to to actually use the associated Accel key when another control had focus. The code looks to see which control has keyboard focus and then if required disables the Accel function, passes an ENTER to the control and then re-enables the Accel function:

Case $cEnter
            ; Get control with focus
            $hFocus = _WinAPI_GetFocus()
            If $hFocus = GUICtrlGetHandle($cInput) Then
                ; If input
                MsgBox(0, "Test", "Enter Pressed In Input")
            Else
                ; If not we need to disable the Accel key
                GUISetAccelerators(0)
                ; Send a CR to the control
                ControlSend($hGUI, "", $hFocus, @CR)
                ; And then reenable the Accel key
                GUISetAccelerators($aAccelKeys)
            EndIf
As you can see, the Accel keys are disabled/re-enabled in the 2 GUISetAccelerators lines - the ControlSend line has nothing to do with it. :)

A "non-array" value is exactly that - anything which is not an array. I tend to use a simple numeric value of 0 as you can see from the above code. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Melba23,

I told you I'm confused about accelerators.  ;)

You told me to add a Non-array value in your 1st replay,

but I added one (or am I wrong?):  :unsure:

GUISetAccelerators(0)

Melba,

Have you seen also my 3rd question?

ps:  

does accelerators not work with $WS_SIZEBOX?

Edited by remin

Share this post


Link to post
Share on other sites
How you are setting/cancelling the Accelerator keys is fine - just pass a non-array value to the function.

 

 

Oh.. sorry, 

I didn't understand this phrase in the beginning.

I thought I had to add a non-array value to the function

but your way of writing is a confirmation of what I did.:)

About my 3rd question:

I'm curious to know if I can use GUICtrlSetState and GUISetAccelerators

in an external function.. there is no way to indicate the Gui-name in both functions ....

Share this post


Link to post
Share on other sites

remin,

Yes, you can use a function - this is how I might do it (although I have not tested the code as I have no idea what you are doing): ;)

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <String.au3>
#include <GuiButton.au3>
#include <Constants.au3>
#include <EditConstants.au3>

HotKeySet("^4", "SearchMenu")

Global $url,$Focus, $EnterSubmit ; Do not declare Global variables inside functions <<<<<<<<<<<<

While 1
    Sleep(10) ; 10 is quite sufficient <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
WEnd

Func SearchMenu()

    ;========GUI=============
    $MyFile = "d:\temp\RW-autoit.ini"

    $Form5 = GUICreate("Search Menu", 345, 140, @DesktopWidth * 0.65, @DesktopHeight * 0.21)
    $RWSearch = GUICtrlCreateEdit("", 16, 10, 270, 50)
    $textGoogle = GUICtrlCreateLabel("Google:", 20, 90, 100, 20)
    $bsearch = GUICtrlCreateButton("Search", 110, 90, 60, 20)
    $bimages = GUICtrlCreateButton("Images", 175, 90, 60, 20)
    $CB3 = GUICtrlCreateCheckbox("Enter=Send (^Enter=Enter)", 110, 120, 145, 20)

    If FileExists($MyFile) Then
        $State = IniRead($MyFile, "CheckBox", "CB3", 0)
        If $State = 1 Then ; == means case-sensitive string comparison, so not needed here <<<<<<<<<<<<<<<<<<<<<<<
            GUICtrlSetState(($CB3), BitOR($GUI_ENABLE, $GUI_CHECKED))
        Else
            GUICtrlSetState(($CB3), BitOR($GUI_ENABLE, $GUI_UNCHECKED))
        EndIf
        $Focus = IniRead($MyFile, "Focus", "Button", 0)
    Else
        GUICtrlSetState($CB3, BitOR($GUI_ENABLE, $GUI_CHECKED))
        $Focus = "bsearch"
    EndIf
    GUISetState(@SW_SHOW)
    ;========END GUI==========

    Local $aAccelKeys[1][2] = [["{ENTER}", Eval($Focus)]]

    ;If _GUICtrlButton_GetCheck($CB3) Then
    If GUICtrlRead($CB3) = $GUI_CHECKED Then ; Use native functions if possible <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        GUISetAccelerators($aAccelKeys)
        $EnterSubmit = True
    Else
        GUISetAccelerators(0)
        $EnterSubmit = False
    EndIf

    ; Set the Default Key
    GUICtrlSetState(Eval($Focus), $GUI_DEFBUTTON)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                ; write status checkboxes in ini
                If FileExists($MyFile) Then
                    If GUICtrlRead($CB3) = $GUI_CHECKED Then
                        IniWrite($MyFile, "CheckBox", "CB3", 1)
                    Else
                        IniWrite($MyFile, "CheckBox", "CB3", 0)
                    EndIf
                EndIf
                ; write focus in ini
                IniWrite($MyFile, "Focus", "Button", $Focus)
                GUIDelete($Form5)
                ExitLoop
            Case $CB3
                If GUICtrlRead($CB3) = $GUI_CHECKED Then
                    GUISetAccelerators($aAccelKeys)
                    $EnterSubmit = True
                Else
                    GUISetAccelerators(0)
                    $EnterSubmit = False
                EndIf
            Case $bsearch
                $RWSearch1 = GUICtrlRead($RWSearch)
                $RWSearch2 = StringRegExpReplace($RWSearch1, "(\s+)", "+")

                _Focus_Accel("bsearch", $aAccelKeys) ; Call a function with suitable parameters <<<<<<<<<<<<<<<<<

                $url = "https://www.google.com/search?q=" & $RWSearch2
                SearchMenuExec()


            Case $bimages
                $RWSearch1 = GUICtrlRead($RWSearch)
                $RWSearch2 = StringRegExpReplace($RWSearch1, "(\s+)", "+")

                _Focus_Accel("bImages", $aAccelKeys) ; Call a function with suitable parameters <<<<<<<<<<<<<<<<<

                $url = "http://images.google.com/images?hl=en&q=" & $RWSearch2
                SearchMenuExec()
        EndSwitch
    WEnd
EndFunc   ;==>SearchMenu


Func SearchMenuExec()
    ClipPut($url)
    ShellExecute($url)
EndFunc   ;==>SearchMenuExec

Func _Focus_Accel($Focus, $aAccelKeys)

    $Focus = "bsearch"
    GUICtrlSetState(Eval($Focus), $GUI_DEFBUTTON)
    If $EnterSubmit Then
        GUISetAccelerators($aAccelKeys)
    Else
        GUISetAccelerators(0)
    EndIf

EndFunc
I have added a few comments as well - please ask if any of them are unclear. :)

m23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Thank you for your reply Melba :)

It seems that something doesn't work.

Without the function (_Focus_Accel) it works fine.

With the function not (neither the Accelerator Keys nor the focus are updated).

........

You wrote in your reply that you didn't understand what I'm trying to do.

What I would like to do with the checkbutton is:

- when the checkbutton CB3 (Enter=Send) is checked

  I would like to view an inputbox of 1 line  

$RWSearch = GUICtrlCreateInput("", 16, 10, 270, 25)

 (with accelerators enabled and focus active on last used button)

- when the checkbutton CB3 (label: Enter=Send) is unchecked

 I would like to view an editbox of 3 lines

$RWSearch = GUICtrlCreateEdit("", 16, 10, 270, 65)

(with accelerators disabled and focus active on last used button

I hope I made myself clear :)

Edited by remin

Share this post


Link to post
Share on other sites

remin,

I think I understand now. :)

I would code something like that rather differently. Most importantly I would create the GUI just once and then hide/show it as required - that way you do not need an ini file as the various values can be stored within the script itself. I have also shown how you can use a 2D array to have as many buttons as you want - although you will have to develop an algorithm to position them within your GUI, as well as making the GUI big enough to hold them. ;)

Take a look at this and see if it does what you want - then we can then look to developing the button algorithm:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <EditConstants.au3>

HotKeySet("^4", "SearchMenu")

; These need to be Global as we retain their values between function calls
Global $RWSearch, $Focus = 9999

; Create an array to hold button data: ["Title", ControlID, "url to use"]
Global $aButton[3][3] = [[2, 0, 0], _
                        ["Search", -1, "https://www.google.com/search?q="], _
                        ["Images", -1, "http://images.google.com/images?hl=en&q="]]

$Form5 = GUICreate("Search Menu", 345, 140, @DesktopWidth * 0.65, @DesktopHeight * 0.21)
$textGoogle = GUICtrlCreateLabel("Google:", 20, 90, 100, 20)
For $i = 1 To $aButton[0][0]
    $aButton[$i][1] = GUICtrlCreateButton($aButton[$i][0], 45 + ($i * 65), 90, 60, 20)
Next
$CB3 = GUICtrlCreateCheckbox("Enter=Send (^Enter=Enter)", 110, 120, 145, 20)

GUISetState(@SW_HIDE)

While 1
    Sleep(10)
WEnd

Func SearchMenu()

    ; Check state of checkbox
    If GUICtrlRead($CB3) = $GUI_CHECKED Then
        ; Create correct sized input
        $RWSearch = GUICtrlCreateInput("", 16, 10, 270, 25, $ES_WANTRETURN)
        ; Set accel key
        If $Focus <> 9999 Then
            Local $aAccelKeys[1][2] = [["{ENTER}", $Focus]]
            GUISetAccelerators($aAccelKeys)
        EndIf
    Else
        ; Create correct sized input
        $RWSearch = GUICtrlCreateEdit("", 16, 10, 270, 65, BitOr($ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL))
        ; Clear Accel key
        GUISetAccelerators(0)
    EndIf

    ; Set the Default Key
    GUICtrlSetState($Focus, $GUI_DEFBUTTON)

    ; Show GUI
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                ; Delete search box
                GUICtrlDelete($RWSearch)
                ; Hide GUI
                GUISetState(@SW_HIDE)
                ExitLoop
            Case $CB3
                ; Delete current edit control
                GUICtrlDelete($RWSearch)
                ; Creat new edit control and adjust Accel keys as required
                If GUICtrlRead($CB3) = $GUI_CHECKED Then
                    ; Create correct sized input
                    $RWSearch = GUICtrlCreateInput("", 16, 10, 270, 25, $ES_WANTRETURN)
                    If $Focus = 9999 Then
                        ; No focus set so uncheck
                        GUICtrlSetState($CB3, $GUI_UNCHECKED)
                    Else
                        ; Set accel key
                        Local $aAccelKeys[1][2] = [["{ENTER}", $Focus]]
                        GUISetAccelerators($aAccelKeys)
                    EndIf
                Else
                    ; Create correct sized input
                    $RWSearch = GUICtrlCreateEdit("", 16, 10, 270, 65, BitOr($ES_WANTRETURN, $WS_VSCROLL, $ES_AUTOVSCROLL))
                    ; Clear accel key
                    GUISetAccelerators(0)
                EndIf

            Case Else
                ; Look through the buttons
                For $i = 1 To $aButton[0][0]
                    If $nMsg = $aButton[$i][1] Then
                        ; Found a button
                        $RWSearch1 = GUICtrlRead($RWSearch)
                        $RWSearch2 = StringRegExpReplace($RWSearch1, "(\s+)", "+")
                        ; Set focus for next round
                        $Focus = $aButton[$i][1]
                        $url = $aButton[$i][2] & $RWSearch2

                        MsgBox($MB_SYSTEMMODAL, "Actioning", $aButton[$i][0] & @CRLF & @CRLF & $url)

                        ;SearchMenuExec($url)

                        ; No point in looking further
                        ExitLoop
                    EndIf
                Next
        EndSwitch
    WEnd

EndFunc   ;==>SearchMenu


Func SearchMenuExec($url)
    ClipPut($url)
    ShellExecute($url)
EndFunc   ;==>SearchMenuExec
Let me know how it works - and if you have any questions. :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

:thumbsup: Thank you very much Melba! 

You've dedicated a lot of time to my script!

I resolved all my questions.

The only thing I didn't use is the dynamic button creator.

Most Urls's of my Cases are constructed and there 

is a lot more text then the single Url. :)

Just a few remarks:

--------

While 1
    Sleep(10)
WEnd
Can I change it to Sleep(1000) or Sleep(10000)?
Higher values takes less CPU I've noted.
(I still don't understand very well what it does)
--------
I haven't added (for now) 
        ExitLoop

to all Case.

It seems to work fine without.

But I added to Case $GUI_EVENT_CLOSE:
        GuiDelete($Form5)
        ExitLoop

Is it correct to do it without ExitLoop in all other CASE

--------
Now when my Search Script is ready I'll add it to my general script file with other scripts, isn't it?
There will no conflicts I believe because the search script is invoked by hotkey isn't it?
--------
You've told me to write the global keys at the top of the file.
I have many hotkeys in my general script file.
Do I have to declare the global keys below the hotkeys or can it also be between the hotkeys?
 
Is this correct?
<includes.......>

HotKeySet("^4", "SearchMenu")
Global $url,$Currenttab .....
HotKeySet("^5", "emptyclipb")
HotKeySet("^+5", "empty2ndclipb")

--------

You wrote in a previous reply:

$State = IniRead($MyFile, "CheckBox", "CB3", 0)         
If $State = 1 Then ; == means case-sensitive string comparison, so not needed here <<<<<<<<<<<<<<<<<<<<<<<

I still don't understand exactly what you mean by this.

--------

My convertion from AHK to AI is almost done :)

One thing I haven't converted till now:

My autotext lines

:?*:\\em::myname@domain.com 
etc..

This isn't possible in autoit isn't it?

--------

Melba, thank you again for all you did.

I'm glad I switched to autoit.

Have a nice day.

Edited by remin

Share this post


Link to post
Share on other sites

remin,

 

I'm glad I switched to autoit

Good. I am glad you like the script - and it is my pleasure to help you. :)

Now to all the questions:

 

Can I change it to Sleep(1000) or Sleep(10000)?

Sleep(10) is the lowest script pause you can have and is quite suffcient to give the CPU time to breathe and personally I have never seen for than 1% CPU use on my machine when using that value. Certainly you can use a bigger value - but I doubt if would make that much difference to this script. :)

I haven't added (for now) ExitLoop to all Case

You do not need to. The only reason that it is present when we look for the buttons is that once we have found the pressed button there is no point looking any further. So we use ExitLoop to exit from the For $i = 1 To $aButton[0][0] loop. As the other Case codes do not use loops there is no need to exit them. ;)

 

There will no conflicts I believe because the search script is invoked by hotkey isn't it?

I have no idea as I have not seen the other script. :huh:

 

Do I have to declare the global keys below the hotkeys or can it also be between the hotkeys?

Autoit is pretty tolerant about where you place things, but I suggest that you try and structure your code in a sensible way - it helps debugging and is a boon when you return to a script after some time. I always try to structure my scripts like this:

Directives
Include files
Options
HotKeys
Global declarations
Main code
Functions
Handlers
Obviously you may wish to do something different, but coding in a structured manner, whatever it is, makes life much easier, believe me! ;)

 

case-sensitive string comparison, so not needed here <<<<<<<<<<<<<<<<<<<<<<<

I still don't understand exactly what you mean by this

AutoIt normally compares using the = operator. If both sides are numeric it does a numeric comparison; if both sides are strings it does a case-insensitive ASCII comparison; if there is a mix of datatypes it can go very wrong, so force the 2 sides into type you want using String or Number. If you use the == operator then AutoIt forces both sides into strings and does a case-sensitive ASCII comparison - this takes longer than a simple compare and so you should only use it if you really require such a comparison. In this case you are comparing 2 numbers and so there is no need. :)

 

:?*:em::myname@domain.com

I have no idea what an "autotext" line is supposed to do - so I cannot comment on whether AutoIt can do whatever it is. If you explain what you are trying to do we can probably come up with a solution. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Good. I am glad you like the script - and it is my pleasure to help you.  :)

 

 

Thank you :)

Sleep(10) is the lowest script pause you can have and is quite suffcient to give the CPU time to breathe and personally I have never seen for than 1% CPU use on my machine when using that value. Certainly you can use a bigger value - but I doubt if would make that much difference to this script.  :)

 

The higher the sleep value the slower the response of the script isn't it?

AutoIt normally compares using the = operator. If both sides are numeric it does a numeric comparison; if both sides are strings it does a case-insensitive ASCII comparison; if there is a mix of datatypes it can go very wrong, so force the 2 sides into type you want using String or Number. If you use the == operator then AutoIt forces both sides into strings and does a case-sensitive ASCII comparison - this takes longer than a simple compare and so you should only use it if you really require such a comparison. In this case you are comparing 2 numbers and so there is no need.  :)

 

I still don't get it totally.

My code:

     $State = IniRead($MyFile,"CheckBox",$cbarray[$i],0)
     If $State == 1 Then
       GUICtrlSetState(eval($cbarray[$i]), BitOR($GUI_ENABLE, $GUI_CHECKED))
     Else
       GUICtrlSetState(eval($cbarray[$i]), BitOR($GUI_ENABLE, $GUI_UNCHECKED))
     EndIf

Do i have to change it like this  (is that what you mean?)

If IniRead($MyFile,"CheckBox",$cbarray[$i],0) Then
Else
Endif
I have no idea what an "autotext" line is supposed to do - so I cannot comment on whether AutoIt can do whatever it is. If you explain what you are trying to do we can probably come up with a solution.  ;)

 

 

Sorry :)
Autotext is the name of ahk text expanding.
 
p.e. in this case 
:?*:em::myname@domain.com
 
Typing "em" will expand to the email address "myname@domain.com"
 
Thanks again :)
 
ps:
 
In my search script I will use 3 global arrays with long strings inside.
I tried to declare the arrays above the scripts like this:
Global $BClass[3]
etc

and then use the array within the function like this:

$BClass[3] = ["text", "text", "text"]

but that doesn't seems to work.

What did I wrong Melba?
 
.
Edited by remin

Share this post


Link to post
Share on other sites

remin,

 

The higher the sleep value the slower the response of the script isn't it?

But only in MessageLoop mode where you should just use the built-in pause in GUIGetMsg - that waits up to 12-15ms when the CPU is very busy while the return almost instantaneous if it is idle. In OnEvent mode, and here when only HotKeys are used, the Sleep period has no effect. This is one reason I would not comment on the interaction between your current script and the one with which you wish to merge it - until I see exactly what is involved I am not prepared to say whether problem might arise. ;)

 

[=/==] I still don't get it totally

In this case as you are comparing numbers, you do not need a case-sensitive string comparison. All you need do is replace the == operator with =:

If $State == 1 Then

; should become

If $State = 1 Then

Autotext is the name of ahk text expanding

I see. In Autoit you have 2 options:

 

- 1. Use a variable to contain the expanded text:

; Declare the content
$sEM = "myname@domain.com"

; And use it like this
$url = $sEM & "\section\item.html"

$url will then hold myname@domain.comsectionitem.html

-2. Use the Abbrev manager in SciTE4AutoIt3 to create an abbreviation which you can expand as you type. Look under the <Help - SciTE Help - SciTE4AutoIt3 - User Abbreviations> and <Help - SciTE Help - Extra Utilities - Abbrev Manager> to learn more. If you do not have the full SciTE4AutoIt3 package I highly recommend that you download it from here - you get lots of helpful utilities to help you code in AutoIt. ;)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

I'll read more about GUIGetMsg :)

In this case as you are comparing numbers, you do not need a case-sensitive string comparison. All you need do is replace the == operator with =:

 

 

Oh.. I see the error I've made :sweating:   :)

Thank you also for the autotext info.

I'll study it a bit more.

I added one more thing in my previous post but you were too fast answering ;)

------------

In my search script I will use 3 global arrays with long strings inside.
I tried to declare the arrays above the scripts like this:
Global $BClass[3]
etc

and then use the array within the function like this:

$BClass[3] = ["text", "text", "text"]

but that doesn't seems to work.

What did I wrong Melba?
------------
 
Remin

Edited by remin

Share this post


Link to post
Share on other sites

remin,

 

you were too fast answering

I will try to do worse in future. :D

You need to declare the arrays and their contents at the same time - otherwise you can only assign individual elements:

; This will work
Global $BClass[3] = ["text", "text", "text"]

; As will this if you use the Beta
Global $BClass[] = ["text", "text", "text"]

;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

; Or you need to declare the array at the beginning of the script
Global $BClass[3]

; And then assign the elements individually
$BClass[0] = "text"
$BClass[1] = "text"
$BClass[2] = "text"
Al clear? :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

You need to declare the arrays and their contents at the same time - otherwise you can only assign individual elements:

 

Or just declare them in the function self?

Melba, thank you very much for the time you've dedicated to my script.

Thanks for all :)

Share this post


Link to post
Share on other sites

remin,

 

Or just declare them in the function self?

You can always redeclare arrays - but you still need to either declare the contents at the same time or assign the individual elements separately. ;)

As always, my pleasure to help. :)

M23


Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Recently Browsing   0 members

    No registered users viewing this page.

  • Similar Content

    • By paw
      I use SetSoundDevice to control my audio devices but the UI was either
       
      blurry like this:
      or unusable like this:

      so I made this horrible thing to add scaling to the GUI:
      #Region ;**** Directives created by AutoIt3Wrapper_GUI **** #AutoIt3Wrapper_Change2CUI=y #AutoIt3Wrapper_Res_HiDpi=y #AutoIt3Wrapper_AU3Check_Parameters=-w 3 -w 4 -w 5 #AutoIt3Wrapper_Run_Au3Stripper=y #Au3Stripper_Parameters=/sf /sv /rm #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI **** #include <File.au3> ;~ _convertGUI("") If $CmdLine[0] <> 0 Then _convertGUI($CmdLine[1]) Func _convertGUI($sFilePath) If $sFilePath <> "" Then Local $aArray = FileReadToArray($sFilePath) Else ;TEST DATA Local $aArray[6] = ['$H_Res_Language = GUICtrlCreateProgress(5, 120, 210 + 25, 480, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_SIMPLE)) ; $CBS_DROPDOWNLIST)', _ 'Local $h_Ok = GUICtrlCreateButton("Ok", 72, 224, 81, 33, 0)', _ 'GUICreate($Warning_TiTle, 700, 310, -1, -1, $WS_SIZEBOX + $WS_SYSMENU + $WS_MINIMIZEBOX)', _ 'GUICtrlCreateLabel("Output type: ", 30, 130, 65, 20) ;, $SS_RIGHT)', _ '$H_FieldNameEdit = GUICtrlCreateEdit($INP_FieldNameEdit, 100,260+25, 500, 150 - 25) ;comment', 'Local $H_CANCEL = GUICtrlCreateGraphic("Cancel", 224, 224, 97, 33, 0)'] EndIf Local $hTimer = TimerInit(), $iGUIElementCount = 0, $sResult = "", $sFileName = "", $sDrive = "", $sDir = "", $sExtension = "" If @Compiled Then _PathSplit($sFilePath, $sDrive, $sDir, $sFileName, $sExtension) $sFileName = StringRegExpReplace($sFilePath, "^.*\\", "") EndIf For $i = 0 To (UBound($aArray) - 1) If StringRegExp($aArray[$i], "GUICtrlCreate|GUICreate") Then $sResult = _splitComma($aArray[$i]) If Not @error Then $aArray[$i] = $sResult $iGUIElementCount += 1 EndIf Next ConsoleWrite("t = " & TimerDiff($hTimer) & " GUI elements = " & $iGUIElementCount & " lines = " & (UBound($aArray) - 1) & @CRLF) If $sFileName <> "" Then Local $hFile = FileOpen("edited." & $sFileName, 2) _FileWriteFromArray("edited." & $sFileName, $aArray) FileClose($hFile) EndIf Exit EndFunc ;==>_convertGUI Func _splitComma($sString) Local $sSplitResult = "", $sTrimmedR = "", $sTrimmedL = "" Local $aSplit = StringSplit($sString, ',') If Not @error Then $sTrimmedR = "" $sTrimmedL = "" For $j = 1 To $aSplit[0] If StringRegExp($aSplit[1], "(?:.GUICtrlCreateGraphic|GUICtrlCreateProgress|GUICtrlCreateSlider|GUICtrlCreateTab|GUICtrlCreateTreeView)") Then If $j = 1 Then While StringLeft($aSplit[$j], 1) <> '(' $sTrimmedL &= StringLeft($aSplit[$j], 1) $aSplit[$j] = StringTrimLeft($aSplit[$j], 1) WEnd $aSplit[$j] = StringTrimLeft($aSplit[$j], 1) EndIf EndIf If $j = $aSplit[0] Then While StringRight($aSplit[$j], 1) <> ')' $sTrimmedR &= StringRight($aSplit[$j], 1) $aSplit[$j] = StringTrimRight($aSplit[$j], 1) WEnd $aSplit[$j] = StringTrimRight($aSplit[$j], 1) EndIf If StringRegExp($aSplit[$j], "[0-9]") And $aSplit[$j] <> -1 And $aSplit[$j] <> 0 And $aSplit[$j] <> 1 And Not StringInStr($aSplit[$j], ')') Then If StringRegExp($aSplit[$j], "\-|\+") Then ;put parenthesis around + or - $aSplit[$j] = '(' & $aSplit[$j] & ")*$g_DPI" Else $aSplit[$j] = $aSplit[$j] & "*$g_DPI" EndIf EndIf If $j < $aSplit[0] Then $sSplitResult &= $aSplit[$j] & ',' ElseIf $j = $aSplit[0] Then $sSplitResult &= $aSplit[$j] & ')' Else $sSplitResult &= $aSplit[$j] EndIf Next If $sTrimmedR <> "" Then $sSplitResult &= StringReverse($sTrimmedR) If $sTrimmedL <> "" Then $sSplitResult = $sTrimmedL & '(' & $sSplitResult Else SetError(1) Return EndIf ConsoleWrite($sSplitResult & @CRLF) Return $sSplitResult EndFunc ;==>_splitComma
      And now it looks good: 
      but it doesn't work on everything, for example the "GUICtrlCreateLabel("Output type: ", 30, 130, 65, 20) ;, $SS_RIGHT)" (from the autoit3wrapper gui)
      because the comment contains a parenthesis and it would break completely if there were variables as parameters..
      Is there some kind of parser around that I could use instead or maybe someone who has already done something like this?
    • By Zobu
      Hey Guys,
      I want to add a new checkbox with its own variable every time the add button is clicked.
      The added checkboxes should remain when I close the window or exit the script and when I reopen I should be able to add new checkboxes aswell.
      here is what I have so far..
      #include <GUIConstantsEx.au3> #include <WindowsConstants.au3> #include <StaticConstants.au3> #include <EditConstants.au3> #include <MsgBoxConstants.au3> #include <GuiButton.au3> $test = GUICreate("adding test", 475, 345, 500, 175) $Check1 = GUICtrlCreateCheckbox("Checkbox 1", 15, 25, 300, 25) $Button = GUICtrlCreateButton("Add", 365, 25, 90, 20) $Check2 = GUICtrlCreateCheckbox("Checkbox 2", 15, 50, 300, 25) $Check3 = GUICtrlCreateCheckbox("Checkbox 3", 15, 75, 300, 25) GUICtrlSetState($Check2, $GUI_HIDE) GUICtrlSetState($Check3, $GUI_HIDE) GUISetState(@SW_SHOW) While 1 Switch GUIGetMsg() Case $GUI_EVENT_CLOSE ; Exit Case $Button GUICtrlSetPos($Check2, 15, 50, 300, 25) GUICtrlSetState($Check2, $GUI_SHOW) Case $Button GUICtrlSetPos($Check3, 15, 75, 300, 25) GUICtrlSetState($Check3, $GUI_SHOW) EndSwitch WEnd  
    • By TXTechie
      Hello Everyone,
      I've developed my own GUI using AutoIt and I'm allowing users to minimize the GUI, but I also want to include some kind of timer so that it will automatically restore the GUI after something like 30 minutes or an hour. However, I also want them to be able to manually restore the GUI by clicking the application's icon in the taskbar.
      I've searched through the forums, but I'm not sure how to get started.
      Any ideas or functions to research are appreciated!
      Regards,
      TX Techie
    • By Rskm
      Hi, recently i created a GUI for some calculations in AutoIT.  The GUI has 2 tabs and on the first tab, it has few inputboxes where i use to click with mouse and start entering the inputs. i recently made some changes in the position of these textboxes. I made this by changing the autoit code file instead of making changes in KODA. Now i cannot click inside these textboxes with mouse. However, i can use TAB key to cycle through/enter input in these input boxes. what could have made the inputboxes not responding to mouseclicks. thanks
    • By TheDcoder
      Hi everyone,
      I am bit stumped as to why I am not able to set the time in the Date control
      #include <DateTimeConstants.au3> #include <GUIConstantsEx.au3> #include <MsgBoxConstants.au3> Example() Func Example() GUICreate("My GUI get date", 200, 200, 800, 200) Local $idDate = GUICtrlCreateDate("1953/04/25", 10, 10, 185, 20, $DTS_TIMEFORMAT) ; to select a specific default format Local $sStyle = "HH:mm:ss" GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, $sStyle) ; Set time Local $iRet = GUICtrlSetData($idDate, '13:33:37') ConsoleWrite('GUICtrlSetData returned ' & ($iRet = 1 ? 'success' : 'failure') & @CRLF) GUISetState(@SW_SHOW) ; Loop until the user exits. While GUIGetMsg() <> $GUI_EVENT_CLOSE WEnd MsgBox($MB_SYSTEMMODAL, "Time", GUICtrlRead($idDate)) EndFunc ;==>Example The documentation for GUICtrlSetData clearly mentions that it uses the same format as GUICtrlRead:
      But I get failure
      What gives?
      Thanks for the help in advance!
×
×
  • Create New...