StdinWrite and Special characters

[Lantz]

I am working on a script that is gonna ease the domain migration of 100+ computers, one of the steps in the script is to create a local account and add it to the local administrators group. 

This all works fine on my test machine running english windows, but on a Swedish OS where the Administrator group is called "Administratörer" it doesnt find the group because it misinterprets the letter Ö.

Here is a short script demonstrating the same problem but when adding a user with Ö in the name. The result will be a user called "tempadmin÷"

#AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator


#include <Constants.au3>
#include <MsgBoxConstants.au3>


$RunPid=Run(@ComSpec & ' /K', '',"",$STDIN_CHILD + $STDOUT_CHILD + $STDERR_CHILD)
Sleep(1500)
StdinWrite($RunPid, 'Net User ' & "tempadminö" & ' ' & "secretpassword" & ' /add' & @CRLF)
Sleep(2000)
$result=StdoutRead($RunPid)
StdinWrite($RunPid)
ProcessClose($RunPid)


MsgBox(4096,"test",$result)

 

I have tried playing around with chcp and cmd /U, cmd /A but haven't really gotten any where, is there anyone that can nudge me in the right direction?

FYI: to my knowledge this script must be compiled and then run as admin before it will create any user.

Edited April 9, 2014 by Lantz

[sahsanu]

Hello,

You said that you used chcp with no result but as it is working to me, could you try this?.

$RunPid=Run(@ComSpec & ' /k chcp 1250', '',"",$STDIN_CHILD + $STDOUT_CHILD + $STDERR_CHILD)

Cheers,

sahsanu

[Lantz]

Hello,

You said that you used chcp with no result but as it is working to me, could you try this?.

$RunPid=Run(@ComSpec & ' /k chcp 1250', '',"",$STDIN_CHILD + $STDOUT_CHILD + $STDERR_CHILD)

Cheers,

sahsanu

 

That seems to solve the problem!!

Thanks for helping out.

[sahsanu]

That seems to solve the problem!!

Thanks for helping out.

 

I'm glad that worked to solve your problem.

You are welcome

[jchd]

Code page 1250 will only work with characters in CP1250. Welcome to the headache of so-called ANSI.

[jguinch]

I made some functions to help with languages changes.

I share it with you, maybe it can help.

It's very slow because of the use of Winnt object...

expandcollapse popup

Local $sUser = "tempadminö"
Local $sPassword = "secretpassword"

Local $sAdminGroupName = _GetAdminGroupName()

If _CreateLocalUser($sUser, $sPassword) Then _AddUserToGroup($sAdminGroupName, $sUser)



Func _GetAdminGroupName()
    Local $objWMIService = ObjGet("winmgmts:\\" & @ComputerName & "\root\CIMV2")
    If $objWMIService = 0 Then SetError(1, 0, 0)
   
    $colGroup = $objWMIService.ExecQuery("select * from Win32_Group Where SID = 'S-1-5-32-544'")
    If NOT IsObj($colGroup) Then SetError(1, 0, 0)

    For $oGroup In $colGroup
        Return $oGroup.Name
    Next
    
    Return 0
EndFunc



Func _CreateLocalUser($sUsername, $sPassword, $bPasswordNeverExpires = 1, $bUserCannotChangePassword = 1)
    Local $colAccounts = ObjGet("WinNT://" & @ComputerName & "")
    Local $objUser = $colAccounts.Create("user", $sUsername)
    Local $Flags = $objUser.Get("UserFlags")
    
    $objUser.SetPassword($sPassword)

    If $bPasswordNeverExpires Then $Flags = BitOr($Flags, 0x10000)
    If $bUserCannotChangePassword Then $Flags = BitOr($Flags, 0x0040)
    
    $objUser.put("Userflags", $Flags )

    $objUser.setinfo
    If @error Then Return SetError(1, 0, 0)
    
    Return 1
EndFunc



Func _AddUserToGroup($sGroup, $sUser)
    Local $objGroup = ObjGet("WinNT://" & @ComputerName & "/" & $sGroup & ",group")
    If NOT IsObj($objGroup) Then Return 0
    
    Local $objUser = ObjGet("WinNT://" & @ComputerName & "/" & $sUser & ",user")
    If NOT IsObj($objUser) Then Return 0
    
    $objGroup.Add($objUser.ADsPath)
    If @error Then Return SetError(1, 0, 0)
    
    Return 1
EndFunc