sort array 1D by value

[nhockm4v]

hi all

i have a array:

local $array = ['10c','6b','6c','6d','10b','7b','8a','9d','2c','5a','ab','bb']

i want sort this array like 

local $array = ['2c','5a','6b','6c','6d','7b','8a','9d','10b','10c','ab','bb']

i tried _arraysort() it not working

sorry my English not good, thanks

[nhockm4v]

If I press Col 0 when _arraydisplay () runs then it works, but I do not know how to do it with code.

illustration: 

[Melba23]

nhockm4v,

_ArraySort and the internal ListView sort algorithms are not the same, which is why you get different results. I suggest using leading zeroes like this:

#include <Array.au3>

local $array = ['10c','6b','6c','6d','10b','7b','8a','9d','2c','5a','ab','bb']

; Add leading zero to all elements that start with a digit
For $i = 0 To UBound($array) - 1
    If Number($array[$i]) Then
        $array[$i] = StringFormat("%03s", $array[$i])
    EndIf
Next
; And here they are
_ArrayDisplay($array)

; Now sort the array
_ArraySort($array)

; And then remove any leading zeros
For $i = 0 To UBound($array) - 1
    If StringLeft($array[$i], 1) = "0" Then
        $array[$i] = StringtrimLeft($array[$i], 1)
    EndIf
Next

; Et voila!
_ArrayDisplay($array)

M23

Edit: Search the forum for "natural sort" and you will find quite a few implementations which will sort as you require.

Edited April 9, 2018 by Melba23

[nhockm4v]

3 minutes ago, Melba23 said:

nhockm4v,

_ArraySort and the internal ListView sort algorithms are not the same, which is why you get different results. I suggest using leading zeroes like this:

#include <Array.au3>

local $array = ['10c','6b','6c','6d','10b','7b','8a','9d','2c','5a','ab','bb']

; Add leading zero to all elements that start with a digit
For $i = 0 To UBound($array) - 1
    If Number($array[$i]) Then
        $array[$i] = StringFormat("%03s", $array[$i])
    EndIf
Next
; And here they are
_ArrayDisplay($array)

; Now sort the array
_ArraySort($array)

; And then remove any leading zeros
For $i = 0 To UBound($array) - 1
    If StringLeft($array[$i], 1) = "0" Then
        $array[$i] = StringtrimLeft($array[$i], 1)
    EndIf
Next

; Et voila!
_ArrayDisplay($array)

M23

Edit: Search the forum for "natural sort" and you will find quite a few implementations which will sort as you require.

i no have a keywork, thanks you legend, It helped me a lot,  thanks again