Rfsvieira

Gui + Combobox setdata from other comboboxs choices

11 posts in this topic

#1 ·  Posted (edited)

Hello, i past only part of the code

I´m trying to create a new list depeding  of the choices of the combobox 1,2, and 3, for the combobox 10

If i ask the choice in the mensage box it respondes correctely, but if i click on the combobox10 it is empty doesnt add the $ps1 (choice of combobox1)

I get the probleme alredy, is because wen i create the combox10 and the setdata, is before the variable get the value.

Is there any way to add the combobox inside the loop?

while 1

.....

case $????

$Combo10 = GUICtrlCreateCombo("Corpo", 273, 53, 75, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData($combo10, $ps1)

Any ideas??

sorry i creat 3 quots and dont know how to erase the 2 empty ones

Thanks

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$dir =("FU\")



#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 500, 400, 224, 137)

$Button1 = GUICtrlCreateButton("reade var $ps1", 6, 360, 40, 20)
GUICtrlSetFont(-1, 8, 400, 0, "Arial")


$Pic1 = GUICtrlCreatePic("", 41, 51, 25, 25)
$Pic2 = GUICtrlCreatePic("", 41, 83, 25, 25)
$Pic3 = GUICtrlCreatePic("", 41, 113, 25, 25)

$Combo1 = GUICtrlCreateCombo("Corpo", 73, 53, 75, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
jcorpo($combo1); this funcion will show list of itens
$Combo2 = GUICtrlCreateCombo("Corpo", 73, 85, 75, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
jcorpo($combo2)
$Combo3 = GUICtrlCreateCombo("Corpo", 73, 115, 75, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
jcorpo($combo3)


$Pic10 = GUICtrlCreatePic("", 241, 51, 25, 25)
$Combo10 = GUICtrlCreateCombo("Corpo", 273, 53, 75, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData($combo10, $ps1 &"|"& $ps2 &"|"& $ps3); doesnt work, supostely should get the choice of combo1,1 and 3

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1

    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $Button1
            MsgBox("0", "test", $ps1, "3")
        Case $combo1
            $ps1 = GUICtrlRead($combo1)
            img1($combo1, $Pic1, 41, 51); this funcion will show one image depending the choice
        case $combo2
            $ps2 = GUICtrlRead($combo2)
            if $ps2 = $ps1 Then

            MsgBox("0", "ERRO", "Repetindo seleção",2)
            Else

            img1($combo2, $pic2, 41, 83)
            EndIf

        Case $combo3
            $ps3 = GUICtrlRead($combo3)
            if $ps3 = $ps2 or $ps3 = $ps1 Then

            MsgBox("0", "ERRO", "Repetindo seleção",2)
            Else

            img1($combo3, $Pic3, 41, 113)
            EndIf

        case $combo10
            img1($combo10, $pic10, 41, 145)

             Case $GUI_EVENT_CLOSE
                 Exit


    EndSwitch

WEnd


 

 

 

 

 

Edited by Rfsvieira

Share this post


Link to post
Share on other sites



#2 ·  Posted (edited)

Something like this maybe:

$hMain=GUICreate("Test")

$idCombo1=GUICtrlCreateCombo("One",10,10)
GUICtrlSetData($idCombo1,"Two")
$idCombo2=GUICtrlCreateCombo("A",10,40)
GUICtrlSetData($idCombo2,"B")

$idCombo3=GUICtrlCreateCombo("",10,70) ;this is the combobox that will be populated depending on selection from Combo1 and Combo2

Global $Combo1Text=GUICtrlRead($idCombo1), $Combo2Text=GUICtrlRead($idCombo2) ;read current selections and store them inside some variables
Global $Combo1NewText, $Combo2NewText ; when an combobox gets actioned its selection will be stored in these variables

GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $idCombo1
            $Combo1NewText=GUICtrlRead($idCombo1)
            If $Combo1NewText<>$Combo1Text Then ;if selection has been changed then proceed
                $Combo1Text=$Combo1NewText
                GUICtrlSetData($idCombo3,$Combo1Text & ", " & $Combo2Text) 
            EndIf
        Case $idCombo2
            $Combo2NewText=GUICtrlRead($idCombo2)
            If $Combo2NewText<>$Combo2Text Then
                $Combo2Text=$Combo2NewText
                GUICtrlSetData($idCombo3,$Combo1Text & ", " & $Combo2Text) 
            EndIf
    EndSwitch
WEnd

 

Edited by ahmet

Share this post


Link to post
Share on other sites

Thanks ahmet

its almost what i want and need, e make some changes but have for now 1 problem

combo1 - options - one|two|tree

combo2 - options - A|B|C

I add the "|" to appear in list, theproble is that it sume all choises, imagine option One our A its add only if i choice other and then goes to A our One,

i know how resolve it, i dont know is how to resolve the sume, if i choise A for mistake our B , and the i figure that i want is C, wen i go to the combo3 there will be all Choises maked and not the last choise

Thanks for help

 

$hMain=GUICreate("Test")

$idCombo1=GUICtrlCreateCombo("One",10,10)
GUICtrlSetData($idCombo1,"Two|three|four"); list of choices
$idCombo2=GUICtrlCreateCombo("A",10,40)
GUICtrlSetData($idCombo2,"B|C|D|E")

$idCombo3=GUICtrlCreateCombo("",10,70) ;this is the combobox that will be populated depending on selection from Combo1 and Combo2

Global $Combo1Text=GUICtrlRead($idCombo1), $Combo2Text=GUICtrlRead($idCombo2) ;read current selections and store them inside some variables

Global $Combo1NewText, $Combo2NewText ; when an combobox gets actioned its selection will be stored in these variables



GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $idCombo1
            $Combo1NewText=GUICtrlRead($idCombo1)
            If $Combo1NewText<>$Combo1Text Then ;if selection has been changed then proceed (understand)

                $Combo1Text=$Combo1NewText
                ;GUICtrlSetData($idCombo3,$Combo1Text & ", " & $Combo2Text); I dasactiv it because was duplicating
            EndIf

        Case $idCombo2
            $Combo2NewText=GUICtrlRead($idCombo2)
            If $Combo2NewText<>$Combo2Text Then

                $Combo2Text=$Combo2NewText

            EndIf

            GUICtrlSetData($idCombo3, $Combo1Text & "|" & $Combo2Text)
    EndSwitch
WEnd

 Thanks it helps nnow i know that is possible i have another problema with tabs afterresolv it i will place in new post

Share this post


Link to post
Share on other sites

Can you write expected results like this:

Combo1: One; Combo2: A; Result: One A
Combo1=One; Combo2: C; Result: previous data + One C

Or something that looks like the above text

Share this post


Link to post
Share on other sites

Sorry, i didnt understand :(

 

like is now the code, if i change the combo1 to B, and if i change to C, because i didnt want the B

Wen i go to the combo3, it will have all (B, C), But what i want is that ther only have C, because was the last option

I thing

Combo1: One; Combo2: A; Result: One A
Combo1=One; Combo2: C; Result: previous data + One C; this is what i thing i want, how i apply it to my code?

I have 14 combobox, with 10 option every one, and i only want to have in (combo3) the 14 choices, this my example, but i dont get how i make it if i make changes for mistake or somthing like it.

Can you past your code idea?

Thanks for your time, sorry im basic for now in autoit, hope in future increse my knowlege

 

Share this post


Link to post
Share on other sites

I think the following code should help

#include <GuiComboBox.au3>

Global $bRemoved=0
$hMain=GUICreate("Test")

$idCombo1=GUICtrlCreateCombo("One",10,10)
GUICtrlSetData($idCombo1,"Two|three|four"); list of choices
$idCombo2=GUICtrlCreateCombo("A",10,40)
GUICtrlSetData($idCombo2,"B|C|D|E")

$idCombo3=GUICtrlCreateCombo("",10,70) ;this is the combobox that will be populated depending on selection from Combo1 and Combo2

Global $Combo1Text=GUICtrlRead($idCombo1), $Combo2Text=GUICtrlRead($idCombo2) ;read current selections and store them inside some variables

Global $Combo1NewText, $Combo2NewText ; when an combobox gets actioned its selection will be stored in these variables



GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $idCombo1
            $Combo1NewText=GUICtrlRead($idCombo1)
            If $Combo1NewText<>$Combo1Text Then ;if selection has been changed then proceed (understand)
                $bRemoved=_GuiCtrlComboBox_RemoveString($idCombo3, $Combo1Text, $Combo1NewText)
                $Combo1Text=$Combo1NewText
                If $bRemoved=0 Then GUICtrlSetData($idCombo3, $Combo1Text & "|" & $Combo2Text); I dasactiv it because was duplicating
            EndIf
            ;GUICtrlSetData($idCombo3, $Combo1Text & "|" & $Combo2Text)
        Case $idCombo2
            $Combo2NewText=GUICtrlRead($idCombo2)
            If $Combo2NewText<>$Combo2Text Then
                $bRemoved=_GuiCtrlComboBox_RemoveString($idCombo3, $Combo2Text, $Combo2NewText)
                $Combo2Text=$Combo2NewText
                If $bRemoved=0 Then GUICtrlSetData($idCombo3, $Combo1Text & "|" & $Combo2Text) ; if string was not replaced then add manually
            EndIf

    EndSwitch
WEnd

;Function _GuiCtrlComboBox_RemoveString removes string from combobox and replaces it eith the new string, and also returns 1 if strig has benn replaced or 0 otherwise
Func _GuiCtrlComboBox_RemoveString($hWnd, $sOldText, $sReplaceWithText)
    Local $iIndex=_GUICtrlComboBox_FindStringExact($hWnd, $sOldText) ;find index of string you want to change
    If $iIndex<>-1 Then ; if the string has been found do the following
        _GUICtrlComboBox_DeleteString($hWnd, $iIndex)
        _GUICtrlComboBox_InsertString($hWnd,$sReplaceWithText,$iIndex)
        Return 1
    Else ; the string $sOldText has not been found
        Return 0
    EndIf
EndFunc

 

Share this post


Link to post
Share on other sites

Very very thanks, is that, the code in the funcion i didnt know, will try read abou it in  the help file, thanks a lot is that i was nedding

and work like i want :=))))))))

Thanks for your time

Share this post


Link to post
Share on other sites

You are welcome :)

Share this post


Link to post
Share on other sites

#9 ·  Posted (edited)

Rfsvieira,

Following our PM exchange, here is my version of how you might do this. Remember computers are really fast - so where humans always look for the small changes to limit the work, computers can run whole repetitive loops. So we just look for any combo to be actioned and then reload the third - using a leading "|" to completely replace the data rather than removing the old entries:

#include <GUIConstantsEx.au3>

; Array to hold combo ControlIDs
Global $aCombo[3]

$hMain = GUICreate("Test")

$aCombo[1] = GUICtrlCreateCombo("One", 10, 10)
GUICtrlSetData($aCombo[1], "Two|Three|Four") ; list of choices
$aCombo[2] = GUICtrlCreateCombo("A", 10, 40)
GUICtrlSetData($aCombo[2], "B|C|D|E")

$idCombo3 = GUICtrlCreateCombo("", 10, 70) ; this is the combobox that will be populated depending on selection from Combo1 and Combo2

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $aCombo[1], $aCombo[2]                 ; Whenever a combo is actioned

            $sNewData = _ReadCombos()               ; Read all combos
            GUICtrlSetData($idCombo3, $sNewData)    ; Reset the data in the dependent combo
    EndSwitch

WEnd



Func _ReadCombos()

    ; Will hold combo contents
    $sData = ""
    ; Loop through combos
    For $i = 1 To 2
        ; Note leading "|" even for first element - that way this data will replace the existing content 
        $sData &= "|" & GUICtrlRead($aCombo[$i])
    Next
    ; Return the string ready for loading
    Return $sData

EndFunc

M23

Edited by Melba23
Added more explanation

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Hello, very thanks its working, im not gething is the comparations if repet working..

Thomowro i wll try add the timing (for loop the functions)

Any idea?

Case $idCombo[1], $idCombo[2], $idCombo[3], $idCombo[4], $idCombo[5], $idCombo[6], $idCombo[7]
            _Image($idcombo[1], $cPic_1)

            _Image($idcombo[2], $cPic_2)

            _Image($idcombo[3], $cPic_3)

            _Image($idcombo[4], $cPic_4)

            _Image($idcombo[5], $cPic_5)

            _Image($idcombo[6], $cPic_6)

            _Image($idcombo[7], $cPic_7)

        For $i = 2 To 7
        If GUICtrlRead($idcombo[1]) == GUICtrlRead ($idcombo[$i]) or GUICtrlRead($idcombo[2]) == GUICtrlRead ($idcombo[$i+1]) Then
        MsgBox("", "ERROR", "repetitions of options", 3);If chose the same it informe that canot be igual
        EndIf
   Next



$sNewData = _ReadCombos()               ; Read all combos
            GUICtrlSetData($idCombo15, $sNewData)    ; Reset the data in the dependent combo

        Case $idCombo15
            $c15 = GUICtrlRead($idCombo15)
            _Image($idCombo15, $cPic_15)
            
            
            

_pos($c15)

EndSwitch

WEnd

func _pos($tt)
if $tt = GUICtrlRead($idcombo[1]) Then
MsgBox("","","ps1")
EndIf
if $tt = GUICtrlRead($idcombo[2]) Then
MsgBox("","","ps2")
EndIf

EndFunc

 

Share this post


Link to post
Share on other sites

#11 ·  Posted (edited)

Rfsvieira,

This seems to work just fine for me - you cannot select the same item more than once and the dependent combo fills with the selections:

#include <GuiConstantsEx.au3>
#include <GuiTab.au3>
#include <GuiComboBox.au3>
#include <Array.au3>

Global $sDir = @ScriptDir & "\"

; Arrays to hold combo and pic ControlIDs
Global $aCombo_1[4], $aPic_1[4]
; Array to hold initial combo data and linked images
Global $aComboData[8][2] = [[0, 0], ["1", "1.bmp"], _
                                    ["2", "2.bmp"], _
                                    ["3", "3.bmp"], _
                                    ["4", "4.bmp"], _
                                    ["5", "5.bmp"], _
                                    ["6", "6.bmp"], _
                                    ["7", "7.bmp"]]

$hGUI = GUICreate("Test Script", 500, 500)

$cTab = GUICtrlCreateTab(5, 10, 500, 450)

$cTab_0 = GUICtrlCreateTabItem("Tab 0")

$cTab_1 = GUICtrlCreateTabItem("Tab 1")

; use a loop to fill the arrays with the ControlIDs
For $i = 1 To 3
    $aCombo_1[$i] = GUICtrlCreateCombo("", 50, 170 + (30 * $i), 65, 25)
    _GUICtrlComboBox_SetCueBanner($aCombo_1[$i], "Corpo")
    GUICtrlSetFont($aCombo_1[$i], 8, 400, 0, "Arial")
    _jcorpo($aCombo_1[$i])
    $aPic_1[$i] = GUICtrlCreatePic("", 15, 170 + (30 * $i), 25, 25)
Next

$cTab_2 = GUICtrlCreateTabItem("Tab 2")

; Create dependent combo and pic control
$cCombo_2 = GUICtrlCreateCombo("", 50, 200, 65, 25)
$cPic_2 = GUICtrlCreatePic("", 15, 200, 25, 25)

GUICtrlCreateTabItem("")

; Button to move to next tab
$cSwitch = GUICtrlCreateButton("Switch Next", 20, 470, 80, 20)

GUISetState(@SW_SHOW, $hGUI)

While 1
    $iMsg = GUIGetMsg()
    Switch $iMsg

        Case $GUI_EVENT_CLOSE
            Exit

        Case $cSwitch
            ; Much more elegant way to move to the next tab
            _GUICtrlTab_SetCurSel($cTab, Mod(_GUICtrlTab_GetCurSel($cTab) + 1, 3))

        Case $cCombo_2
            ; Read combo selection
            $sSel = GUICtrlRead($cCombo_2)
            ; Find associated image
            $iImage = _ArraySearch($aComboData, $sSel, 0, 0, 0, 0, 1, 0)
            ; Set image
            GUICtrlSetImage($cPic_2, $sDir & $aComboData[$iImage][1])

        Case Else
            For $i = 1 To 3
                ; Check if a combo
                If $iMsg = $aCombo_1[$i] Then
                    ; Check if a valid choice
                    If _Check($i) Then
                        ; Set correct image
                        _Image($i)
                        ; Get selected combo items to add to dependent combo in Tab 2
                        $sData = ""
                        For $i = 1 To 3
                            ; Read combo
                            $sSel = GUICtrlRead($aCombo_1[$i])
                            ; If somethign selected then add to list
                            If $sSel Then
                                $sData &= "|" & $sSel
                            EndIf
                        Next
                        ; Add to combo
                        GUICtrlSetData($cCombo_2, $sData)
                    Else
                        ; Set combo back to default state
                        _jcorpo($aCombo_1[$i])
                    EndIf
                    ; No point in checking further
                    ExitLoop
                EndIf
            Next

    EndSwitch
WEnd

Func _Image($iIndex)

    ; Get combo selection
    $sSel = GUICtrlRead($aCombo_1[$iIndex])
    ; get associated image
    $iImage = _ArraySearch($aComboData, $sSel, 0, 0, 0, 0, 1, 0)
    ; Set image
    GUICtrlSetImage($aPic_1[$iIndex], $sDir & $aComboData[$iImage][1])

EndFunc   ;==>_Image

Func _jcorpo($cCombo)

    ; read data from the combo data array
    $sData = ""
    For $i = 1 To UBound($aComboData) - 1
        $sData &= "|" & $aComboData[$i][0]
    Next
    GUICtrlSetData($cCombo, $sData)

EndFunc   ;==>_jcorpo

Func _Check($iIndex)

    ; Get contents of other combos
    $sData = ""
    For $i = 1 To 3
        If $i <> $iIndex Then
            $sData &= "|" & GUICtrlRead($aCombo_1[$i])
        EndIf
    Next
    $sData &= "|"
    ; Read content of the actioned combo
    $sSel = "|" & GUICtrlRead($aCombo_1[$iIndex]) & "|"
    ; Now check there is not another instance of the selection
    If StringInStr($sData, $sSel) Then
        ; Return "error" state
        Return False
    EndIf
    ; Return "no error" state
    Return True 

EndFunc

Func _exit()
    Exit
EndFunc   ;==>_exit

How about you?

M23

Edit: The BMPs I used - put them in the same folder as the script:

 

Edited by Melba23
Added BMPs

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now

  • Similar Content

    • anusha
      By anusha
      Hi I have jus started using auto-it . Please correct me if I'm wrong.
      I need to read data from an input in text box and search in excel file and return value in next column of matched cell on GUI.
      I have written below code but i cannot use variable which has data stored. it works only when search string is hard coded.
      Please help out.
       
      Example()
      Func Example()
      Local $GuiMain = GUICreate("EXCEL TEST", 399, 180) ;creates main GUI
      ;~ Local $idOK = GUISetOnEvent($GUI_EVENT_CLOSE, "Close")
      Local $iWidthCell = 70
      Local $idLabel = GUICtrlCreateLabel("PART NUMBER", 10, 30, $iWidthCell,50)
      Local $RUN_1 = GUICtrlCreateButton("OK", 70, 70, 85, 25)
      Local $Input_1 = GUICtrlCreateInput("PART NUMBER", 100, 20, 120, 20)
      Local $sMenutext = GUICtrlRead($Input_1, 1)
      GUISetState(@SW_SHOW, $GuiMain)

          While 1
          $MSG = GUIGetMsg()
          Select
              Case $MSG = $GUI_EVENT_CLOSE
                  Exit
              Case $MSG = $RUN_1
                  Local $oAppl = _Excel_Open()

      Local $sFilePath1 = "D:\Anu_WorkFolder\Components.xlsx"
      Local $oWorkbook = _Excel_BookOpen($oAppl, $sFilePath1, Default, Default, True)
      Local $aResult = _Excel_RangeFind($oWorkbook, $sMenutext , Default, Default, $xlWhole)
    • Miliardsto
      By Miliardsto
      Hello.
      Drag option works only on parent window but as we can see on the parent gui is showed up child gui (on the right side with the color).
      Desired action is when we want to drag whole program we can also drag child gui and child gui will drag with parent gui.
      How to do this?
       
      #include <GUIConstantsEx.au3> #include <WindowsConstants.au3> #include <Array.au3> GUIRegisterMsg($WM_NCHITTEST, "_NCHITTEST") $hGUI = GUICreate("Test", 500, 500, -1, -1) $cButton_0 = GUICtrlCreateButton("Child 0", 10, 10, 80, 30) $cButton_1 = GUICtrlCreateButton("Child 1", 10, 50, 80, 30) $cButton_2 = GUICtrlCreateButton("Child 2", 10, 90, 80, 30) GUISetState(@SW_SHOW, $hGUI) ; guis Global $hChild_[3] Global $countGUI = UBound($hChild_) - 1 ;MsgBox("","",$countGUI) ; licznik dla GUI Global $gui = 0 $hChild_[0] = GUICreate("Child 0", 350, 300, 150, 0, $WS_POPUP, $WS_EX_MDICHILD, $hGUI) GUISetBkColor(0xFF0000) GUISetState(@SW_SHOW, $hChild_[0]) $hChild_[1] = GUICreate("Child 1", 350, 300, 150, 0, $WS_POPUP, $WS_EX_MDICHILD, $hGUI) GUISetBkColor(0x00FF00) GUISetState(@SW_HIDE, $hChild_[1]) $hChild_[2] = GUICreate("Child 2", 350, 300, 150, 0, $WS_POPUP, $WS_EX_MDICHILD, $hGUI) GUISetBkColor(0x0000FF) GUISetState(@SW_HIDE, $hChild_[2]) While 1 Switch GUIGetMsg() Case $GUI_EVENT_CLOSE Exit Case $cButton_0 _All_Hide() GUISetState(@SW_SHOW, $hChild_[0]) $gui = 0 Case $cButton_1 _All_Hide() GUISetState(@SW_SHOW, $hChild_[1]) $gui = 1 Case $cButton_2 _All_Hide() GUISetState(@SW_SHOW, $hChild_[2]) $gui = 2 EndSwitch WEnd Func _All_Hide() GUISetState(@SW_HIDE, $hChild_[0]) GUISetState(@SW_HIDE, $hChild_[1]) GUISetState(@SW_HIDE, $hChild_[2]) EndFunc Func _NCHITTEST($hWnd, $uMsg, $wParam, $lParam) If $hWnd = $hGUI Then Local $aPos = WinGetPos($hWnd) If Abs(BitAND(BitShift($lParam, 16),0xFFFF)- $aPos[1]) < 500 Then Return $HTCAPTION EndIf Return $GUI_RUNDEFMSG EndFunc  
    • IAMK
      By IAMK
      Hello,
       
      I have a script which uses a GUI with two buttons. It gets shown and hidden., and pressing the buttons (including their hotkeys) highlights the button, making you able to press enter the next time.
      However, I don't want that.
       
      I've tried using WinActivate() to make enter do things on another program, but the enter is still tied to the AutoIT GUI (which still has the button highlighted).
       
      Here's the important part of my code:
      $MY_GUI = GUICreate("Check.exe", 400, 300, ((@DesktopWidth / 2) - 200), -500) WinSetOnTop($MY_GUI, "", 1) ;Keeps the window on the top. $Button1 = GUICtrlCreateButton("Pass (Ctrl+P)", 40, 250, 120, 40, $WS_GROUP) GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif") $Button2 = GUICtrlCreateButton("Fail (Ctrl+F)", 240, 250, 120, 40, $WS_GROUP) GUICtrlSetFont(-1, 12, 400, 0, "MS Sans Serif") $GUIText = GUICtrlCreateLabel("", 20, 10, 360, 230) GUICtrlSetFont(-1, 13, 400, 0, "MS Sans Serif") GUICtrlSetData($GUIText, Execute($stepMessage[$step])) $showGUI = "True" GUISetState(@SW_SHOW) While($showGUI = "True") $buttonPressed = GUIGetMsg() Switch $buttonPressed Case $Button1 ;Pass $pass = "True" $buttonPressed = 0 $showGUI = "False" GUISetState(@SW_HIDE) Case $Button2 ;Fail $buttonPressed = 0 $showGUI = "False" GUISetState(@SW_HIDE) While($message = "") $message = InputBox("Check.exe", "Please enter the reason the step failed." & @CRLF, "", "", 300, 200, ((@DesktopWidth / 2) - 150), -400) WEnd Return $message EndSwitch WEnd Local $pass = "False" ;Whether "Pass" or "Fail" was pressed. Local $failLog = xxxfunc($pass) ;Returns a message to log if the step failed. ##THIS CALLS THE CODE SNIPPET ABOVE## FileWrite($file, _Now() & ": Step " & $step & getStatus($pass) & "and took " & Ceiling(TimerDiff($timer) / 1000) & " seconds." & @CRLF) If($failLog <> "") Then FileWrite($file, "Logged comment: " & $failLog & @CRLF) EndIf WinActivate("[TITLE:ProgramName]") ;Hotkeys: HotKeySet("^{p}", "pressPass") HotKeySet("^{f}", "pressFail") Func pressPass() $buttonPressed = $Button1 EndFunc Func pressFail() $buttonPressed = $Button2 EndFunc  
      The GUI's button/hotkey pressing works correctly.
      The same WinActivate code works in another script of mine.
      Together, WinActivate is not take "Active" away from the GUI's last-pressed button. How do I fix this?
       
      Thank you in advance.
    • fatpig
      By fatpig
      Dear AutoIT Community.
      I am currently working on a program that will display lots of images in a scroll down GUI.
      I create the GUI based on the number of images, which works fine.
      But all images I place using GuiCtrlCreatePic above a threshold of around 32000 pixels (cant say exactly) are placed at negative locations and finally will reach 0 again
      and will then populate on top of the images placed there before.
      For $i = 1 To $Images[0] ; Get picture dimensions $hImage = _GDIPlus_ImageLoadFromFile($ImgRep & $Images[$i]) $iX = _GDIPlus_ImageGetWidth($hImage) $iY = _GDIPlus_ImageGetHeight($hImage) _GDIPlus_ImageDispose($hImage) ; Resize & place images in GUI $Pic[$i] = GUICtrlCreatePic($ImgRep & $Images[$i], $Spacer, Round($yPos, 0), $MaxImgWidth, $MaxImgWidth * ($iY / $iX)) $yPos = $yPos + $MaxImgWidth * ($iY / $iX) + $Spacer $log = $log & "|" & $yPos $currentlut = $Images[1] Next I have found a limit at 32767 pixels for some GUI elements when googling around.
      Can someone tell me how to circumvent that?
      thanks!
      cheers
      Felix
    • Shirdish_chakravarthi
      By Shirdish_chakravarthi
      Hello Guys this is my gui and i need the numeric value typed in the highlighted  inputbox. if this value is greater than 1 i need to perform some operations
      \
       
      Here is the summary about that field which i got from wininfo tool

      i tried writing the code as shown below.. but the msgbox is popping up empty value..when the same code is pasted under some button action i am able to access the value present in the field..but when placed alone as written in the attached script i am unable to fetch it... 

      here i am using the valu present in the field

      can you guys tell me what's wrong??? or how can i get that value?
       
      My_GUI.au3