Quick _ArraySort Question

[guestscripter]

I'm making separate arrays containing a. song titles in itunes and b. the corresponding artists.

eg $titles[1] = "all my loving" $artists[1] = "the beatles"

I want to sort the song titles alphabetically using the _ArraySort udf, but won't that mean that the artists will no longer match, and if I sort the artists the order will be completely different?

I'm looking for a simple way around that.

Any ideas?

Edited October 6, 2006 by yaziquex

[Xenobiologist]

Hi,

does this work? I tried it. :">

; Array Sort
#include<Array.au3>

Global $song[4] = ["Ein bißchen Frieden", "Skater Boi", "Supreme", "Hello again"]
Global $artist[4] = ["Nicole", "Avril", "Robbie Williams", "Howard Carpendale"]

_ArrayDisplay($song, "Song")
_ArrayDisplay($artist, "Artist")
_sort($song, $artist)
_ArrayDisplay($song, "Song")
_ArrayDisplay($artist, "Artist")


Func _sort(ByRef $Master_A, ByRef $Slave_A, $i_Descending = 0)
    If UBound($Master_A) <> UBound($Slave_A) Then Return -1
    Local $sort_A[UBound($Master_A) ][2]
    For $i = 0 To UBound($Master_A) - 1
        $sort_A[$i][0] = $Master_A[$i]
        $sort_A[$i][1] = $Slave_A[$i]
    Next
    _ArraySort($sort_A, $i_Descending, 0, 0, 2, 0)
    For $i = 0 To UBound($sort_A) - 1
        $Master_A[$i] = $sort_A[$i][0]
        $Slave_A[$i] = $sort_A[$i][1]
    Next
    Return 1
EndFunc   ;==>_sort

So long,

Mega