Sign in to follow this  
Followers 0
Paradox

Issues grabbing input from GUI

12 posts in this topic

#1 ·  Posted (edited)

Short and simple.

I need input for 3 variables from an AutoIT GUI. The combo box, as you can see, is pulling information from a seperate file that is proprietary to my company's software.

What I ultimately need to be able to do is grab a Username, Password, and selection from the dropdown combo box and pass those variables onto a seperate application to streamline user input.

#include <file.au3>
#include <guiconstants.au3>

$extract=@scriptdir & "\transparent logo.gif"
fileinstall("e:\Projects\DBSync\transparent logo.gif", $extract, 1)

;###############################################
;#
;# declaration of variables
;#
;###############################################

    global $dbuser, $dbpass, $baseid, $list

    $dbstart="net start ""docubase service"""
    $dbstop="net stop ""docubase service"""
    $dbbase=@scriptdir & "\dbsrvrun.bas"

;###############################################
;#
;# Create GUI and get info
;#
;###############################################

$basename=inireadsection($dbbase, "BASE")

for $x=1 to $basename[0][0]
    $list=$list & $basename[$x][0] & "|"
next

$list = stringtrimright($list, 1)

guicreate("Base Selection",400,250,-1,-1,-1,$WS_EX_TOPMOST)
guisetbkcolor(0xffffff)
Guisetfont(10, 400,0 ,"Courier")
guictrlcreatelabel("Administrative User Name:", 10, 10)
    $dbuser=stringupper(guictrlcreateinput("", 250, 8, 120))
guictrlcreatelabel("Password:", 10, 35)
    $dbpass=guictrlcreateinput("", 250, 33, 120)
guictrlcreatelabel("Base to ReIndex:", 10, 60)
    guictrlcreatecombo("", 250, 58, 120)
    $baseid=guictrlsetdata(-1, $list, $basename[1][0])

    $button_1 = guictrlcreatebutton("OK", 125, 150, 75)
    $button_2 = guictrlcreatebutton("Cancel", 205, 150, 75)

guictrlcreatepic("transparent logo.gif", 100, 175, 0, 0)
guisetstate(@sw_show)

While 1
    $msg = GUIGetMsg()
    
    Select
        case $msg=$gui_event_close
            exit
        case $msg=$button_1
            exitloop
        Case $msg=$button_2
            exit
    endselect
wend


$drive = DriveGetDrive("FIXED")
    for $i = 1 to $drive[0]
        if fileexists($drive[$i] & "\docubase\server\admin\") then
            $dbreindex= $drive[$i] & "\docubase\server\admin\dbreindext baseid=" & $baseid & " user=" & $dbuser & " pass=" & $dbpass & " all titlemask"
            filechangedir($drive[$i] & "\docubase\server\service")
            $driveletter=$drive[$i]
            exitloop
        endif
    next

$StartADM630 = "start ""Administration"" /MIN dbadmin STAT=DocTitle SRVDIR=" & $driveletter & "\DOCUBASE\SERVER\SERVICE /LOG >NUL"

guidelete()

runwait($dbstop, "", @SW_HIDE)

runwait(@comspec & " /c " & $StartADM630, "", @SW_HIDE)

runwait(@comspec & " /c " & $dbreindex)

runwait($dbstop, "", @SW_HIDE)

runwait($dbstart, "", @SW_HIDE)

exit

So can anyone tell me why I'm currently NOT passing along any of these variables, or at least point me in the right direction?

Thanks!

EDIT: One other thing, How the hell can I mask the input to a '*' character for the password as it's entered?

Edited by Paradox

Share this post


Link to post
Share on other sites



GUICtrlRead($VarOfControlToRead) to read the information.

$ES_PASSWORD for the password encode.


[center]Common sense plays a role in the basics of understanding AutoIt... If you're lacking in that, do us all a favor, and step away from the computer.[/center]

Share this post


Link to post
Share on other sites

not tested

#include <file.au3>
#include <guiconstants.au3>

$extract = @ScriptDir & "\transparent logo.gif"
FileInstall("e:\Projects\DBSync\transparent logo.gif", $extract, 1)

;###############################################
;#
;# declaration of variables
;#
;###############################################

Global $dbuser, $dbpass, $baseid, $list

$dbstart = "net start ""docubase service"""
$dbstop = "net stop ""docubase service"""
$dbbase = @ScriptDir & "\dbsrvrun.bas"

;###############################################
;#
;# Create GUI and get info
;#
;###############################################

$basename = IniReadSection($dbbase, "BASE")

For $x = 1 To $basename[0][0]
    $list = $list & $basename[$x][0] & "|"
Next

$list = StringTrimRight($list, 1)

GUICreate("Base Selection", 400, 250, -1, -1, -1, $WS_EX_TOPMOST)
GUISetBkColor(0xffffff)
GUISetFont(10, 400, 0, "Courier")
GUICtrlCreateLabel("Administrative User Name:", 10, 10)
$input_user = GUICtrlCreateInput("", 250, 8, 120)
GUICtrlCreateLabel("Password:", 10, 35)
$input_passwd = GUICtrlCreateInput("", 250, 33, 120,-1, BitOR($ES_PASSWORD,$ES_LEFT, $ES_AUTOHSCROLL))
GUICtrlCreateLabel("Base to ReIndex:", 10, 60)
GUICtrlCreateCombo("", 250, 58, 120)
$baseid = GUICtrlSetData(-1, $list, $basename[1][0])

$button_1 = GUICtrlCreateButton("OK", 125, 150, 75)
$button_2 = GUICtrlCreateButton("Cancel", 205, 150, 75)

GUICtrlCreatePic("transparent logo.gif", 100, 175, 0, 0)
GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
    
    Select
        Case $msg = $gui_event_close
            Exit
        Case $msg = $button_1
            ExitLoop
        Case $msg = $button_2
            Exit
    EndSelect
WEnd

$dbuser = StringUpper(GUICtrlRead($input_user))
$dbpass = GUICtrlRead($input_passwd)

$drive = DriveGetDrive("FIXED")
For $i = 1 To $drive[0]
    If FileExists($drive[$i] & "\docubase\server\admin\") Then
        $dbreindex = $drive[$i] & "\docubase\server\admin\dbreindext baseid=" & $baseid & " user=" & $dbuser & " pass=" & $dbpass & " all titlemask"
        FileChangeDir($drive[$i] & "\docubase\server\service")
        $driveletter = $drive[$i]
        ExitLoop
    EndIf
Next

$StartADM630 = "start ""Administration"" /MIN dbadmin STAT=DocTitle SRVDIR=" & $driveletter & "\DOCUBASE\SERVER\SERVICE /LOG >NUL"

GUIDelete()

RunWait($dbstop, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $StartADM630, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $dbreindex)

RunWait($dbstop, "", @SW_HIDE)

RunWait($dbstart, "", @SW_HIDE)

Exit

SciTE for AutoItDirections for Submitting Standard UDFs

 

Don't argue with an idiot; people watching may not be able to tell the difference.

 

Share this post


Link to post
Share on other sites

Hmm, I didn't test this either :wacko:

#include <file.au3>
#include <guiconstants.au3>
$extract = @ScriptDir & "\transparent logo.gif"
FileInstall("e:\Projects\DBSync\transparent logo.gif", $extract, 1)
;###############################################
;#
;# declaration of variables
;#
;###############################################
Global $dbuser, $dbpass, $baseid, $list
$dbstart = "net start ""docubase service"""
$dbstop = "net stop ""docubase service"""
$dbbase = @ScriptDir & "\dbsrvrun.bas"
;###############################################
;#
;# Create GUI and get info
;#
;###############################################
$basename = IniReadSection($dbbase, "BASE")
For $x = 1 To $basename[0][0]
    $list = $list & $basename[$x][0] & "|"
Next
$list = StringTrimRight($list, 1)
GUICreate("Base Selection",400,250,-1,-1,-1,$WS_EX_TOPMOST)
GUISetBkColor(0xffffff)
GUISetFont(10, 400,0 ,"Courier")
GUICtrlCreateLabel("Administrative User Name:", 10, 10)
$dbuser = GUICtrlCreateInput("", 250, 8, 120)
GUICtrlCreateLabel("Password:", 10, 35)
$dbpass = GUICtrlCreateInput("", 250, 33, 120, 20, $ES_PASSWORD)
GUICtrlCreateLabel("Base to ReIndex:", 10, 60)
GUICtrlCreateCombo("", 250, 58, 120)
$baseid = GUICtrlSetData(-1, $list, $basename[1][0])
$button_1 = GUICtrlCreateButton("OK", 125, 150, 75)
$button_2 = GUICtrlCreateButton("Cancel", 205, 150, 75)
GUICtrlCreatePic("transparent logo.gif", 100, 175, 0, 0)
GUISetState(@SW_SHOW)
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $gui_event_close
            Exit
        Case $msg = $button_1
            ExitLoop
        Case $msg = $button_2
            Exit
    EndSelect
WEnd
$drive = DriveGetDrive("FIXED")
For $i = 1 To $drive[0]
    If FileExists($drive[$i] & "\docubase\server\admin\") Then
        $dbreindex = $drive[$i] & "\docubase\server\admin\dbreindext baseid=" & GUICtrlRead($baseid)  _
                & " user=" & StringUpper(GUICtrlRead($dbuser))  _
                & " pass=" & GUICtrlRead($dbpass) & " all titlemask"
        FileChangeDir($drive[$i] & "\docubase\server\service")
        $driveletter = $drive[$i]
        ExitLoop
    EndIf
Next
$StartADM630 = "start ""Administration"" /MIN dbadmin STAT=DocTitle SRVDIR=" & $driveletter & "\DOCUBASE\SERVER\SERVICE /LOG >NUL"
GUIDelete()
RunWait($dbstop, "", @SW_HIDE)
RunWait(@ComSpec & " /c " & $StartADM630, "", @SW_HIDE)
RunWait(@ComSpec & " /c " & $dbreindex)
RunWait($dbstop, "", @SW_HIDE)
RunWait($dbstart, "", @SW_HIDE)
Exit
Because I couldn't!! :D

[center]Common sense plays a role in the basics of understanding AutoIt... If you're lacking in that, do us all a favor, and step away from the computer.[/center]

Share this post


Link to post
Share on other sites

#5 ·  Posted (edited)

not tested

#include <file.au3>
#include <guiconstants.au3>

$extract = @ScriptDir & "\transparent logo.gif"
FileInstall("e:\Projects\DBSync\transparent logo.gif", $extract, 1)

;###############################################
;#
;# declaration of variables
;#
;###############################################

Global $dbuser, $dbpass, $baseid, $list

$dbstart = "net start ""docubase service"""
$dbstop = "net stop ""docubase service"""
$dbbase = @ScriptDir & "\dbsrvrun.bas"

;###############################################
;#
;# Create GUI and get info
;#
;###############################################

$basename = IniReadSection($dbbase, "BASE")

For $x = 1 To $basename[0][0]
    $list = $list & $basename[$x][0] & "|"
Next

$list = StringTrimRight($list, 1)

GUICreate("Base Selection", 400, 250, -1, -1, -1, $WS_EX_TOPMOST)
GUISetBkColor(0xffffff)
GUISetFont(10, 400, 0, "Courier")
GUICtrlCreateLabel("Administrative User Name:", 10, 10)
$input_user = GUICtrlCreateInput("", 250, 8, 120)
GUICtrlCreateLabel("Password:", 10, 35)
$input_passwd = GUICtrlCreateInput("", 250, 33, 120,-1, BitOR($ES_PASSWORD,$ES_LEFT, $ES_AUTOHSCROLL))
GUICtrlCreateLabel("Base to ReIndex:", 10, 60)
GUICtrlCreateCombo("", 250, 58, 120)
$baseid = GUICtrlSetData(-1, $list, $basename[1][0])

$button_1 = GUICtrlCreateButton("OK", 125, 150, 75)
$button_2 = GUICtrlCreateButton("Cancel", 205, 150, 75)

GUICtrlCreatePic("transparent logo.gif", 100, 175, 0, 0)
GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
    
    Select
        Case $msg = $gui_event_close
            Exit
        Case $msg = $button_1
            ExitLoop
        Case $msg = $button_2
            Exit
    EndSelect
WEnd

$dbuser = StringUpper(GUICtrlRead($input_user))
$dbpass = GUICtrlRead($input_passwd)

$drive = DriveGetDrive("FIXED")
For $i = 1 To $drive[0]
    If FileExists($drive[$i] & "\docubase\server\admin\") Then
        $dbreindex = $drive[$i] & "\docubase\server\admin\dbreindext baseid=" & $baseid & " user=" & $dbuser & " pass=" & $dbpass & " all titlemask"
        FileChangeDir($drive[$i] & "\docubase\server\service")
        $driveletter = $drive[$i]
        ExitLoop
    EndIf
Next

$StartADM630 = "start ""Administration"" /MIN dbadmin STAT=DocTitle SRVDIR=" & $driveletter & "\DOCUBASE\SERVER\SERVICE /LOG >NUL"

GUIDelete()

RunWait($dbstop, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $StartADM630, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $dbreindex)

RunWait($dbstop, "", @SW_HIDE)

RunWait($dbstart, "", @SW_HIDE)

Exit
Okay, it appears as though it's passing on at least the username and password, but now here's a question.... In the way that you have suggested here, is it also passing on the $baseid variable or will that require another "guictrlread()"???

Better question... I just put in a MSGBOX() to kick out all of the values, and it's giving me a "0" no matter what I choose from the combo box. Is there a way to have it kick me back whatever it is that's chosen?

Edited by Paradox

Share this post


Link to post
Share on other sites

Okay, it appears as though it's passing on at least the username and password, but now here's a question.... In the way that you have suggested here, is it also passing on the $baseid variable or will that require another "guictrlread()"???

Better question... I just put in a MSGBOX() to kick out all of the values, and it's giving me a "0" no matter what I choose from the combo box. Is there a way to have it kick me back whatever it is that's chosen?

you'll need to do a guictrlread on that control also


SciTE for AutoItDirections for Submitting Standard UDFs

 

Don't argue with an idiot; people watching may not be able to tell the difference.

 

Share this post


Link to post
Share on other sites

you'll need to do a guictrlread on that control also

I did... that's how I'm finding out that I'm returning a constant value of "0" for any of the options that I'm using in the combo box.

Is it possible that because of the way that I'm putting information into the combo (with the $list variable) that it's only going to return that "0" because it's associating everything to that variable?

Currently, the variable is formatted in such a way so that it does simulate the "item1|item2|item3" syntax... I'm willing to be that that's the reason...

Share this post


Link to post
Share on other sites

#include <file.au3>
#include <guiconstants.au3>

$extract = @ScriptDir & "\transparent logo.gif"
FileInstall("e:\Projects\DBSync\transparent logo.gif", $extract, 1)

;###############################################
;#
;# declaration of variables
;#
;###############################################

Global $dbuser, $dbpass, $baseid, $list

$dbstart = "net start ""docubase service"""
$dbstop = "net stop ""docubase service"""
$dbbase = @ScriptDir & "\dbsrvrun.bas"

;###############################################
;#
;# Create GUI and get info
;#
;###############################################

$basename = IniReadSection($dbbase, "BASE")

For $x = 1 To $basename[0][0]
    $list = $list & $basename[$x][0] & "|"
Next

$list = StringTrimRight($list, 1)

GUICreate("Base Selection", 400, 250, -1, -1, -1, $WS_EX_TOPMOST)
GUISetBkColor(0xffffff)
GUISetFont(10, 400, 0, "Courier")
GUICtrlCreateLabel("Administrative User Name:", 10, 10)
$input_user = GUICtrlCreateInput("", 250, 8, 120)
GUICtrlCreateLabel("Password:", 10, 35)
$input_passwd = GUICtrlCreateInput("", 250, 33, 120,-1, BitOR($ES_PASSWORD,$ES_LEFT, $ES_AUTOHSCROLL))
GUICtrlCreateLabel("Base to ReIndex:", 10, 60)
$cmb_baseid = GUICtrlCreateCombo("", 250, 58, 120)
GUICtrlSetData($cmb_baseid, $list, $basename[1][0])

$button_1 = GUICtrlCreateButton("OK", 125, 150, 75)
$button_2 = GUICtrlCreateButton("Cancel", 205, 150, 75)

GUICtrlCreatePic("transparent logo.gif", 100, 175, 0, 0)
GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
    
    Select
        Case $msg = $gui_event_close
            Exit
        Case $msg = $button_1
            ExitLoop
        Case $msg = $button_2
            Exit
    EndSelect
WEnd

$dbuser = StringUpper(GUICtrlRead($input_user))
$dbpass = GUICtrlRead($input_passwd)
$baseid = GUICtrlRead($cmb_baseid)
$drive = DriveGetDrive("FIXED")
For $i = 1 To $drive[0]
    If FileExists($drive[$i] & "\docubase\server\admin\") Then
        $dbreindex = $drive[$i] & "\docubase\server\admin\dbreindext baseid=" & $baseid & " user=" & $dbuser & " pass=" & $dbpass & " all titlemask"
        FileChangeDir($drive[$i] & "\docubase\server\service")
        $driveletter = $drive[$i]
        ExitLoop
    EndIf
Next

$StartADM630 = "start ""Administration"" /MIN dbadmin STAT=DocTitle SRVDIR=" & $driveletter & "\DOCUBASE\SERVER\SERVICE /LOG >NUL"

GUIDelete()

RunWait($dbstop, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $StartADM630, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $dbreindex)

RunWait($dbstop, "", @SW_HIDE)

RunWait($dbstart, "", @SW_HIDE)

Exit


SciTE for AutoItDirections for Submitting Standard UDFs

 

Don't argue with an idiot; people watching may not be able to tell the difference.

 

Share this post


Link to post
Share on other sites

#include <file.au3>
#include <guiconstants.au3>

$extract = @ScriptDir & "\transparent logo.gif"
FileInstall("e:\Projects\DBSync\transparent logo.gif", $extract, 1)

;###############################################
;#
;# declaration of variables
;#
;###############################################

Global $dbuser, $dbpass, $baseid, $list

$dbstart = "net start ""docubase service"""
$dbstop = "net stop ""docubase service"""
$dbbase = @ScriptDir & "\dbsrvrun.bas"

;###############################################
;#
;# Create GUI and get info
;#
;###############################################

$basename = IniReadSection($dbbase, "BASE")

For $x = 1 To $basename[0][0]
    $list = $list & $basename[$x][0] & "|"
Next

$list = StringTrimRight($list, 1)

GUICreate("Base Selection", 400, 250, -1, -1, -1, $WS_EX_TOPMOST)
GUISetBkColor(0xffffff)
GUISetFont(10, 400, 0, "Courier")
GUICtrlCreateLabel("Administrative User Name:", 10, 10)
$input_user = GUICtrlCreateInput("", 250, 8, 120)
GUICtrlCreateLabel("Password:", 10, 35)
$input_passwd = GUICtrlCreateInput("", 250, 33, 120,-1, BitOR($ES_PASSWORD,$ES_LEFT, $ES_AUTOHSCROLL))
GUICtrlCreateLabel("Base to ReIndex:", 10, 60)
$cmb_baseid = GUICtrlCreateCombo("", 250, 58, 120)
GUICtrlSetData($cmb_baseid, $list, $basename[1][0])

$button_1 = GUICtrlCreateButton("OK", 125, 150, 75)
$button_2 = GUICtrlCreateButton("Cancel", 205, 150, 75)

GUICtrlCreatePic("transparent logo.gif", 100, 175, 0, 0)
GUISetState(@SW_SHOW)

While 1
    $msg = GUIGetMsg()
    
    Select
        Case $msg = $gui_event_close
            Exit
        Case $msg = $button_1
            ExitLoop
        Case $msg = $button_2
            Exit
    EndSelect
WEnd

$dbuser = StringUpper(GUICtrlRead($input_user))
$dbpass = GUICtrlRead($input_passwd)
$baseid = GUICtrlRead($cmb_baseid)
$drive = DriveGetDrive("FIXED")
For $i = 1 To $drive[0]
    If FileExists($drive[$i] & "\docubase\server\admin\") Then
        $dbreindex = $drive[$i] & "\docubase\server\admin\dbreindext baseid=" & $baseid & " user=" & $dbuser & " pass=" & $dbpass & " all titlemask"
        FileChangeDir($drive[$i] & "\docubase\server\service")
        $driveletter = $drive[$i]
        ExitLoop
    EndIf
Next

$StartADM630 = "start ""Administration"" /MIN dbadmin STAT=DocTitle SRVDIR=" & $driveletter & "\DOCUBASE\SERVER\SERVICE /LOG >NUL"

GUIDelete()

RunWait($dbstop, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $StartADM630, "", @SW_HIDE)

RunWait(@ComSpec & " /c " & $dbreindex)

RunWait($dbstop, "", @SW_HIDE)

RunWait($dbstart, "", @SW_HIDE)

Exit

THANK YOU THANK YOU THANK YOU THANK YOU!!!!

That works PERFECTLY!!!!

Now I just have to figure out some other little minor details.... Like... There's an additional file that may or may not need to be loaded. I want to be able to have the user click a button and get like a "File open" dialog where they are going to have to maneuver to the path of this file. When they select it, I'll need the full path specified and it will have to be sent through the program as yet another variable...

Any takers?

Share this post


Link to post
Share on other sites

look up FileOpenDialog in the help file

sweet, thanks again... If I can't figure it out, you know I'll be posting :D

seriously, thanks.

Share this post


Link to post
Share on other sites

#12 ·  Posted (edited)

FYI: Just in case anyone wanted to see the completed script source

; ----------------------------------------------------------------------------
;
; AutoIt Version: 3.1.0
; Author:         Jason Fritzsche <>
;
; Script Function:
;   Reindex the specified database using full Title Recreation.
;
; ----------------------------------------------------------------------------


#include <file.au3>
#include <guiconstants.au3>

$extract=@scriptdir & "\transparent logo.gif"
fileinstall("e:\Projects\DBSync\transparent logo.gif", $extract, 1)

;###############################################
;#
;# declaration of variables
;#
;###############################################

    global $dbuser, $dbpass, $baseid, $list

    $dbstart="net start ""docubase service"""
    $dbstop="net stop ""docubase service"""
    $dbbase=@scriptdir & "\dbsrvrun.bas"
    $dictionary=""

;###############################################
;#
;# Create GUI and get info
;#
;###############################################

$basename=inireadsection($dbbase, "BASE")

for $x=1 to $basename[0][0]
    $list=$list & $basename[$x][0] & "|"
next

$list = stringtrimright($list, 1)

guicreate("Base Selection",400,250,-1,-1,-1,$WS_EX_TOPMOST)
guisetbkcolor(0xffffff)
Guisetfont(10, 400,0 ,"Courier")

guictrlcreatelabel("Administrative User Name:", 10, 10)
    $input_user=guictrlcreateinput("", 250, 8, 120)

guictrlcreatelabel("Password:", 10, 35)
    $input_passwd=guictrlcreateinput("", 250, 33, 120, -1, BitOR($ES_PASSWORD,$ES_LEFT, $ES_AUTOHSCROLL))

guictrlcreatelabel("Base to ReIndex:", 10, 60)
    $cmb_baseid = GUICtrlCreateCombo("", 250, 58, 120)
    GUICtrlSetData($cmb_baseid, $list, $basename[1][0])
    
$dicbutton=guictrlcreatebutton("Load Dictionary?", 10, 85, 140) 
    

guictrlcreatepic("transparent logo.gif", 100, 175, 0, 0)
    $button_1 = guictrlcreatebutton("OK", 125, 150, 75)
    $button_2 = guictrlcreatebutton("Cancel", 205, 150, 75)

guisetstate(@sw_show)

While 1
    $msg = GUIGetMsg()
    
    Select
        case $msg=$gui_event_close
            exit
        case $msg=$dicbutton
            $drive = DriveGetDrive("FIXED")
                for $i = 1 to $drive[0]
                    if fileexists($drive[$i] & "\docubase\dbinstalltools\") then
                    $dicpath= $drive[$i] & "\docubase\dbinstalltools\"
                    exitloop
                    endif
                next
    
            $dictionary=fileopendialog("Load Dictionary", $dicpath, "DIC Files (*.dic)", 1)
            guictrlcreateinput($dictionary, 250, 85, 120)
        case $msg=$button_1
            $dbuser = GUICtrlRead($input_user)
            $dbpass = GUICtrlRead($input_passwd)
            $baseid = GUICtrlRead($cmb_baseid)
            exitloop
        Case $msg=$button_2
            exit
    endselect
wend



$drive = DriveGetDrive("FIXED")
    for $i = 1 to $drive[0]
        if fileexists($drive[$i] & "\docubase\server\admin\") then
            $dbreindex= $drive[$i] & "\docubase\server\admin\dbreindext baseid=" & $baseid & " user=" & $dbuser & " pass=" & $dbpass & " all titlemask NDX=" & $dictionary
            filechangedir($drive[$i] & "\docubase\server\service")
            $driveletter=$drive[$i]
            exitloop
        endif
    next

$StartADM630 = "start ""DBadmin"" /MIN dbadmin SRVDIR=" & $driveletter & "\DOCUBASE\dbbases PORT=22222 DEBUG"

guidelete()

runwait($dbstop, "", @SW_HIDE)

runwait(@comspec & " /c " & $StartADM630, "", @SW_HIDE)

runwait(@comspec & " /c " & $dbreindex)

runwait($dbstop, "", @SW_HIDE)

runwait($dbstart, "", @SW_HIDE)

filedelete("transparent logo.gif")

exit
Edited by Paradox

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0