How to read unicode utf8 string from sub process (Run) with StdoutRead()?

[GillesMaisonneuve]

Good morning,

 

I am trying to read a Unicode utf8 string from a perl subprocess via StdoutRead.

I use an AUtoIt GUI and display result in an 'Edit' control (see my code below) using 'Courier New', a font that can handle Unicode characters.

I was expecting a result looking like (CMD console):

++$ chcp 65001>NUL: & perl -Mutf8 -CS -e "use 5.018; binmode STDOUT,q(:utf8); say qq(\x{03A9})" & chcp 850>NUL:
Ω

Instead I get someting like this (see downward the screen copy):

++$ chcp 1250>NUL: & perl -Mutf8 -CS -e "use 5.018; binmode STDOUT,q(:utf8); say qq(\x{03A9})" & chcp 850>NUL:
Ω

Obviously while I was expecting to receive an utf8 char, it seems to have been converted to Windows ANSI codepage 1250 (Windows default for Western/Central Europe, right ?)

What am I doing wrong? Is there someone who could guide me?

 

Here is my code and my output in the GUI.

Creating and configuring the Edit control:

Local $Edit1 = GUICtrlCreateEdit( "", 20, 110, 780, 500, BitOr($GUI_SS_DEFAULT_EDIT,$ES_MULTILINE,$ES_READONLY) )
GUICtrlSetData($Edit1, "This field will contain text result from external Perl command")
GUICtrlSetFont($Edit1, 10, $FW_THIN, $GUI_FONTNORMAL, "Courier New")

 

Executing Perl command (note: `-Mutf8` and `-CS` garantees that I work in utf8 and STDOUT accepts wide-characters):

local $ExePath = 'perl.exe -Mutf8 -CS '     ;~ if perl in PATH, no need for full path C:\Perl\bin\perl.exe
local $Params = '-e "use 5.018; use utf8; use charnames q(:full);  binmode STDOUT,q(:utf8);' & _
                'say scalar localtime; say qq(\N{GREEK CAPITAL LETTER OMEGA})"'
local $Cmd = $ExePath & ' ' & $Params
Local $iPID = Run($Cmd, "", @SW_HIDE, BitOR($STDERR_CHILD, $STDOUT_CHILD))

 

Reading STDOUT and displaying it into the Edit control:

While 1
    $sOutput &= StdoutRead($iPID)
    If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
        ExitLoop
    EndIf
WEnd
If $sOutput <> '' Then
    GUICtrlSetData($Edit1, $sOutput)
EndIf

 

And now, what I get on my GUI:

 

[FrancescoDiMuro]

@GillesMaisonneuve

Edited March 30, 2019 by FrancescoDiMuro
Snip.

[jchd]

"Courier New" definitely handles unicode characters.

Ω is 0xCE 0xA9 = 0x03A9 = 'Ω' encoded in UTF8. You need to convert the UTF8 string to the native encoding used by AutoIt (a subset of UTF16-LE named UCS2).

#include <StringConstants.au3>

Local $sOutput = Chr(0xCE) & Chr(0xA9)

If $sOutput <> '' Then
    $sOutput = BinaryToString($sOutput, $SB_UTF8)
;~     GUICtrlSetData($Edit1, $sOutput)
    MsgBox(0, "", $sOutput)
EndIf

 

[GillesMaisonneuve]

Worked like a charm, thank you very much.