[SOLVED] Reverse state of button

[pinkfoyd]

Hi,

 

I remember a script where i had seen an user inverse state of a button ( $GUI_ENABLE (64)   /  $GUI_DISABLE (128) ) in one line only

I remember it use Bit operation but i cannot reproduce it, can someone help ?

 

In fact if the button is enable i want to disable it and if he is disable , want to enable it, something like that :

 

GuiCtrlSetState ( $button , BitOr ( GuiCtrlGetSate ( $button ) )        ; i know this is NOT working, for explanation only

 

 

Thanks !

Edited August 9, 2016 by pinkfoyd

[pinkfoyd]

Finding myself

 

 

GUICtrlSetState($Button1, BitXOR ( GUICtrlGetState($Button1) , 11000000))

[funkey]

Another one:

#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $Button_1, $Button_2, $Button_3, $Button_4, $msg, $state2, $state3, $state4
    GUICreate("My GUI Button") ; will create a dialog box that when displayed is centered

    Opt("GUICoordMode", 2)
    $Button_1 = GUICtrlCreateButton("Button1 - Click me", 10, 30, 150)
    $Button_2 = GUICtrlCreateButton("Button2", -1, 0)
    $Button_3 = GUICtrlCreateButton("Button3", -1, 0)
    $Button_4 = GUICtrlCreateCheckbox("Button4", -1, 0)

    GUISetState() ; will display an  dialog box with 2 button

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $Button_1
                $state2 = BitXOR(GuiCtrlGetState($Button_2), BitOR($GUI_DISABLE, $GUI_ENABLE))
                $state3 = BitXOR(GuiCtrlGetState($Button_3), BitOR($GUI_SHOW, $GUI_HIDE))
                $state4 = BitXOR(GuiCtrlRead($Button_4), BitOR($GUI_CHECKED, $GUI_UNCHECKED))
                GUICtrlSetState($Button_2, $state2)
                GUICtrlSetState($Button_3, $state3)
                GUICtrlSetState($Button_4, $state4)
        EndSelect
    WEnd
EndFunc   ;==>Example

 

Edited August 9, 2016 by funkey

[pinkfoyd]

Cleaner ! Thanks !