_GUICtrlListBox_GetCaretIndex() returning an unexpected value

[EmilyLove]

So I have an issue where _GUICtrlListBox_GetCaretIndex, which returns a zero-based index, is returning an unexpected value. When expecting a value of anything greater than 0, it actually returns -1 the expected value. So if I selected index 3, it would report index 2 being deleted. Strangely enough, the GUI end still works correctly. For your convenience, I have included some code to serve as a visual aid.

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$hGUI = GUICreate("Test", 172, 292, 192, 125)
$list_data_sample = GUICtrlCreateList("", 0, 0, 170, 253,0)
GUICtrlSetData(-1, "Sample|Data|Is|Awesome")
$button_Remove = GUICtrlCreateButton("Remove", 0, 253, 170, 20)
$results = GUICtrlCreateLabel("Select from list, then click remove", 0, 272, 170, 17, $SS_CENTER)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button_Remove
            _GUICtrlListBox_DeleteString($list_data_sample, _GUICtrlListBox_GetCaretIndex($list_data_sample))
            GUICtrlSetData($results,"zero-based index "&_GUICtrlListBox_GetCaretIndex($list_data_sample) & " deleted!")
    EndSwitch
WEnd

 

Edited April 20, 2020 by BetaLeaf

[MrCreatoR]

Once the item deleted, the selection is lost (rectangle set to previous item, well actually to current one, that take the place of the deleted one), take the value before deletion, and i think better to use _GUICtrlListBox_GetCurSel.

Case $button_Remove
            $iSel = _GUICtrlListBox_GetCurSel($list_data_sample)
            _GUICtrlListBox_DeleteString($list_data_sample, $iSel)
            GUICtrlSetData($results,"zero-based index " & $iSel & " deleted!")

 

Edited April 20, 2020 by MrCreatoR

[EmilyLove]

Wow, I totally spaced that. Why didn't I think about the order earlier? Thank you!!