Alphabetical Sort from inifile section names....

[Aceguy]

heres my code, but would like the contents of the combobox to be sorted.......$CBS_SORT doesnt work.

#include <GUIConstants.au3>

$my_gui=GUICreate("my gui")
$My_list=GUICtrlCreateCombo("",10,10,$CBS_SORT)




$var = IniReadSectionNames(@DesktopDir & "\recipes.ini")
If @error Then 
    MsgBox(4096, "", "Error occured, probably no INI file.")
Else
    For $i = 1 To $var[0]
    GUICtrlSetData($my_list,$var[$i])
    Next
EndIf

GUISetState()

While 1
    $msg=GUIGetMsg()
Select
case $msg=-3
    ExitLoop
    EndSelect
WEnd

is it possible,

Many thanks.

Andy

[Valuater]

#include<array.au3>
#include <GUIConstants.au3>

$my_gui=GUICreate("my gui")
$My_list=GUICtrlCreateCombo("",10,10,$CBS_SORT)




$var = IniReadSectionNames(@DesktopDir & "\recipes.ini")
If @error Then
    MsgBox(4096, "", "Error occured, probably no INI file.")
Else
    _ArraySort($var)
    For $i = 1 To $var[0]
    GUICtrlSetData($my_list,$var[$i])
    Next
EndIf

GUISetState()

While 1
    $msg=GUIGetMsg()
Select
case $msg=-3
    ExitLoop
    EndSelect
WEnd

8)

[SmOke_N]

#include <GUIConstants.au3>
#include <Array.au3>

$my_gui=GUICreate("my gui")
$My_list=GUICtrlCreateCombo("",10,10,$CBS_SORT)

$var = IniReadSectionNames(@DesktopDir & "\recipes.ini")
If @error Then
    MsgBox(4096, "", "Error occured, probably no INI file.")
Else
    _ArraySort($var, 0, 1)
    For $i = 1 To $var[0]
        GUICtrlSetData($my_list,$var[$i])
    Next
EndIf

GUISetState()

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = -3
            ExitLoop
    EndSelect
WEnd

Edit:

Oops, Val was a tad faster....

Edit2:

But he forgot to start the sort on 1

Edited June 29, 2006 by SmOke_N

[GaryFrost]

can't believe you both missed this one

$My_list=GUICtrlCreateCombo("",10,10,-1,-1,$CBS_SORT)

No need for the array sort.

Edited June 30, 2006 by gafrost

[SmOke_N]

can't believe you both missed this one

$My_list=GUICtrlCreateCombo("",10,10,-1,-1,$CBS_SORT)

No need for the array sort.

LOL, well I didn't run the combo personally , nice catch.

[Valuater]

can't believe you both missed this one

$My_list=GUICtrlCreateCombo("",10,10,-1,-1,$CBS_SORT)

No need for the array sort.

oooppss

8)

[Aceguy]

Thanks Guys..... But like i said.... $CBS_SORT doesnt work....

Arraysort Works a Treat.

thanks a 1,000,000 tho.

Edited June 30, 2006 by Aceguy

[GaryFrost]

Thanks Guys..... But like i said.... $CBS_SORT doesnt work....

Arraysort Works a Treat.

thanks a 1,000,000 tho.

If you create the combo correctly it should.

$My_list=GUICtrlCreateCombo("",10,10,-1,-1,$CBS_SORT)

[Aceguy]

Yep Tried that, it sorted the list ok, but the Down Arrow button dissapeared and the list was permanently displayed. ?????? ODD.

[GaryFrost]

not odd, changed the style, need to bitor the default styles back in

#include <GUIConstants.au3>

$my_gui=GUICreate("my gui")
$My_list=GUICtrlCreateCombo("",10,10,200,120,BitOR($CBS_SORT,$CBS_DROPDOWN, $CBS_AUTOHSCROLL, $WS_VSCROLL))




$var = IniReadSectionNames(@DesktopDir & "\recipes.ini")
If @error Then 
    MsgBox(4096, "", "Error occured, probably no INI file.")
Else
    For $i = 1 To $var[0]
    GUICtrlSetData($my_list,$var[$i])
    Next
EndIf

GUISetState()

While 1
    $msg=GUIGetMsg()
Select
case $msg=-3
    ExitLoop
    EndSelect
WEnd

[Aceguy]

have not tried it, but you know your onions from your cabbages....

Thanks gafrost.......