Verifying Ini File Format?

[VollachR]

Hi,

I've written a specialty INI file editor for a specific set of INI files related to a bigger script I'm working on.

I'm trying to create a verification script that checks the ini files structure and format and gives an error if they are not in expected format.

What I did so far is create a couple of custom arrays, each with the list of Sections expected in the files and I use IniReadSectionNames in order to read the sections from the selected INI file and compare it to the array.

It works fine, excepts it only gives an error if one or more of the sections in the custom array is missing, if they all exist but there are other additional sections that shouldn't be there it doesn't give an error and continue to open the editor screen.

Here are the relevant part of my script:

The Custom Verification Arrays:

;Creating Arrays for INI Verification
Global $aSettingsVerify[7]
$aSettingsVerify[1] = "Conversion"
$aSettingsVerify[2] = "AIO"
$aSettingsVerify[3] = "Data"
$aSettingsVerify[4] = "Redist"
$aSettingsVerify[5] = "Split"
$aSettingsVerify[6] = "Autorun"
Global $aDataVerify[6]
$aDataVerify[1] = "Compression"
$aDataVerify[2] = "Exclude"
$aDataVerify[3] = "LangExclude"
$aDataVerify[4] = "PreCommands"
$aDataVerify[5] = "PostCommands"

The IniReadSectionNames verification part:

Case $OK
                If StringInStr($ActiveConfig, "Settings.ini") Then
                    $CheckArray1 = IniReadSectionNames($ActiveConfig)
                    $CheckArray2 = _ArrayCompare($aSettingsVerify, $CheckArray1)
                    $CheckArray3 = UBound($CheckArray2, 1)
                    If $CheckArray3 = 1 Then
                        GUIDelete($ConfigStart)
                        SettingsGUI()
                    EndIf
                    If $CheckArray3 > 1 Then
                        WrongIni()
                    EndIf
                EndIf
                If StringInStr($ActiveConfig, "Data") Then
                    $CheckArray1 = IniReadSectionNames($ActiveConfig)
                    $CheckArray2 = _ArrayCompare($aDataVerify, $CheckArray1)
                    $CheckArray3 = UBound($CheckArray2, 1)
                    If $CheckArray3 = 1 Then
                        GUIDelete($ConfigStart)
                        DataGUI()
                    EndIf
                    If $CheckArray3 > 1 Then
                        WrongIni()
                    EndIf
                EndIf

The Function that performs the compare: (Found it in another thread on this forums somewhere by using Google Search)

;Compares Imported INI file with the Verification array
Func _ArrayCompare(ByRef $a1, ByRef $a2)
    Local $nOldSize = UBound($a2)
    Local $a3[$nOldSize], $nNewSize = $nOldSize

    For $i = 0 To UBound($a1) - 1
        For $j = 0 To $nOldSize - 1
            If Not $a3[$j] And ($a1[$i] = $a2[$j]) Then
                $a3[$j] = 1
                $nNewSize -= 1
            EndIf
        Next
    Next

    Local $a4[$nNewSize], $j = 0
    For $i = 0 To $nOldSize - 1
        If Not $a3[$i] Then
            $a4[$j] = $a2[$i]
            $j += 1
        EndIf
    Next

    Return $a4
EndFunc   ;==>_ArrayCompare

 

Any way to make a check if there are sections other than the ones in the Verification Array and produce an error?

Thanks

[Melba23]

VollachR,

Run a check of the size of the array returned by IniReadSectionNames - if it is larger than the checking array there are too many entries.

M23

[Subz]

As Melba23 pointed out you can compare section name count for example:

If UBound($CheckArray1) - 1 <> UBound($aSettingsVerify) - 1 Then ... ;~ Action here

Alternatively you can get an array of incorrect names and also compare the sizes for example:

expandcollapse popup

#include <Array.au3>
Global $aVerify[7]
$aVerify[1] = "Conversion"
$aVerify[2] = "AIO"
$aVerify[3] = "Data"
$aVerify[4] = "Redist"
$aVerify[5] = "Split"
$aVerify[6] = "Autorun"

;~ IniReadSection
Global $aSection[9]
$aSection[1] = "Conversion"
$aSection[2] = "AIO"
$aSection[3] = "Data"
$aSection[4] = "Redist"
$aSection[5] = "Split"
$aSection[6] = "Autorun"
$aSection[7] = "AutoRunning"
$aSection[8] = "Confersion"

Global $aCompare = _SectionCompare($aSection, $aVerify)
_ArrayDisplay($aCompare, "Error Return = " & @error)

Func _SectionCompare($_aSections, $_aVerification)
    Local $_iError, $_iSearch
    If (UBound($_aSections) -1) < (UBound($_aVerification) - 1) Then $_iError = -1 ;~ $_aSections Array Count less than $_aVerification Array Count
    If (UBound($_aSections) -1) = (UBound($_aVerification) - 1) Then $_iError = 0 ;~ $_aSections Array Count equal to $_aVerification Aay Count
    If (UBound($_aSections) -1) > (UBound($_aVerification) - 1) Then $_iError = 1 ;~ $_aSections Array Count greater than $_aVerification Array Count
    ;~ Check items in $_aSections that match an item in $_aVerification
    For $i = UBound($_aVerification) - 1 To 0 Step - 1
        ConsoleWrite($_aVerification[$i] & @CRLF)
        $_iSearch = _ArraySearch($_aSections, $_aVerification[$i])
        If $_iSearch = -1 Then ContinueLoop
        _ArrayDelete($_aSections, $_iSearch)
    Next
    Return SetError($_iError, 0, $_aSections)
EndFunc

 

[VollachR]

21 minutes ago, Melba23 said:

VollachR,

Run a check of the size of the array returned by IniReadSectionNames - if it is larger than the checking array there are too many entries.

M23

I thought about that but I'm not sure how to modify the existing function to include that check, as I said, I found that function online, don't remember where or who wrote it but I didn't do it myself, all I did was remove the _ArrayDisplay that was near the end of the function.

 

5 minutes ago, Subz said:

As Melba23 pointed out you can compare section name count for example:

If UBound($CheckArray1) - 1 <> UBound($aSettingsVerify) - 1 Then ... ;~ Action here

Alternatively you can get an array of incorrect names and also compare the sizes for example:

expandcollapse popup

#include <Array.au3>
Global $aVerify[7]
$aVerify[1] = "Conversion"
$aVerify[2] = "AIO"
$aVerify[3] = "Data"
$aVerify[4] = "Redist"
$aVerify[5] = "Split"
$aVerify[6] = "Autorun"

;~ IniReadSection
Global $aSection[9]
$aSection[1] = "Conversion"
$aSection[2] = "AIO"
$aSection[3] = "Data"
$aSection[4] = "Redist"
$aSection[5] = "Split"
$aSection[6] = "Autorun"
$aSection[7] = "AutoRunning"
$aSection[8] = "Confersion"

Global $aCompare = _SectionCompare($aSection, $aVerify)
_ArrayDisplay($aCompare, "Error Return = " & @error)

Func _SectionCompare($_aSections, $_aVerification)
    Local $_iError, $_iSearch
    If (UBound($_aSections) -1) < (UBound($_aVerification) - 1) Then $_iError = -1 ;~ $_aSections Array Count less than $_aVerification Array Count
    If (UBound($_aSections) -1) = (UBound($_aVerification) - 1) Then $_iError = 0 ;~ $_aSections Array Count equal to $_aVerification Aay Count
    If (UBound($_aSections) -1) > (UBound($_aVerification) - 1) Then $_iError = 1 ;~ $_aSections Array Count greater than $_aVerification Array Count
    ;~ Check items in $_aSections that match an item in $_aVerification
    For $i = UBound($_aVerification) - 1 To 0 Step - 1
        ConsoleWrite($_aVerification[$i] & @CRLF)
        $_iSearch = _ArraySearch($_aSections, $_aVerification[$i])
        If $_iSearch = -1 Then ContinueLoop
        _ArrayDelete($_aSections, $_iSearch)
    Next
    Return SetError($_iError, 0, $_aSections)
EndFunc

 

I don't see how the 2nd example will work, if somebody modifies the ini file and add a section that shouldn't be there I have no way to guess what section name that person added, so I can't really create an array with incorrect names as that can be anything that isn't in the verification array.

As for the first suggestion, as I said above for Melba23's answer, I'm not sure where or how to add that into the existing _ArrayCompare function, or is there away to add it in the part of the script that calls the function without messing things up?

[Subz]

The $aSection above was an example of an IniReadSection, it should return the differences, here is another example since I didn't  make the first a 2D Array and forgot about comparing the results after the loop.  As I only have partial piece of your script I can't test so will leave it with you.

expandcollapse popup

#include <Array.au3>

Global $aSettingsVerify[7]
    $aSettingsVerify[1] = "Conversion"
    $aSettingsVerify[2] = "AIO"
    $aSettingsVerify[3] = "Data"
    $aSettingsVerify[4] = "Redist"
    $aSettingsVerify[5] = "Split"
    $aSettingsVerify[6] = "Autorun"

Global $aDataVerify[6]
    $aDataVerify[1] = "Compression"
    $aDataVerify[2] = "Exclude"
    $aDataVerify[3] = "LangExclude"
    $aDataVerify[4] = "PreCommands"
    $aDataVerify[5] = "PostCommands"

If StringInStr($ActiveConfig, "Settings.ini") Then
    $CheckArray1 = IniReadSectionNames($ActiveConfig)
    $CheckArray2 = _SectionCompare($CheckArray1, $aSettingsVerify)
    Switch @error
        Case -2, -1, 1
            GUIDelete($ConfigStart)
            SettingsGUI()
    EndSwitch
    _ArrayDisplay($CheckArray2, "Error Return = " & @error)
EndIf
If StringInStr($ActiveConfig, "Data") Then
    $CheckArray1 = IniReadSectionNames($ActiveConfig)
    $CheckArray2 = _SectionCompare($CheckArray1, $aDataVerify)
    Switch @error
        Case -2, -1, 1
            GUIDelete($ConfigStart)
            SettingsGUI()
    EndSwitch
    _ArrayDisplay($CheckArray2, "Error Return = " & @error)
EndIf

; ==================================================================================================
; Func _SectionCompare($_aSections, $_aVerification)
;
; $_aSections       := Section Names Array
; $_aVerifcation    := Verification Array
;
; Returns:
;   Success: "" with @error set to 0
;   Failure: "" if $_aSections is empty or $_vResult Array with differnces, with @error set
;       @error = -2 = $_aSections Array contains incorrect data
;       @error = -1 $_aSections Array Count less than $_aVerification Array Count
;       @error = 1 $_aSections Array Count greater than $_aVerification Array Count
;
; Author: Subz
; ==================================================================================================

Func _SectionCompare($_aSections, $_aVerification)
    Local $_iError, $_iSearch
    If (UBound($_aSections) -1) < (UBound($_aVerification) - 1) Then $_iError = -1 ;~ $_aSections Array Count less than $_aVerification Array Count
    If (UBound($_aSections) -1) = (UBound($_aVerification) - 1) Then $_iError = 0 ;~ $_aSections Array Count equal to $_aVerification Aay Count
    If (UBound($_aSections) -1) > (UBound($_aVerification) - 1) Then $_iError = 1 ;~ $_aSections Array Count greater than $_aVerification Array Count
    ;~ Check items in $_aSections that match an item in $_aVerification
    For $i = UBound($_aVerification) - 1 To 0 Step - 1
        $_iSearch = _ArraySearch($_aSections, $_aVerification[$i], 0, 0, 0, 0, 1, 0)
        If $_iSearch = -1 Then ContinueLoop
        _ArrayDelete($_aSections, $_iSearch)
    Next
    $_iError = UBound($_aSections) -1 = 0 ? 0 : -2
    $_vReturn = UBound($_aSections) = 0 ? "" : $_aSections
    Return SetError($_iError, 0, $_vReturn)
EndFunc

 

[VollachR]

OK, turned out I didn't need that additional check after all, my existing check was enough once I moved another part of the script from another "Case" into the "Case $OK" portion, it was probably a logic issue.

I accidentally made the script import the in sections (with IniReadSection) to Arrays before performing the check instead of after, which caused my problem, now that I moved it to be done after the check is performed I get the error message at every situation it needs to be without any additional checks.

That's the change I made:

Case $OK
                If StringInStr($ActiveConfig, "Settings.ini") Then
                    $CheckArray1 = IniReadSectionNames($ActiveConfig)
                    $CheckArray2 = _ArrayCompare($aSettingsVerify, $CheckArray1)
                    $CheckArray3 = UBound($CheckArray2, 1)
                    If $CheckArray3 = 1 Then
                        Global $aConversion = IniReadSection($ActiveConfig, "Conversion")
                        Global $aAIO = IniReadSection($ActiveConfig, "AIO")
                        Global $aData = IniReadSection($ActiveConfig, "Data")
                        Global $aRedist = IniReadSection($ActiveConfig, "Redist")
                        Global $aSplit = IniReadSection($ActiveConfig, "Split")
                        Global $aAutorun = IniReadSection($ActiveConfig, "Autorun")
                        GUIDelete($ConfigStart)
                        SettingsGUI()
                    EndIf
                    If $CheckArray3 > 1 Then
                        WrongIni()
                    EndIf
                EndIf
                If StringInStr($ActiveConfig, "Data") Then
                    $CheckArray1 = IniReadSectionNames($ActiveConfig)
                    $CheckArray2 = _ArrayCompare($aDataVerify, $CheckArray1)
                    $CheckArray3 = UBound($CheckArray2, 1)
                    If $CheckArray3 = 1 Then
                        Global $aCompression = IniReadSection($ActiveConfig, "Compression")
                        Global $aExclude = IniReadSection($ActiveConfig, "Exclude")
                        Global $aLangExclude = IniReadSection($ActiveConfig, "LangExclude")
                        Global $aPreCommands = IniReadSection($ActiveConfig, "PreCommands")
                        Global $aPostCommands = IniReadSection($ActiveConfig, "PostCommands")
                        GUIDelete($ConfigStart)
                        DataGUI()
                    EndIf
                    If $CheckArray3 > 1 Then
                        WrongIni()
                    EndIf
                EndIf

Before I had these IniReadSection lines in a previous Case for a ComboBox that let the user select the Ini file to edit before enabling the OK button, now it's in the OK button case after the check if it's correct.

These IniReadSection arrays are used to later fill the edit fields in the GUI, don't know why creating them earlier caused a problem but it works now.