Why can't I compare a variable less than 100 with another variable bigger 100?

[ThePoro]

I have this code 

It gets variable input from GUI to run a loop and write to a text file then copy it to the clipboard

But the thing is code runs normally with $px and $py <100 or both > 100 or with $px <10 and $py>100 but It's wrong with 10<$px <100 and $py >100

Can anyone tell me why?

Func clone()

Local $px = GUICtrlRead($input1)
Local $py = GUICtrlRead($input2)
Local $temp = "C:\temp.csv"
FileDelete($temp)
    While $px <= $py
        Local $name = "P"&$px
        FileWrite($temp, " & $name & ""& @CRLF)
        $px+= 1
    WEnd
$a=FileRead($temp)
ClipPut($a)
MsgBox($MB_ICONINFORMATION,"","Copied to Clipboard")

EndFunc

 

Edited March 6, 2019 by ThePoro

[BrewManNH]

4 minutes ago, ThePoro said:

It's wrong with$ px <100 and $py >100

Explain what you mean by it's wrong, what's wrong? What are you expecting to happen if the variables are those values, and what you're seeing happen?

[jchd]

Values read from a control are strings. Convert to numbers using Int() or Number() to compare to numeric values.

[Dionysis]

Is it fixed if you add the missing double quote-mark?

FileWrite($temp, "" & $name & ""& @CRLF)

 

Edited March 6, 2019 by Dionysis

[Loken]

Hello ThePoro, wellcome to AutoIt Forum.

Your problem is about comparing wrong data types. GUICtrlCreateInput elements may includes characters, numbers etc. So "GUICtrlRead" function returns you result as a string even if you put just numbers into it. You have to convert result of "GUICtrlRead" function to integer if you expect compare it as integer. Otherwise if you check "50" is less than "100" you get false as result. Because that means compare 50 and 100 as string and OS handle these strings by their characters. According to ASCII List "50" is bigger than "100";

Converting string to integer;

Local $px = Int(GUICtrlRead($input1))
Local $py = Int(GUICtrlRead($input2))

Here is a full example;

#include <MsgBoxConstants.au3>
#include <GUIConstantsEx.au3>

$gui = GUICreate("gui for testing", 300, 90, -1, -1)
$input1 = GUICtrlCreateInput("50", 0, 0, 300, 30)
$input2 = GUICtrlCreateInput("150", 0, 30, 300, 30)
$button1 = GUICtrlCreateButton("clone", 0, 60, 300, 30)
GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $button1
            clone()
    EndSwitch
WEnd

Func clone()
Local $px = Int(GUICtrlRead($input1))
Local $py = Int(GUICtrlRead($input2))
Local $temp = @DesktopDir & "\temp.csv"
FileDelete($temp)
    While $px <= $py
        Local $name = "P"&$px
        FileWrite($temp, "" & $name & ""& @CRLF)
        $px+= 1
    WEnd
$a=FileRead($temp)
ClipPut($a)
MsgBox($MB_ICONINFORMATION,"","Copied to Clipboard")
EndFunc

 

[ThePoro]

Ahhh, I understand now, thank everyone