slider question

[am632 3]

Hi,

I have a basic slider, with numbers between 1 & 100 and the slider works fine, I click a button which displays a msgbox containing the selected number from the slider control but is there a way I can make the slider show the current number as the user slides up & down - like in a small balloon tip above the slider for example? because the user doesnt know which number is selected until the msgbox is displayed.

Thanks

[jdelaney 281]

The helpfile example shows how to do that:

$hSlider = _GUICtrlSlider_Create($hGUI, 2, 2, 396, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))

Edited March 13, 2015 by jdelaney

[DocTorCoder 0]

Hi,

I have a basic slider, with numbers between 1 & 100 and the slider works fine, I click a button which displays a msgbox containing the selected number from the slider control but is there a way I can make the slider show the current number as the user slides up & down - like in a small balloon tip above the slider for example? because the user doesnt know which number is selected until the msgbox is displayed.

Thanks

you can do something like this

while 1
      changeslider()
       sleep(200)
Wend

Func changeslider()
    GUICtrlSetData($yourlabel,$yourslidervalue)
EndFunc

Or:

AdlibRegister("changeslider",200)

Func changeslider()
    GUICtrlSetData($yourlabel,$yourslidervalue)
EndFunc 

$yourslidervalue = slider which you created with current value

$yourlabel = a label which you will create it and will contain the slider value (put in below slider to look like is a part of slider)

Edited March 13, 2015 by DocTorCoder

[Melba23 2,805]

DocTorCoder,

Personally, I would wait until the slider was actually moved rather than run the function every time through the loop:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <SliderConstants.au3>
#include <WinAPI.au3>

Global $nTimer, $bToolTip = False

$hGUI = GUICreate("Test", 500, 500)

$cSlider = GUICtrlCreateSlider(10, 10, 200, 20, $TBS_AUTOTICKS)
$hSlider = GUICtrlGetHandle($cSlider)

GUISetState()

GUIRegisterMsg($WM_HSCROLL, "_WM_HSCROLL")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; If tooltip displayed and no change for 500ms
    If $bToolTip And TimerDiff($nTimer) > 500 Then
        ; Clear tootip
        ToolTip("")
        ; Clear flag
        $bToolTip = False
    EndIf

WEnd

; React to slider movement
Func _WM_HSCROLL($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg

    If $lParam = $hSlider Then
        If _WinAPI_LoWord($wParam) = 5 Then ;$SB_THUMBTRACK
            ; Show tooltip
            ToolTip(GUICtrlRead($cSlider))
            ; Set timestamp
            $nTimer = TimerInit()
            ; Set flag
            $bToolTip = True
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG

EndFunc   ;==>_WM_HSCROLL

When passing through the idle loop the flag is checked and nothing more happens until it is set. That means the slider has been moved and now there is a second check to get the time since the last movement - and then the tooltip is cleared if no movement has taken place for a given time.

M23

[am632 3]

Hi,

Thanks all for the help, Melba23 your example worked perfectly, Thanks

[jdelaney 281]

easier route:

#include <GuiSlider.au3>
#include <GUIConstantsEx.au3>
Example()

Func Example()

    GUICreate("slider", 220, 100, 100, 200)
    GUISetBkColor(0x00E0FFFF) ; will change background color

    Local $idSlider1 = GUICtrlCreateSlider(10, 10, 200, 20,BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
    GUICtrlSetLimit(-1, 200, 0) ; change min/max value
    GUISetState(@SW_SHOW)
    GUICtrlSetData($idSlider1, 45) ; set cursor

    Local $idMsg
    ; Loop until the user exits.
    Do
        $idMsg = GUIGetMsg()
    Until $idMsg = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

Edited March 13, 2015 by jdelaney

[DocTorCoder 0]

DocTorCoder,

Personally, I would wait until the slider was actually moved rather than run the function every time through the loop:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <SliderConstants.au3>
#include <WinAPI.au3>

Global $nTimer, $bToolTip = False

$hGUI = GUICreate("Test", 500, 500)

$cSlider = GUICtrlCreateSlider(10, 10, 200, 20, $TBS_AUTOTICKS)
$hSlider = GUICtrlGetHandle($cSlider)

GUISetState()

GUIRegisterMsg($WM_HSCROLL, "_WM_HSCROLL")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    ; If tooltip displayed and no change for 500ms
    If $bToolTip And TimerDiff($nTimer) > 500 Then
        ; Clear tootip
        ToolTip("")
        ; Clear flag
        $bToolTip = False
    EndIf

WEnd

; React to slider movement
Func _WM_HSCROLL($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg

    If $lParam = $hSlider Then
        If _WinAPI_LoWord($wParam) = 5 Then ;$SB_THUMBTRACK
            ; Show tooltip
            ToolTip(GUICtrlRead($cSlider))
            ; Set timestamp
            $nTimer = TimerInit()
            ; Set flag
            $bToolTip = True
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG

EndFunc   ;==>_WM_HSCROLL

When passing through the idle loop the flag is checked and nothing more happens until it is set. That means the slider has been moved and now there is a second check to get the time since the last movement - and then the tooltip is cleared if no movement has taken place for a given time.

M23

 

Correct,to avoid doing same thing when moving event is not there!