ListView Help

[jezzzzy 0]

The below code updates an input field to show how many listviewitems are selected. The problem is that the $GUI_EVENT_PRIMARYUP doesn't fire when clicking on a listviewitem - only on part of the listview itself (scrollbar, emptyspace, column header, etc). I have searched the forums and there are lots of people who aparently have something similar to this working. Not sure what the problem is.

$listView= GUICtrlCreateListView("Email Lists",120+$halignInput,190+$valignInput,220,115,BitOR($LVS_REPORT, $LVS_SORTASCENDING,$LVS_NOCOLUMNHEADER))

;Then a function that adds listview items based on folder contents
;Other stuff
;Then my msg loop

        Case $msg = $GUI_EVENT_PRIMARYUP
            $pos = GUIGetCursorInfo()
            If ($pos[4] = $listView) Then
                GUICtrlSetData($inputField,_GUICtrlListViewGetSelectedCount($listView))
            EndIf

[jezzzzy 0]

Posted this over the weekend ... so ....

bump

[Gyzmok 0]

Yep, I have the same problem.

Would like to know a solution too.

Anyone ?

[GaryFrost 10]

why not use a click event instead of trying to get primary up?

expandcollapse popup

; Events - ListView
#include <GuiConstants.au3>;Inclusion file for the GUI interface controls
#include <GuiListView.au3>

Global $ListView
Global Const $WM_NOTIFY = 0x004E
Global Const $DebugIt = 0

;ListView Events
Global Const $NM_FIRST = 0
Global Const $NM_CLICK = ($NM_FIRST - 2)
Global Const $NM_DBLCLK = ($NM_FIRST - 3)
#endregion End Global variables

Opt("WinTitleMatchMode", 2)

$main_GUI = GUICreate("GuiRegisterMsg Test", 225, 400, 300, 10, BitOR($WS_THICKFRAME, $WS_SIZEBOX))

$input = GUICtrlCreateInput("",5,10,120,20)

$ListView = GUICtrlCreateListView("Email Lists", 5, 75, 195, 280, BitOR($LVS_SORTASCENDING, $LVS_SINGLESEL))
_GUICtrlListViewSetColumnWidth ($ListView, 0, $LVSCW_AUTOSIZE_USEHEADER)
GUICtrlSendMsg($ListView, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_GRIDLINES, $LVS_EX_GRIDLINES)
GUICtrlSendMsg($ListView, $LVM_SETEXTENDEDLISTVIEWSTYLE, $LVS_EX_FULLROWSELECT, $LVS_EX_FULLROWSELECT)
GUICtrlCreateListViewItem("E-Mail Name 1", $ListView)
GUICtrlCreateListViewItem("E-Mail Name 2", $ListView)
GUISetState()

;Register WM_NOTIFY  events
GUIRegisterMsg($WM_NOTIFY, "WM_Notify_Events")

While 1
   
   $msg = GUIGetMsg()
   
   Switch $msg
      
    ;-----------------------------------------------------------------------------------------
    ;This case statement exits and updates code if needed
      Case $GUI_EVENT_CLOSE
         Exit
         
         
       ;-----------------------------------------------------------------------------------------
       ;put all the misc. stuff here
        Case Else
            ;;;
   EndSwitch
WEnd

Func ListView_Click()
    ;----------------------------------------------------------------------------------------------
    If $DebugIt Then    ConsoleWrite (_DebugHeader ("$NM_CLICK"))
    ;----------------------------------------------------------------------------------------------
    GUICtrlSetData($input,_GUICtrlListViewGetItemText ($ListView))
EndFunc   ;==>ListView_Click

Func ListView_DoubleClick()
    ;----------------------------------------------------------------------------------------------
    If $DebugIt Then    ConsoleWrite (_DebugHeader ("$NM_DBLCLK"))
    ;----------------------------------------------------------------------------------------------
    MsgBox(0,"Double Clicked", _GUICtrlListViewGetItemText ($ListView))
EndFunc   ;==>ListView_DoubleClick

;
; WM_NOTIFY event handler
Func WM_Notify_Events($hWndGUI, $MsgID, $wParam, $lParam)
    #forceref $hWndGUI, $MsgID, $wParam
    Local $tagNMHDR, $event, $hwndFrom, $code
    $tagNMHDR = DllStructCreate("int;int;int", $lParam) ;NMHDR (hwndFrom, idFrom, code)
    If @error Then Return
    $event = DllStructGetData($tagNMHDR, 3)
    Select
    Case $wParam = $ListView
        Select
            Case $event = $NM_CLICK
                ListView_Click ()
            Case $event = $NM_DBLCLK
                ListView_DoubleClick ()
            EndSelect
    EndSelect
    $tagNMHDR = 0
    $event = 0
    $lParam = 0
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_Notify_Events

Func _DebugHeader($s_text)
    Return _
            "!===========================================================" & @LF & _
            "+===========================================================" & @LF & _
            "-->" & $s_text & @LF & _
            "+===========================================================" & @LF
EndFunc   ;==>_DebugHeader

[jezzzzy 0]

Because I'm no gafrost!

Works as described. Thank you.

[GaryFrost 10]

Because I'm no gafrost!

Works as described. Thank you.

y/w