Manipulating a function

[bahjat]

the code that i have written is extremely long so i will post only the part i am having trouble with. I am trying to make the function "_EncryptionProcess" take the arrays 1 by 1 and then process them. Unfortunately after much reading on this forum i have realised that you cant have functions inside For loops. 
 The location in which the arrays need to be taken is where the "$aArray" is typed, the arrays are stored in this value. The other variable defines the key size being used and the key value being used. 

;Cuts the input up into piece; 
$VariableToBeCut = "12345678"
$aArray = StringRegExp($VariableToBeCut, ".{2}", 3)
MsgBox(0, "die", $aArray[0]) ; personal check to make sure array works


$DataToBeEncrypted=_EncryptionProcess($aArray, $keyvalue, $keysize, 1) ;$aArray needs to be where the different arrays are processed
MsgBox(0, "Encrypted data", $DataToBeEncrypted)

 

[Melba23]

bahjat,

Unfortunately after much reading on this forum i have realised that you cant have functions inside For loops

Really? You cannot define functions inside loops, but there is nothing to prevent you from calling them. And the code you posted should run - although you will need to extract the elements from the array you pass as a parameter within the _EncryptionProcess function.  This shows the how you might do it:

expandcollapse popup

#include <Array.au3>
#include <MsgBoxConstants.au3>

Global $keysize, $keyvalue = "-simulate-encrypted"

$VariableToBeCut = "12345678"
$DataToBeEncrypted = StringRegExp($VariableToBeCut, ".{2}", 3)

; Display original data
_ArrayDisplay($DataToBeEncrypted, "Before", Default, 8)

; Pass array to encryption process
$aDataAfterEncryption = _EncryptionProcess($DataToBeEncrypted, $keyvalue, $keysize, 1) ;$aArray needs to be where the different arrays are processed

; Display returned data
_ArrayDisplay($aDataAfterEncryption, "After", Default, 8)

Func _EncryptionProcess($aArray, $keyvalue, $keysize, $iVal)

    For $i = 0 To UBound($aArray) - 1
        ; Display each element
        MsgBox($MB_SYSTEMMODAL, "Unencrypted data", $aArray[$i])
        ; Call a function from inside the loop to encrypt the value
        $aArray[$i] = _Encrypt($aArray[$i])
    Next
    ; Return amended array
    Return $aArray

EndFunc

Func _Encrypt($sString)

    ; Simulate encryption
    $sString = $sString & $keyvalue
    ; Return encrupted value
    Return $sString

EndFunc

Does that help explain how to do what you require? 

M23