RegExp - Remove white spaces before and after coma

[RAMzor]

Hi guys I need your help.

I have string like this : "TDM111A5,      RCT222Y5/ 7  ; FDT444E4 /8 , ABC222R5"

I need find a coma or semicolon and delete white spaces before and after them

The output should be a string and/or array 

String : "TDM111A5,RCT222Y5/ 7;FDT444E4 /8,ABC222R5"
Array:
TDM111A5
RCT222Y5/ 7
FDT444E4 /8
ABC222R5

Edited October 16, 2019 by RAMzor

[InnI]

$s = "TDM111A5,      RCT222Y5/ 7  ; FDT444E4 /8 , ABC222R5"

$s = StringRegExpReplace($s, "\h*([,;])\h*", "\1") ; string
ConsoleWrite($s & @CRLF)

$a = StringSplit($s, ",;") ; array

#include <Array.au3>
_ArrayDisplay($a)

 

[Jos]

Something like this?

$In = "TDM111A5,      RCT222Y5/ 7  ; FDT444E4 /8 , ABC222R5"
$Out = StringRegExpReplace($In,"\s*([,;])\s*","$1")
ConsoleWrite($out &@CRLF)

Jos

[RAMzor]

Thanks 🤝

[mikell]

Straight-to-array version 

#include <Array.au3>

$s = "TDM111A5,      RCT222Y5/ 7  ; FDT444E4 /8 , ABC222R5"

$a = StringRegExp($s, "\h*([^,;]+)\h*", 3) 
_ArrayDisplay($a)

 

[iamtheky]

an irregular straight to array version

#include <Array.au3>

local $a[0] , $s = "TDM111A5,      RCT222Y5/ 7  ; FDT444E4 /8 , ABC222R5"

_ArrayAdd($a , StringReplace(StringStripWS($s , 4) , "," , ";") , "" , ";")

_ArrayDisplay($a)

 

[iamtheky]

awww 💩

#include <Array.au3>

local $a[0] , $s = "TDM111A5,      RCT222Y5/ 7  ; FDT444E4 /8 , ABC222R5"

_ArrayDisplay(StringSplit(StringStripWS($s , 4) , ",;" , 2))

 

[mikell]

7 hours ago, iamtheky said:

awww 💩

In both cases, what about the persistent white space just before the 2nd, 3rd and 4th items ? 

[iamtheky]

suppose I'd continue to ignore them like i did last night 😕

[Malkey]

On 10/17/2019 at 3:48 AM, mikell said:

Straight-to-array version 

#include <Array.au3>

$s = "TDM111A5,      RCT222Y5/ 7  ; FDT444E4 /8 , ABC222R5"

$a = StringRegExp($s, "\h*([^,;]+)\h*", 3) 
_ArrayDisplay($a)

 

Note the trailing "\h*" in mikell's RE pattern does not match any spaces, because all trailing spaces are already captured by previous "([^,;]+)" capture group.  This means the 2nd and 3rd items have trailing spaces.

 

Here is another straight-to-array example.

#include <Debug.au3>

$s = "  TDM111A4  ,      RCT222Y5/ 7     ; FDT444E4 /8 ,   ABC222R56   "

; $a = StringRegExp($s, "\h*[;,]?(\w+\h*/?\h*\d*)\h*", 3) ; When "/?\h*\d*" does not match in the test string,
;                                                          "(\w+\h*" captures trailing spaces in 1st and 4th items.

$a = StringRegExp($s, "\h*[;,]?(\w+(?:\h*/\h*\d*)?)\h*", 3)

_DebugArrayDisplay($a)

 

Edited October 20, 2019 by Malkey
See comments in my example.

[RAMzor]

Thanks guys for examples 👌