Get Listview content issue

[Valnurat]

I don't understand why I can't get the picked content from a Listview.

The content in my listview has been added with an array.

When I press the $idNewEntry I just get a message with 0 as returned.

Do I do something wrong?

 

expandcollapse popup

Global $idListview, $idOKay, $hMainForm, $idNewEntry, $idEditEntry, $aMsg, $hNewEntry, $idNewOKay, $idNewCancel


_MainFormCreate()
_Main()


Func _MainFormCreate()
    ; Create GUI
    $hMainForm = GUICreate("Computer Asset", 1027, 400)
    $idListview = GUICtrlCreateListView("", 2, 2, 1024, 268);,Default, BitOR($LVS_SHOWSELALWAYS, $LVS_EX_GRIDLINES,$LVS_EX_FULLROWSELECT))

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Computername", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Tkt No.", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Req No.", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Order Date", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Costcenter", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Username", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Model", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Current Location", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Option", 100,2)
    _GUICtrlListView_AddColumn($idListview, "Shipdate", 100,2)
    $idNewEntry = GUICtrlCreateButton("New", 310, 290, 85, 25)
    $idEditEntry = GUICtrlCreateButton("New", 310, 290, 85, 25)
    GUISetState()
EndFunc

Func _NewFormCreate()
    $hNewEntry = GUICreate("Create New", 500, 500, -1, -1,-1,-1,$hMainForm)
    $idNewOKay = GUICtrlCreateButton("Ok", 110, 290, 85, 25)
    $idNewCancel = GUICtrlCreateButton("Cancel", 310, 290, 85, 25)
    GUISetState()
EndFunc

Func _Main()
    Local $sConnectionString = 'DRIVER={' & $sDriver & '};SERVER=' & $sServer & ';DATABASE=' & $sDatabase & ';UID=' & $sUser & ';PWD=' & $sPassword & ';'
    Local $oConnection = _ADO_Connection_Create()
    _ADO_Connection_OpenConString($oConnection, $sConnectionString)
    If @error Then Return SetError(@error, @extended, $ADO_RET_FAILURE)
    Local $sTableName = 'StaffMemberUser.ComputerAsset'
    Local $sQUERY = "Select Computername, TktNo, ReqNo, OrderDate, CostCenter, Username, Model, CurrentLocation, Note, Shipdate from " & $sTableName
    Local $oRecordset = _ADO_Execute($oConnection, $sQUERY)
    Local $aRecordsetArray = _ADO_Recordset_ToArray($oRecordset, False)
    Local $aRecordset_inner = _ADO_RecordsetArray_GetContent($aRecordsetArray)

    _GUICtrlListView_SetItemCount($idListview, UBound($aRecordset_inner) - 1)

    _GUICtrlListView_AddArray($idListview, $aRecordset_inner)

    ; CleanUp
    $oRecordset = Null
    _ADO_Connection_Close($oConnection)
    $oConnection = Null
    ; Loop until the user exits.
    While 1
        $aMsg = GUIGetMsg(1)
        Switch $aMsg[1]
            Case $hMainForm
                Switch $aMsg[0]
                    Case $GUI_EVENT_CLOSE
                        ExitLoop
                    Case $idNewEntry
                        MsgBox($MB_SYSTEMMODAL, "listview item", GUICtrlRead(GUICtrlRead($idListview)), 2)
                        _NewFormCreate()
                        GUISetState(@SW_DISABLE,$hMainForm)
                    Case $idListview
                        MsgBox($MB_SYSTEMMODAL, "listview", "clicked=" & GUICtrlGetState($idListview), 2)
                EndSwitch
            Case $hNewEntry
                Switch $aMsg[0]
                    Case $GUI_EVENT_CLOSE
                        GUIDelete($hNewEntry)
                        GUISetState(@SW_ENABLE, $hMainForm)
                EndSwitch
        EndSwitch
    WEnd
    GUIDelete()
EndFunc

 

[kurtykurtyboy]

The issue seems to be the use of _GUICtrlListView_AddArray.
Using GUICtrlCreateListViewItem for each item, I have no problem reading the selected text.

One way to get the text while using  _AddArray is to use the UDF functions:

MsgBox($MB_SYSTEMMODAL, "listview item", _GUICtrlListView_GetItemText($idListview, int(_GUICtrlListView_GetSelectedIndices($idListview))), 2)

 

[BrewManNH]

If you use the UDF functions on listviews, then you need to use the listview UDF to work with the listview. You should probably be using _GUICtrlListView_GetItemText.

[Valnurat]

15 hours ago, kurtykurtyboy said:

The issue seems to be the use of _GUICtrlListView_AddArray.
Using GUICtrlCreateListViewItem for each item, I have no problem reading the selected text.

One way to get the text while using  _AddArray is to use the UDF functions:

MsgBox($MB_SYSTEMMODAL, "listview item", _GUICtrlListView_GetItemText($idListview, int(_GUICtrlListView_GetSelectedIndices($idListview))), 2)

 

Thank you, but why do I only retrieve the 1st column?

I need to get all columns in the listview.

[Valnurat]

If I do this:

Local $iIndex = _GUICtrlListView_GetSelectedIndices($idListview)
MsgBox($MB_SYSTEMMODAL, "listview item", $iIndex, 2)

I can clearly see the index I selected. So  _GUICtrlListView_GetSelectedIndices($idListview), gives me the index of the selected.

but if I do this, it does not work:

_GUICtrlListView_GetItemTextArray($idListview, _GUICtrlListView_GetSelectedIndices($idListview))

But this does:

_GUICtrlListView_GetItemTextArray($idListview, int(_GUICtrlListView_GetSelectedIndices($idListview)))

Why do I need to use the INT?

[benners]

_GuiCtrlListView_GetSelectedIndices returns a string  or an array, depending on the second parameter. _GUICtrlListView_GetItemTextArray requires a number for the index, using int converts the returned string to a number.

[Valnurat]

Ahhh, yes. Thank you.