Help with defining arrays

[TheDcoder]

Hello, I am using this function:

Func ListScripts($sPath)
    Local $aFilesAU3 = _FileListToArray($sPath, "*.au3", 1, True)
    If @error = 4 Then
        Local $aFilesAU3[1]
        $aFilesAU3[0] = 0
    EndIf
    Local $aFilesA3X = _FileListToArray($sPath, "*.a3x", 1, True)
    If @error = 4 Then
        Local $aFilesA3X[1] = 0
        $aFilesA3X[0] = 0
    EndIf
    If $aFilesAU3[0] = 0 And $aFilesAU3[0] = 0 Then Return
    Local $aReturn[UBound($aFilesAU3) + UBound($aFilesA3X) - 2]
    $aReturn[0] = $aFilesAU3[0] + $aFilesA3X[0]
    $iFileCount = $aFilesAU3[0] + $aFilesA3X[0]
    For $i = 1 To $aFilesAU3[0]
        $aReturn[$i] = $aFilesAU3[$i]
    Next
    _ArrayConcatenate($aReturn, $aFilesA3X, 1)
    Return $aReturn
EndFunc

But It works only when the path contains both au3 & a3x files

I get this error: Missing subscript dimensions in "Dim" statement.

 

Thanks in advance, TD

[iamtheky]

If $aFilesAU3[0] = 0 And $aFilesAU3[0] = 0

going to guess you meant to check the a3x array with one of those

[Luigi]

You can try:

Local $aFilesAU3 = _FileListToArrayRec($sPath, "*.au3;a3x", 1, True)

 

[jguinch]

Instead of using _FileListToArray twice, you could use _FileListToArrayRec in non-recursive mode :

#Include <Array.au3>
#Include <File.au3>

ListScripts(@ScriptDir)

Func ListScripts($sPath)
    Return _FileListToArrayRec($sPath, "*.au3;*.a3x", 1, 0, 0, 1)
EndFunc

Edit : Luigi was faster...

Edited May 2, 2015 by jguinch

[Melba23]

TheDcoder,

This works for me:

#include <Array.au3>
#include <File.au3>

$sPath = @ScriptDir



_ArrayDisplay(ListScripts($sPath), "", Default, 8)

Func ListScripts($sPath)
    Local $aFilesAU3 = _FileListToArray($sPath, "*.au3", 1, True)
    If @error = 4 Then
        Local $aFilesAU3[1] = [0]
    EndIf

    Local $aFilesA3X = _FileListToArray($sPath, "*.a3x", 1, True)
    If @error = 4 Then
        Local $aFilesA3X[1] = [0]
    EndIf

    ; Check if any returns
    If $aFilesAU3[0] + $aFilesAU3[0] = 0 Then Return "" ; Best to return something!
    ; Concatenate the arrays
    _ArrayConcatenate($aFilesAU3, $aFilesA3X, 1)
    ; Add the count of the second array
    $aFilesAU3[0] += $aFilesA3X[0]
    ; Return the concatenated array
    Return $aFilesAU3
EndFunc

M23

[TheDcoder]

Thanks @Luigi & @jguinch!

I adopted Melba's version of ListScripts, Thanks a lot @Melba23 for the less resource consumptive function