Singleton using Atom / Semaphore

[UEZ]

Here another approach to check if a script was already started using atoms and semaphores.

 

Atom:

expandcollapse popup

#include <MsgBoxConstants.au3>

Global $iSingleton = Singleton()
If Not $iSingleton Then
    Exit MsgBox($MB_TOPMOST, "Singleton Test", "Process is already running!")
EndIf
MsgBox($MB_TOPMOST, "Singleton Test", "Singleton atom initialized: " & $iSingleton)
Singleton_Delete($iSingleton)


; #FUNCTION# ====================================================================================================================
; Name ..........: Singleton
; Description ...: Checks if the script has been started already.
; Syntax ........: Singleton([$sOccurrenceName = @ScriptFullPath])
; Parameters ....: $sOccurrenceName     - [optional] a string value. Default is @ScriptFullPath.
; Return values .: If the function succeeds, the return value is the newly created atom or 0 else error is set and false is returned.
; Author ........:  UEZ
; Modified ......:
; Remarks .......: If Singleton finds the atom it will return 0 and the atom token will be set to extended macro. It can be used to get the atom string using _WinAPI_AtomGlobalGetName.
; Related .......:
; Link ..........: https://docs.microsoft.com/en-us/windows/win32/api/winbase/nf-winbase-globalfindatomw
;                     https://docs.microsoft.com/en-us/windows/win32/api/winbase/nf-winbase-globaladdatomw
; Example .......: No
; ===============================================================================================================================
Func Singleton($sOccurrenceName = @ScriptFullPath)
    Local $iFind = _WinAPI_AtomGlobalFind($sOccurrenceName)
    If @error Then Return SetError(1, 0, False)
    If $iFind Then Return SetExtended($iFind, 0)
    Local $iAtom = _WinAPI_AtomGlobalAdd($sOccurrenceName)
    If @error Then Return SetError(2, 0, False)
    Return $iAtom
EndFunc   ;==>Singleton

; #FUNCTION# ====================================================================================================================
; Name ..........: Singleton_Delete
; Description ...: Deletes the atom generated by the first started script.
; Syntax ........: Singleton_Delete($iAtom)
; Parameters ....: $iAtom               - an integer value which was generated by Singleton
; Return values .: True if successful else false.
; Author ........: UEZ
; Modified ......:
; Remarks .......: Don't forget to call Singleton_Delete before first started script ends.
; Related .......:
; Link ..........: https://docs.microsoft.com/en-us/windows/win32/api/winbase/nf-winbase-globaldeleteatom
; Example .......: No
; ===============================================================================================================================
Func Singleton_Delete($iAtom)
    _WinAPI_AtomGlobalDelete($iAtom)
    If @error Then Return SetError(1, 0, False)
    Return True
EndFunc   ;==>Singleton_Delete

;internal functions
Func _WinAPI_AtomGlobalFind($sAtomString)
    Local $aReturn = DllCall("kernel32.dll", "short", "GlobalFindAtomW", "wstr", $sAtomString)
    If @error Then Return SetError(1, 0, -1)
    Return $aReturn[0]
EndFunc   ;==>_WinAPI_AtomGlobalFind

Func _WinAPI_AtomGlobalAdd($sAtomString)
    Local $aReturn = DllCall("kernel32.dll", "short", "GlobalAddAtomW", "wstr", $sAtomString)
    If @error Then Return SetError(1, 0, -1)
    Return $aReturn[0]
EndFunc   ;==>_WinAPI_AtomGlobalAdd

Func _WinAPI_AtomGlobalDelete($nAtom)
    Local $aReturn = DllCall("kernel32.dll", "short", "GlobalDeleteAtom", "short", $nAtom)
    If @error Then Return SetError(1, 0, -1)
    Return $aReturn[0] = 0
EndFunc   ;==>_WinAPI_AtomGlobalDelete

Func _WinAPI_AtomGlobalGetName($nAtom, $iBufferSize = 512)
    Local $tBufferAtom = DllStructCreate("wchar name[" & $iBufferSize & "]")
    Local $aReturn = DllCall("kernel32.dll", "uint", "GlobalGetAtomNameW", "short", $nAtom, "struct*", $tBufferAtom, "int", $iBufferSize)
    If @error Or Not $aReturn[0] Then Return SetError(1, 0, -1)
    Return $tBufferAtom.name
EndFunc   ;==>_WinAPI_AtomGlobalGetName

 

Semaphore:

#include <MsgBoxConstants.au3>
#include <WinAPIError.au3>

Global $iSingleton = Singleton("&]8h/x87</htFV4-K*&.b.w~")
If Not $iSingleton Then
    Exit MsgBox($MB_TOPMOST, "Singleton Test", "Process is already running!")
EndIf
MsgBox($MB_TOPMOST, "Singleton Test", "Singleton Semaphore initialized: " & $iSingleton)



; #FUNCTION# ====================================================================================================================
; Name ..........: Singleton
; Description ...: Checks if the script has been started already.
; Syntax ........: Singleton($sOccurrenceName)
; Parameters ....: $sOccurrenceName     - a string value which will be used to create the semaphore handle.
; Return values .: True if Singleton started the first time. False if script was already started
; Author ........: UEZ
; Modified ......:
; Remarks .......: The system closes the handle automatically when the process terminates. The semaphore object is destroyed when its last handle has been closed.
; Related .......:
; Link ..........: https://docs.microsoft.com/en-us/windows/win32/api/winbase/nf-winbase-createsemaphorea
; Example .......: No
; ===============================================================================================================================
Func Singleton($sOccurrenceName)
    If StringLen($sOccurrenceName) > 260 Then $sOccurrenceName = StringLeft($sOccurrenceName, 260)
    Local $aReturn = DllCall("kernel32.dll", "handle", "CreateSemaphoreA", "ptr", Null, "long", 0, "long", 1, "str", $sOccurrenceName)
    If @error Or Not $aReturn[0] Then Return SetError(1, 0, -1)
    Return SetExtended($aReturn[0], $aReturn[0] And _WinAPI_GetLastErrorMessage()  = "The operation completed successfully.")
EndFunc   ;==>Singleton

 

Just start the script twice to see if it works.

The disadvantage of using atoms is that atoms have a memory that means when your app is crashing or you forgot to delete the atom then the atom does still have the $sOccurrenceName saved and thus Singleton will not work if you use the same same value for $sOccurrenceName.

With semaphore you don't have this issue.

 

Thanks to jj2007 and SARG.

Edited June 6, 2020 by UEZ
Update

[argumentum]

hmmm, let's say that I did not call the "Singleton_Delete($iSingleton)" and wanted to run the script again, how do I clear a previous $iSingleton ?

[UEZ]

  On 5/30/2020 at 6:21 PM, argumentum said:

hmmm, let's say that I did not call the "Singleton_Delete($iSingleton)" and wanted to run the script again, how do I clear a previous $iSingleton ?

Expand  

You can use 

Global $iSingleton = Singleton()
Singleton_Delete(@extended)

to delete the atom.

But you cannot use this in you main script because how do you know if it was called the 1st time?

[argumentum]

  On 5/30/2020 at 7:14 PM, UEZ said:

how do you know if it was called the 1st time?

Expand  

...say the script crashed, or very unlikely, I messes up... very very unlikely  

[MrCreatoR]

I always use this:

 

Global $sAppName = 'My App'

_RunOnce($sAppName, _OnSecondRun)
MsgBox(64, @ScriptName, 'Run me again')

;Main code...

Func _OnSecondRun()
    MsgBox(48, @ScriptName, 'Second copy detected, exiting...', 3)
    Exit
EndFunc

Func _RunOnce($sAppName = '', $sCallback = '')
    Local $iOld_WTMM = Opt('WinTitleMatchMode', 3)
    Local $sTitle = @ScriptName & '_@#$%^&*_' & $sAppName
    
    If WinExists('[CLASS:AutoIt v3;TITLE:' & $sTitle & ']') Then
        If Not $sCallback Then
            Exit
        EndIf
        
        Call(FuncName($sCallback))
    EndIf
    
    AutoItWinSetTitle($sTitle)
    Opt('WinTitleMatchMode', $iOld_WTMM)
EndFunc

You can use it even as UDF, without do anything...

RunOnce.au3:

#include-once
#OnAutoItStartRegister '__RunOnce'

Func __RunOnce()
    Local $iOld_WTMM = Opt('WinTitleMatchMode', 3)
    Local $sTitle = @ScriptName & '_@#$%^&*_' & @ScriptName
    
    If WinExists('[CLASS:AutoIt v3;TITLE:' & $sTitle & ']') Then
        MsgBox(48, @ScriptName, 'Second copy detected, exiting...', 3)
        Exit
    EndIf
    
    AutoItWinSetTitle($sTitle)
    Opt('WinTitleMatchMode', $iOld_WTMM)
EndFunc

Just add #include <RunOnce.au3> to your script.

[UEZ]

I added another Singleton variant using Semaphore winapi function. Check first post.

@MrCreatoR: thanks for your contribution.

[argumentum]

The semaphore one better fit my coding style**.
A note on the advantages of one over the other at the first post will be welcomed by those that code like me.

**good luck running this unstructured thoughtless rambling called code

[Exit]

If you simultaneously click F5 in the SciTe4Autoit Editor, Scriptname.au3 or Scriptname.exe in the Explorer and want to use the "cancel, wait, test" functionality, you can also use _SingleScript ().