How to deselect an item in a List?

[Damein]

So I have two list's side by side and I am trying to make it so you can only select one item on each list. I have it setup like this:

$FavoriteListOnline = GuiCtrlCreateList("", 20,120,200,350)
    GUICtrlSetOnEvent(-1, "_OnlineSelected")
    $FavoriteListOffline = GuiCtrlCreateList("", 230,120,200,350)
    GUICtrlSetOnEvent(-1, "_OfflineSelected")

So I have a func that I want to run (_OnlineSelected or vice versa for offline) each time someone selects an item. And if that item is in a different List I want the other list deselected. Just not quite sure the command I need to send for this to happen ^^;

Thanks!

Edited May 10, 2014 by Damein

[Melba23]

Damein,

The only way I know is to reset the list data:

#include <GUIConstantsEx.au3>

$sData = "|Line 1|Line 2|Line 3|Line 4|Line 5"

$hGUI = GUICreate("Test", 500, 500)

$cList1 = GUICtrlCreateList("", 20, 120, 200, 350)
GUICtrlSetData($cList1, $sData)
$cList2 = GUICtrlCreateList("", 230, 120, 200, 350)
GUICtrlSetData($cList2, $sData)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cList1
            GUICtrlSetData($cList2, $sData)
        Case $cList2
            GUICtrlSetData($cList1, $sData)
    EndSwitch
WEnd

Any use?

M23

[Damein]

A little dirty, but it will do unless someone has a better way.

Sadly, each time I reset the list I need to do a check using InetRead but it's only about 1 line of text its reading so its not a large data transfer. But we'll see. Thanks!

[T0M50N]

You can do this with _GUICtrlListBox_SetCurSel($hWnd, $iIndex)

If you set $iIndex to -1 it removes the selection.

[Melba23]

T0M50N,

Excellent!

And just to prove it:

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>

$sData = "|Line 1|Line 2|Line 3|Line 4|Line 5"

$hGUI = GUICreate("Test", 500, 500)

$cList1 = GUICtrlCreateList("", 20, 120, 200, 350)
GUICtrlSetData($cList1, $sData)
$cList2 = GUICtrlCreateList("", 230, 120, 200, 350)
GUICtrlSetData($cList2, $sData)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cList1
            _GUICtrlListBox_SetCurSel($cList2, -1)
        Case $cList2
            _GUICtrlListBox_SetCurSel($cList1, -1)
    EndSwitch
WEnd

M23